add unit tests and determine version from GIT_TAG (#66)

* add unit tests

* determine package version from git tag. closes #54.

* update readme

* bugfix

* update example

* update gitignore

.gitignore

@@ -8,3 +8,4 @@ install_manifest.txt
 compile_commands.json
 CTestTestfile.cmake
 build
+.vscode

.travis.yml

@@ -1,11 +1,14 @@
 
 language: cpp
 sudo: require
+dist: xenial
 
 common_sources: &all_sources
   - ubuntu-toolchain-r-test
   - llvm-toolchain-trusty
-  - llvm-toolchain-trusty-6.0
+
+python:
+  - 3.7
 
 matrix:
   include:
@@ -41,10 +44,9 @@ before_install:
   - cmake --version
 
 script:
-  - cmake -Hexamples/simple -Bbuild/simple 
-  - cmake --build build/simple
-  - CTEST_OUTPUT_ON_FAILURE=1 cmake --build build/simple --target test
-  - cmake -Hexamples/complex -Bbuild/complex
-  - cmake --build build/complex
-  - CTEST_OUTPUT_ON_FAILURE=1 cmake --build build/complex --target test
+  # unit tests
+  - cmake -Htest -Bbuild/test
+  - CTEST_OUTPUT_ON_FAILURE=1 cmake --build build/test --target test
+  # examples
+  - python3 examples/run_all.py
  

README.md

@@ -1,16 +1,47 @@
 [![Build Status](https://travis-ci.com/TheLartians/CPM.svg?branch=master)](https://travis-ci.com/TheLartians/CPM)
 
-# CPM
+<p align="center">
+  <img src="./logo/CPM.png" height="100" />
+</p>
 
-CPM is a simple GIT dependency manager written in CMake. The main use-case is abstracting CMake's `FetchContent` and managing dependencies in small to medium sized projects.
+# Setup-free CMake dependency management
 
-## Supported projects
+CPM is a CMake script that adds dependency management capabilities to CMake.
+It's built as a wrapper around CMake's [FetchContent](https://cmake.org/cmake/help/latest/module/FetchContent.html) module that adds version control and a simple API.
 
-Any project that you can add via `add_subdirectory` should already work with CPM.
+## Manage everything
+
+Anything can be added as a version-controlled dependency though CPM, no packaging required.
+Projects using CMake are automatically configured and their targets can be used immediately.
+For everything else, a target can be created manually (see below).
 
 ## Usage
 
-To add a new dependency to your project simply add the Projects target name, the git URL and the version. If the git tag for this version does not match the pattern `v$VERSION`, then the exact branch or tag can be specified with the `GIT_TAG` argument. CMake options can also be supplied with the package.
+After `CPM.cmake` has been added to your project, the function `CPMAddPackage` can be used to fetch and configure a dependency.
+Afterwards, any targets defined in the dependency can be used directly.
+`CPMAddPackage` takes the following named paramters.
+
+```cmake
+CPMAddPackage(
+  NAME          # The unique name of the dependency (should be the main target's name)
+  VERSION       # The minimum version of the dependency (optional, defaults to 0)
+  OPTIONS       # Configuration options passed to the dependency (optional)
+  DOWNLOAD_ONLY # If set, the project is downloaded, but not configured (optional)
+  [...]         # Origin paramters forwarded to FetchContent_Declare, see below
+)
+```
+
+The origin may be specified by a `GIT_REPOSITORY`, but other sources, such as direct URLs, are [also supported](https://cmake.org/cmake/help/v3.11/module/ExternalProject.html#external-project-definition).
+If `GIT_TAG` hasn't been explicitly specified it defaults to `v(VERSION)`, a common convention for git projects.
+`GIT_TAG` can also be set to a specific commit or a branch name such as `master` to download the most recent version.
+
+Besides downloading and to configuring the dependency, the following variables are defined in the local scope, where `(DEPENDENCY)` is the name of the dependency.
+
+- `(DEPENDENCY)_SOURCE_DIR` is the path to the source of the dependency.
+- `(DEPENDENCY)_BINARY_DIR` is the path to the build directory of the dependency.
+- `(DEPENDENCY)_ADDED` is set to `YES` if the dependency has not been added before, otherwise it is set to `NO`.
+
+## Full CMakeLists Example
 
 ```cmake
 cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
@@ -18,31 +49,32 @@ cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
 # create project
 project(MyProject)
 
+# add executable
+add_executable(myProject myProject.cpp)
+set_target_properties(myProject PROPERTIES CXX_STANDARD 17)
+
 # add dependencies
-include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/CPM.cmake)
+include(cmake/CPM.cmake)
 
 CPMAddPackage(
   NAME LarsParser
   VERSION 1.8
   GIT_REPOSITORY https://github.com/TheLartians/Parser.git
-  GIT_TAG v1.8 # optional here, as indirectly defined by VERSION
-  OPTIONS      # optional CMake arguments passed to the dependency
+  OPTIONS
     "LARS_PARSER_BUILD_GLUE_EXTENSION ON"
 )
 
-# add executable
-add_executable(my-project my-project.cpp)
-set_target_properties(my-project PROPERTIES CXX_STANDARD 17)
-target_link_libraries(my-project LarsParser)
+target_link_libraries(myProject LarsParser)
 ```
 
-See the [examples directory](https://github.com/TheLartians/CPM/tree/master/examples) for more examples.
+See the [examples directory](https://github.com/TheLartians/CPM/tree/master/examples) for more examples with source code.
 
 ## Adding CPM
 
 To add CPM to your current project, simply add `cmake/CPM.cmake` to your project's `cmake` directory. The command below will perform this automatically.
 
 ```bash
+mkdir -p cmake
 wget -O cmake/CPM.cmake https://raw.githubusercontent.com/TheLartians/CPM/master/cmake/CPM.cmake
 ```
 
@@ -50,20 +82,148 @@ wget -O cmake/CPM.cmake https://raw.githubusercontent.com/TheLartians/CPM/master
 
 To update CPM to the newest version, simply update the script in the project's cmake directory, for example by running the command above. Dependencies using CPM will automatically use the updated script of the outermost project.
 
-## Options
-
-Setting the CMake option `CPM_USE_LOCAL_PACKAGES` will activate finding packages via `find_package`. If the option `CPM_LOCAL_PACKAGES_ONLY` is set, CPM will only use local packages.
-
 ## Advantages
 
-- **Small repos** CPM takes care of project dependencies, allowing you to focus on creating small, well-tested frameworks.
+- **Small and reusable projects** CPM takes care of all project dependencies, allowing developers to focus on creating small, well-tested frameworks.
 - **Cross-Plattform** CPM adds projects via `add_subdirectory`, which is compatible with all cmake toolchains and generators.
 - **Reproducable builds** By using versioning via git tags it is ensured that a project will always be in the same state everywhere.
-- **No installation required** No need to install anything. Just add the script to your project and you're good to go.
-- **No Setup required** There is a good chance your existing projects already work as CPM dependencies.
+- **Recursive dependencies** Ensures that no dependency is added twice and is added in the minimum required version.
+- **Plug-and-play** No need to install anything. Just add the script to your project and you're good to go.
+- **No packaging required** There is a good chance your existing projects already work as CPM dependencies.
+- **Simple source distribution** CPM makes including projects with source files and dependencies easy, reducing the need for monolithic header files.
 
 ## Limitations
 
-- **First version used** In diamond-shaped dependency graphs (e.g. `A` depends on `C`(v1.1) and `A` depends on `B` depends on `C`(v1.2)) the first added dependency will be used (in this case `C`@1.1). If the current version is older than the version beeing added, or if provided options are incompatible, a CMake warning will be emitted. To resolve, add the new version of the common dependency to the outer project.
-- **No auto-update** To update a dependency, version numbers or git tags in the cmake scripts must be adapted manually.
-- **No pre-built binaries** Unless they are installed or included in the linked repository.
+- **No pre-built binaries** For every new project, all dependencies must be downloaded and built from scratch. A possible workaround is to use CPM to fetch a pre-built binary or to enable local packages (see below).
+- **Dependent on good CMakeLists** Many libraries do not have CMakeLists that work well for subprojects. Luckily this is slowly changing, however, until then, some manual configuration may be required (see below).
+- **First version used** In diamond-shaped dependency graphs (e.g. `A` depends on `C`@1.1 and `B`, which itself depends on `C`@1.2 the first added dependency will be used (in this case `C`@1.1). In this case, B requires a newer version of `C` than `A`, so CPM will emit an error. This can be resolved by updating the outermost dependency version.
+
+For projects with more complex needs and where an extra setup step doesn't matter, it is worth to check out fully featured C++ package managers such as [conan](https://conan.io), [vcpkg](https://github.com/microsoft/vcpkg) or [hunter](https://github.com/ruslo/hunter).
+Support for package managers is also [planned](https://github.com/TheLartians/CPM/issues/51) for a future version of CPM.
+
+## Local packages
+
+CPM can be configured to use `find_package` to search for locally installed dependencies first by setting the CMake option `CPM_USE_LOCAL_PACKAGES`.
+If the option `CPM_LOCAL_PACKAGES_ONLY` is set, CPM will emit an error if the dependency is not found locally.
+
+## Snipplets
+
+These examples demonstrate how to include some well-known projects with CPM.
+
+### [Catch2](https://github.com/catchorg/Catch2)
+
+```cmake
+CPMAddPackage(
+  NAME Catch2
+  GITHUB_REPOSITORY catchorg/Catch2
+  VERSION 2.5.0
+)
+```
+
+### [Doctest](https://github.com/onqtam/doctest)
+
+```cmake
+CPMAddPackage(
+  NAME doctest
+  GITHUB_REPOSITORY onqtam/doctest
+  GIT_TAG 2.3.2
+)
+```
+
+### [google/benchmark](https://github.com/google/benchmark)
+
+```cmake
+CPMAddPackage(
+  NAME benchmark
+  GITHUB_REPOSITORY google/benchmark
+  VERSION 1.4.1
+  OPTIONS
+    "BENCHMARK_ENABLE_TESTING Off"
+)
+
+if (benchmark_ADDED)
+  # compile with C++17
+  set_target_properties(benchmark PROPERTIES CXX_STANDARD 17)
+endif()
+```
+
+### [nlohmann/json](https://github.com/nlohmann/json)
+
+```cmake
+CPMAddPackage(
+  NAME nlohmann_json
+  VERSION 3.6.1  
+  # the git repo is incredibly large, so we download the archived include directory
+  URL https://github.com/nlohmann/json/releases/download/v3.6.1/include.zip
+  URL_HASH SHA256=69cc88207ce91347ea530b227ff0776db82dcb8de6704e1a3d74f4841bc651cf
+)
+
+if (nlohmann_json_ADDED)
+  add_library(nlohmann_json INTERFACE IMPORTED)
+  target_include_directories(nlohmann_json INTERFACE ${nlohmann_json_SOURCE_DIR})
+endif()
+```
+
+### [Range-v3](https://github.com/ericniebler/range-v3)
+
+```Cmake
+CPMAddPackage(
+  NAME range-v3
+  URL https://github.com/ericniebler/range-v3/archive/0.5.0.zip
+  VERSION 0.5.0
+  # the range-v3 CMakeLists screws with configuration options
+  DOWNLOAD_ONLY True
+)
+
+if(range-v3_ADDED) 
+  add_library(range-v3 INTERFACE IMPORTED)
+  target_include_directories(range-v3 INTERFACE "${range-v3_SOURCE_DIR}/include")
+endif()
+```
+
+### [Yaml-cpp](https://github.com/jbeder/yaml-cpp)
+
+```CMake
+CPMAddPackage(
+  NAME yaml-cpp
+  GITHUB_REPOSITORY jbeder/yaml-cpp
+  # 0.6.2 uses depricated CMake syntax
+  VERSION 0.6.3                                  
+  # 0.6.3 is not released yet, so use a recent commit
+  GIT_TAG 012269756149ae99745b6dafefd415843d7420bb 
+  OPTIONS
+    "YAML_CPP_BUILD_TESTS Off"
+    "YAML_CPP_BUILD_CONTRIB Off"
+    "YAML_CPP_BUILD_TOOLS Off"
+)
+```
+
+### [Lua](https://www.lua.org)
+
+```cmake
+CPMAddPackage(
+  NAME lua
+  GIT_REPOSITORY https://github.com/lua/lua.git
+  GIT_TAG v5-3-4
+  VERSION 5.3.4
+  DOWNLOAD_ONLY YES
+)
+
+if (lua_ADDED)
+  # lua has no CMakeLists, so we create our own target
+
+  FILE(GLOB lua_sources ${lua_SOURCE_DIR}/*.c)
+  add_library(lua STATIC ${lua_sources})
+
+  target_include_directories(lua
+    PUBLIC
+      $<BUILD_INTERFACE:${lua_SOURCE_DIR}>
+  )
+endif()
+```
+
+For a full example on using CPM to download and configure lua with sol2 see [here](examples/sol2).
+
+### Examples
+
+See the [examples directory](https://github.com/TheLartians/CPM/tree/master/examples) for more examples with source code.

cmake/CPM.cmake

@@ -2,8 +2,9 @@
 # =================================================
 # See https://github.com/TheLartians/CPM for usage and update instructions.
 #
-#   MIT License
-#[[ -----------
+# MIT License
+# ----------- 
+#[[
   Copyright (c) 2019 Lars Melchior
 
   Permission is hereby granted, free of charge, to any person obtaining a copy
@@ -27,50 +28,45 @@
 
 cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
 
+set(CURRENT_CPM_VERSION 0.12) 
+
 if(CPM_DIRECTORY)
   if(NOT ${CPM_DIRECTORY} MATCHES ${CMAKE_CURRENT_LIST_DIR})
+    if (${CPM_VERSION} VERSION_LESS ${CURRENT_CPM_VERSION})
+      CPM_HANDLE_OLD_VERSION(${CURRENT_CPM_VERSION})  
+    endif()
     return()
   endif()
 endif()
 
-set(CPM_VERSION 0.7 CACHE INTERNAL "")
-
+set(CPM_VERSION ${CURRENT_CPM_VERSION} CACHE INTERNAL "")
 set(CPM_DIRECTORY ${CMAKE_CURRENT_LIST_DIR} CACHE INTERNAL "")
 set(CPM_PACKAGES "" CACHE INTERNAL "")
+set(CPM_DRY_RUN OFF CACHE INTERNAL "Don't download or configure dependencies (for testing)")
 
 option(CPM_USE_LOCAL_PACKAGES "Use locally installed packages (find_package)" OFF)
 option(CPM_LOCAL_PACKAGES_ONLY "Use only locally installed packages" OFF)
 
+
 include(FetchContent)
 include(CMakeParseArguments)
 
+# Initialize logging prefix
 if(NOT CPM_INDENT)
   set(CPM_INDENT "CPM:")
 endif()
 
-function(CPMRegisterPackage PACKAGE VERSION)
-  set(CPM_PACKAGES ${CPM_PACKAGES} CACHE INTERNAL "")
-  set("CPM_PACKAGE_${PACKAGE}_VERSION" ${VERSION} CACHE INTERNAL "")
-endfunction()
-
-function(CPM_GET_PACKAGE_VERSION PACKAGE)
-  set(CPM_PACKAGE_VERSION "${CPM_PACKAGE_${PACKAGE}_VERSION}" PARENT_SCOPE)
-endfunction()
-
-function(CPM_PARSE_OPTION OPTION)
-  string(REGEX MATCH "^[^ ]+" OPTION_KEY ${OPTION})
-  string(LENGTH ${OPTION_KEY} OPTION_KEY_LENGTH)
-  math(EXPR OPTION_KEY_LENGTH "${OPTION_KEY_LENGTH}+1")
-  string(SUBSTRING ${OPTION} "${OPTION_KEY_LENGTH}" "-1" OPTION_VALUE)
-  set(OPTION_KEY "${OPTION_KEY}" PARENT_SCOPE)
-  set(OPTION_VALUE "${OPTION_VALUE}" PARENT_SCOPE)
-endfunction()
-
+# The main workhorse of CPM
 function(CPMAddPackage)
+
   set(oneValueArgs
     NAME
     VERSION
     GIT_TAG
+    DOWNLOAD_ONLY
+    GITHUB_REPOSITORY
+    GITLAB_REPOSITORY
+    DRY # for testing
   )
 
   set(multiValueArgs
@@ -96,18 +92,39 @@ function(CPMAddPackage)
     endif()
   endif()
 
-  if (NOT CPM_ARGS_VERSION)
-    set(CPM_ARGS_VERSION 0)
+  if (NOT DEFINED CPM_ARGS_VERSION)
+    if (DEFINED CPM_ARGS_GIT_TAG) 
+      CPM_GET_VERSION_FROM_GIT_TAG("${CPM_ARGS_GIT_TAG}" CPM_ARGS_VERSION)
+    endif()
+    if (NOT DEFINED CPM_ARGS_VERSION) 
+      set(CPM_ARGS_VERSION 0)
+    endif()
   endif()
 
-  if (NOT CPM_ARGS_GIT_TAG)
+  if (NOT DEFINED CPM_ARGS_GIT_TAG)
     set(CPM_ARGS_GIT_TAG v${CPM_ARGS_VERSION})
   endif()
 
+  list(APPEND CPM_ARGS_UNPARSED_ARGUMENTS GIT_TAG ${CPM_ARGS_GIT_TAG})
+
+  if(CPM_ARGS_DOWNLOAD_ONLY)
+    set(DOWNLOAD_ONLY ${CPM_ARGS_DOWNLOAD_ONLY})
+  else()
+    set(DOWNLOAD_ONLY NO)
+  endif()
+
+  if (CPM_ARGS_GITHUB_REPOSITORY)
+    list(APPEND CPM_ARGS_UNPARSED_ARGUMENTS GIT_REPOSITORY "https://github.com/${CPM_ARGS_GITHUB_REPOSITORY}.git")
+  endif()
+
+  if (CPM_ARGS_GITLAB_REPOSITORY)
+    list(APPEND CPM_ARGS_UNPARSED_ARGUMENTS GIT_REPOSITORY "https://gitlab.com/${CPM_ARGS_GITLAB_REPOSITORY}.git")
+  endif()
+
   if (${CPM_ARGS_NAME} IN_LIST CPM_PACKAGES)
-    CPM_GET_PACKAGE_VERSION(${CPM_ARGS_NAME})
+    CPM_GET_PACKAGE_VERSION(${CPM_ARGS_NAME} CPM_PACKAGE_VERSION)
     if(${CPM_PACKAGE_VERSION} VERSION_LESS ${CPM_ARGS_VERSION})
-      message(WARNING "${CPM_INDENT} newer package ${CPM_ARGS_NAME} requested (${CPM_ARGS_VERSION}, currently using ${CPM_PACKAGE_VERSION})")
+      message(WARNING "${CPM_INDENT} requires a newer version of ${CPM_ARGS_NAME} (${CPM_ARGS_VERSION}) than currently included (${CPM_PACKAGE_VERSION}).")
     endif()
     if (CPM_ARGS_OPTIONS)
       foreach(OPTION ${CPM_ARGS_OPTIONS})
@@ -117,7 +134,11 @@ function(CPMAddPackage)
         endif()
       endforeach()
     endif()
-    CPM_FETCH_PACKAGE(${CPM_ARGS_NAME})
+    CPM_FETCH_PACKAGE(${CPM_ARGS_NAME} ${DOWNLOAD_ONLY})
+    CPMGetProperties(${CPM_ARGS_NAME})
+    SET(${CPM_ARGS_NAME}_SOURCE_DIR "${${CPM_ARGS_NAME}_SOURCE_DIR}" PARENT_SCOPE)
+    SET(${CPM_ARGS_NAME}_BINARY_DIR "${${CPM_ARGS_NAME}_BINARY_DIR}" PARENT_SCOPE)  
+    SET(${CPM_ARGS_NAME}_ADDED NO PARENT_SCOPE)  
     return()
   endif()
 
@@ -131,22 +152,86 @@ function(CPMAddPackage)
   endif()
 
   CPM_DECLARE_PACKAGE(${CPM_ARGS_NAME} ${CPM_ARGS_VERSION} ${CPM_ARGS_GIT_TAG} "${CPM_ARGS_UNPARSED_ARGUMENTS}")
-  CPM_FETCH_PACKAGE(${CPM_ARGS_NAME})
+  CPM_FETCH_PACKAGE(${CPM_ARGS_NAME} ${DOWNLOAD_ONLY})
+  CPMGetProperties(${CPM_ARGS_NAME})
+  SET(${CPM_ARGS_NAME}_SOURCE_DIR "${${CPM_ARGS_NAME}_SOURCE_DIR}" PARENT_SCOPE)
+  SET(${CPM_ARGS_NAME}_BINARY_DIR "${${CPM_ARGS_NAME}_BINARY_DIR}" PARENT_SCOPE)
+  SET(${CPM_ARGS_NAME}_ADDED YES PARENT_SCOPE)  
 endfunction()
 
 function (CPM_DECLARE_PACKAGE PACKAGE VERSION GIT_TAG)
   message(STATUS "${CPM_INDENT} adding package ${PACKAGE}@${VERSION} (${GIT_TAG})")
 
+  if (${CPM_DRY_RUN}) 
+    message(STATUS "${CPM_INDENT} package not declared (dry run)")
+    return()
+  endif()
+
   FetchContent_Declare(
     ${PACKAGE}
-    GIT_TAG ${GIT_TAG}
     ${ARGN}
   )
 endfunction()
 
-function (CPM_FETCH_PACKAGE PACKAGE)  
+function (CPM_FETCH_PACKAGE PACKAGE DOWNLOAD_ONLY)  
+
+  if (${CPM_DRY_RUN}) 
+    message(STATUS "${CPM_INDENT} package ${PACKAGE} not fetched (dry run)")
+    return()
+  endif()
+
   set(CPM_OLD_INDENT "${CPM_INDENT}")
   set(CPM_INDENT "${CPM_INDENT} ${PACKAGE}:")
-  FetchContent_MakeAvailable(${PACKAGE})
+  if(${DOWNLOAD_ONLY})
+    if(NOT "${PACKAGE}_POPULATED")
+      FetchContent_Populate(${PACKAGE})
+    endif()
+  else()
+    FetchContent_MakeAvailable(${PACKAGE})
+  endif()
   set(CPM_INDENT "${CPM_OLD_INDENT}")
 endfunction()
+
+function (CPMGetProperties PACKAGE)
+  if (${CPM_DRY_RUN}) 
+    return()
+  endif()
+  FetchContent_GetProperties(${PACKAGE})
+  string(TOLOWER ${PACKAGE} lpackage)
+  SET(${PACKAGE}_SOURCE_DIR "${${lpackage}_SOURCE_DIR}" PARENT_SCOPE)
+  SET(${PACKAGE}_BINARY_DIR "${${lpackage}_BINARY_DIR}" PARENT_SCOPE)
+endfunction()
+
+function(CPMRegisterPackage PACKAGE VERSION)
+  list(APPEND CPM_PACKAGES ${PACKAGE})
+  set(CPM_PACKAGES ${CPM_PACKAGES} CACHE INTERNAL "")
+  set("CPM_PACKAGE_${PACKAGE}_VERSION" ${VERSION} CACHE INTERNAL "")
+endfunction()
+
+function(CPM_GET_PACKAGE_VERSION PACKAGE OUTPUT)
+  set(${OUTPUT} "${CPM_PACKAGE_${PACKAGE}_VERSION}" PARENT_SCOPE)
+endfunction()
+
+function(CPM_PARSE_OPTION OPTION)
+  string(REGEX MATCH "^[^ ]+" OPTION_KEY ${OPTION})
+  string(LENGTH ${OPTION_KEY} OPTION_KEY_LENGTH)
+  math(EXPR OPTION_KEY_LENGTH "${OPTION_KEY_LENGTH}+1")
+  string(SUBSTRING ${OPTION} "${OPTION_KEY_LENGTH}" "-1" OPTION_VALUE)
+  set(OPTION_KEY "${OPTION_KEY}" PARENT_SCOPE)
+  set(OPTION_VALUE "${OPTION_VALUE}" PARENT_SCOPE)
+endfunction()
+
+function(CPM_GET_VERSION_FROM_GIT_TAG GIT_TAG RESULT)
+  string(REGEX MATCH "v?([0123456789.]*).*" _ ${GIT_TAG})
+  SET(${RESULT} ${CMAKE_MATCH_1} PARENT_SCOPE)
+endfunction()
+
+function (CPM_HANDLE_OLD_VERSION NEW_CPM_VERSION)
+  
+  message(AUTHOR_WARNING "${CPM_INDENT} \
+A dependency is using a more recent CPM (${NEW_CPM_VERSION}) than the current project (${CPM_VERSION}). \
+It is recommended to upgrade CPM to the most recent version. \
+See https://github.com/TheLartians/CPM for more information."
+  )
+
+endfunction()

cmake/testing.cmake

@@ -0,0 +1,10 @@
+
+function(ASSERT_EQUAL)
+  if (NOT ARGC EQUAL 2) 
+    message(FATAL_ERROR "assertion failed: invalid argument count: ${ARGC}")
+  endif()
+
+  if (NOT ${ARGV0} EQUAL ${ARGV1})
+    message(FATAL_ERROR "assertion failed: '${ARGV0}' != '${ARGV1}'")
+  endif()
+endfunction()

examples/benchmark/CMakeLists.txt

@@ -0,0 +1,30 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME fibonacci
+  GIT_REPOSITORY https://github.com/TheLartians/Fibonacci.git
+  VERSION 1.0
+)
+
+CPMAddPackage(
+  NAME benchmark
+  GITHUB_REPOSITORY google/benchmark
+  VERSION 1.4.1
+  OPTIONS
+    "BENCHMARK_ENABLE_TESTING Off"
+)
+
+if (benchmark_ADDED)
+  # patch google benchmark target
+  set_target_properties(benchmark PROPERTIES CXX_STANDARD 17)
+endif()
+
+# ---- Executable ----
+
+add_executable(CPMExampleBenchmark "main.cpp")
+set_target_properties(CPMExampleBenchmark PROPERTIES CXX_STANDARD 17)        
+target_link_libraries(CPMExampleBenchmark fibonacci benchmark)

examples/benchmark/main.cpp

@@ -0,0 +1,36 @@
+#include <benchmark/benchmark.h>
+#include <vector>
+#include <algorithm>
+#include <random>
+
+#include <fibonacci.h>
+
+
+std::vector<unsigned> createTestNumbers(){
+  std::vector<unsigned> v;
+  for (int i=0;i<25;++i) v.emplace_back(i);
+  std::random_device rd;
+  std::mt19937 g(rd());
+  std::shuffle(v.begin(), v.end(), g);
+  return v;
+}
+
+void fibonnacci(benchmark::State& state) {
+  auto numbers = createTestNumbers();
+  for (auto _ : state) {
+    for (auto v: numbers) benchmark::DoNotOptimize(fibonnacci(v));
+  }
+}
+
+BENCHMARK(fibonnacci);
+
+void fastFibonacci(benchmark::State& state) {
+  auto numbers = createTestNumbers();
+  for (auto _ : state) {
+    for (auto v: numbers) benchmark::DoNotOptimize(fastFibonacci(v));
+  }
+}
+
+BENCHMARK(fastFibonacci);
+
+BENCHMARK_MAIN();

examples/catch2/CMakeLists.txt

@@ -0,0 +1,39 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+# ---- Options ----
+
+option(ENABLE_TEST_COVERAGE "Enable test coverage" OFF)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME fibonacci
+  GIT_REPOSITORY https://github.com/TheLartians/Fibonacci.git
+  VERSION 1.0
+)
+
+CPMAddPackage(
+  NAME Catch2
+  GITHUB_REPOSITORY catchorg/Catch2
+  VERSION 2.5.0
+)
+
+# ---- Create binary ----
+
+add_executable(CPMExampleCatch2 main.cpp)
+target_link_libraries(CPMExampleCatch2 fibonacci Catch2)
+set_target_properties(CPMExampleCatch2 PROPERTIES CXX_STANDARD 17 COMPILE_FLAGS "-Wall -pedantic -Wextra -Werror")
+
+# ---- Enable testing ----
+
+ENABLE_TESTING() 
+ADD_TEST(CPMExampleCatch2 CPMExampleCatch2)
+
+# ---- Add code coverage ----
+
+if (${ENABLE_TEST_COVERAGE})
+  set_target_properties(CPMExampleCatch2 PROPERTIES CXX_STANDARD 17 COMPILE_FLAGS "-O0 -g -fprofile-arcs -ftest-coverage --coverage")
+  target_link_options(CPMExampleCatch2 PUBLIC "--coverage")
+endif()

examples/catch2/main.cpp

@@ -0,0 +1,20 @@
+#define CATCH_CONFIG_MAIN
+
+#include <catch2/catch.hpp>
+#include <fibonacci.h>
+
+TEST_CASE("fibonnacci"){
+  REQUIRE(fibonnacci(0) == 0);
+  REQUIRE(fibonnacci(1) == 1);
+  REQUIRE(fibonnacci(2) == 1);
+  REQUIRE(fibonnacci(3) == 2);
+  REQUIRE(fibonnacci(4) == 3);
+  REQUIRE(fibonnacci(5) == 5);
+  REQUIRE(fibonnacci(13) == 233);
+}
+
+TEST_CASE("fastFibonnacci"){
+  for (unsigned i=0; i<25; ++i){
+    REQUIRE(fibonnacci(i) == fastFibonacci(i));
+  }
+}

examples/complex/CMakeLists.txt

@@ -1,55 +0,0 @@
-cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
-
-project(CPMTest)
-
-include(${CMAKE_CURRENT_SOURCE_DIR}/../../cmake/CPM.cmake)
-
-# ignore locally installed projects for reproducable builds
-set(CPM_REMOTE_PACKAGES_ONLY ON CACHE INTERNAL "")
-
-# util library
-CPMAddPackage(
-  NAME LHC
-  GIT_REPOSITORY https://github.com/TheLartians/LHC.git
-  VERSION 0.7
-)
-
-# will be ignored as newer version already added
-CPMAddPackage(
-  NAME LHC
-  GIT_REPOSITORY https://github.com/TheLartians/LHC.git
-  VERSION 0.2
-)
-
-# language bindings
-# uses git tag instead of version identifier
-# depends on visitor library that depends on Event library and LHC
-# CMake configuration arguments passed via OPTIONS
-CPMAddPackage(
-  NAME Glue
-  GIT_TAG 78af65625751ad15a42ca52b842863e85b5d2adc
-  GIT_REPOSITORY https://github.com/TheLartians/Glue.git
-  VERSION 0.5.1
-  OPTIONS 
-    "GLUE_ENABLE_LUA ON"
-    "GLUE_BUILD_LUA ON"
-)
-
-# parser library 
-# depends on LHC and Glue
-CPMAddPackage(
-  NAME LarsParser
-  GIT_REPOSITORY https://github.com/TheLartians/Parser.git
-  VERSION 1.8
-  OPTIONS 
-    "LARS_PARSER_BUILD_GLUE_EXTENSION ON"
-)
-
-# add executable
-add_executable(cpm-test-complex main.cpp)
-set_target_properties(cpm-test-complex PROPERTIES CXX_STANDARD 17)
-target_link_libraries(cpm-test-complex LHC LarsParser Glue)
-
-# tests
-enable_testing()
-add_test(cpm-test-complex cpm-test-complex)

examples/complex/main.cpp

@@ -1,52 +0,0 @@
-#include <lars/parser/extension.h>
-#include <lars/lua_glue.h>
-#include <stdexcept>
-
-int main() {
-  // create lua state
-  auto lua = lars::LuaState();
-  lua.open_libs();
-
-  // create extensions
-  lars::Extension extensions;
-
-  // add parser library to extension
-  extensions.add_extension("parser", lars::extensions::parser());
-
-  // connect parser extension to lua
-  extensions.connect(lua.get_glue());
-
-  // create a parser
-  lua.run(R"(
-    NumberMap = parser.Program.create()
-
-    NumberMap:setRule("Whitespace", "[ \t]")
-    NumberMap:setSeparatorRule("Whitespace")
-
-    NumberMap:setRuleWithCallback("Object", "'{' KeyValue (',' KeyValue)* '}'",function(e) 
-      local N = e:size()-1
-      local res = {}
-      for i=0,N do 
-        local a = e:get(i)
-        res[a:get(0):evaluate()] = a:get(1):evaluate() 
-      end
-      return res
-    end)
-
-    NumberMap:setRule("KeyValue", "Number ':' Number")
-
-    NumberMap:setRuleWithCallback("Number", "'-'? [0-9]+", function(e) return tonumber(e:string()); end)
-    
-    NumberMap:setStartRule("Object")
-  )");
-
-  // parse a string
-  lua.run("m = NumberMap:run('{1:3, 2:-1, 3:42}')");
-  
-  // check result
-  if (lua.get_numeric("m[1]") != 3) throw std::runtime_error("unexpected result");
-  if (lua.get_numeric("m[2]") != -1) throw std::runtime_error("unexpected result");
-  if (lua.get_numeric("m[3]") != 42) throw std::runtime_error("unexpected result");
-
-  return 0;
-}

examples/doctest/CMakeLists.txt

@@ -0,0 +1,39 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+# ---- Options ----
+
+option(ENABLE_TEST_COVERAGE "Enable test coverage" OFF)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME fibonacci
+  GIT_REPOSITORY https://github.com/TheLartians/Fibonacci.git
+  VERSION 1.0
+)
+
+CPMAddPackage(
+  NAME doctest
+  GITHUB_REPOSITORY onqtam/doctest
+  GIT_TAG 2.3.2
+)
+
+# ---- Create binary ----
+
+add_executable(CPMExampleDoctest main.cpp)
+target_link_libraries(CPMExampleDoctest fibonacci doctest)
+set_target_properties(CPMExampleDoctest PROPERTIES CXX_STANDARD 17 COMPILE_FLAGS "-Wall -pedantic -Wextra -Werror")
+
+# ---- Enable testing ----
+
+ENABLE_TESTING() 
+ADD_TEST(CPMExampleDoctest CPMExampleDoctest)
+
+# ---- Add code coverage ----
+
+if (${ENABLE_TEST_COVERAGE})
+  set_target_properties(CPMExampleDoctest PROPERTIES CXX_STANDARD 17 COMPILE_FLAGS "-O0 -g -fprofile-arcs -ftest-coverage --coverage")
+  target_link_options(CPMExampleDoctest PUBLIC "--coverage")
+endif()

examples/doctest/main.cpp

@@ -0,0 +1,20 @@
+#define DOCTEST_CONFIG_IMPLEMENT_WITH_MAIN
+
+#include <doctest/doctest.h>
+#include <fibonacci.h>
+
+TEST_CASE("fibonnacci"){
+  CHECK(fibonnacci(0) == 0);
+  CHECK(fibonnacci(1) == 1);
+  CHECK(fibonnacci(2) == 1);
+  CHECK(fibonnacci(3) == 2);
+  CHECK(fibonnacci(4) == 3);
+  CHECK(fibonnacci(5) == 5);
+  CHECK(fibonnacci(13) == 233);
+}
+
+TEST_CASE("fastFibonnacci"){
+  for (unsigned i=0; i<25; ++i){
+    CHECK(fibonnacci(i) == fastFibonacci(i));
+  }
+}

examples/json/CMakeLists.txt

@@ -0,0 +1,24 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME nlohmann_json
+  VERSION 3.6.1  
+  # not using the repo as it takes forever to clone
+  URL https://github.com/nlohmann/json/releases/download/v3.6.1/include.zip
+  URL_HASH SHA256=69cc88207ce91347ea530b227ff0776db82dcb8de6704e1a3d74f4841bc651cf
+)
+
+if(nlohmann_json_ADDED)
+  add_library(nlohmann_json INTERFACE)
+  target_include_directories(nlohmann_json INTERFACE ${nlohmann_json_SOURCE_DIR})
+endif()
+
+# ---- Executable ----
+
+add_executable(CPMJSONExample "main.cpp")
+set_target_properties(CPMJSONExample PROPERTIES CXX_STANDARD 17)        
+target_link_libraries(CPMJSONExample nlohmann_json)

examples/json/main.cpp

@@ -0,0 +1,25 @@
+#include <nlohmann/json.hpp>
+#include <iostream>
+#include <iomanip>
+
+int main(){
+  
+  nlohmann::json json = {
+    {"pi", 3.141},
+    {"happy", true},
+    {"name", "Niels"},
+    {"nothing", nullptr},
+    {"answer", {
+      {"everything", 42}
+    }},
+    {"list", {1, 0, 2}},
+    {"object", {
+      {"currency", "USD"},
+      {"value", 42.99}
+    }}
+  };
+
+  std::cout << "declared JSON object: " << std::setw(2) << json << std::endl;
+
+  return 0;
+}

examples/parser-lua/CMakeLists.txt

@@ -0,0 +1,28 @@
+cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
+
+include(../../cmake/CPM.cmake)
+
+# ---- Dependencies ----
+
+CPMAddPackage(
+  NAME Glue
+  GIT_REPOSITORY https://github.com/TheLartians/Glue.git
+  VERSION 0.8.1
+  OPTIONS 
+    "GLUE_ENABLE_LUA ON"
+    "GLUE_BUILD_LUA ON"
+)
+
+CPMAddPackage(
+  NAME LarsParser
+  GIT_REPOSITORY https://github.com/TheLartians/Parser.git
+  VERSION 1.9
+  OPTIONS 
+    "LARS_PARSER_BUILD_GLUE_EXTENSION ON"
+)
+
+# ---- Create binary ----
+
+add_executable(parser-lua main.cpp)
+set_target_properties(parser-lua PROPERTIES CXX_STANDARD 17)
+target_link_libraries(parser-lua LHC LarsParser Glue)

examples/parser-lua/main.cpp

@@ -0,0 +1,46 @@
+#include <lars/parser/extension.h>
+#include <glue/lua.h>
+#include <stdexcept>
+#include <iostream>
+
+int main() {
+  auto lua = glue::LuaState();
+  lua.openStandardLibs();
+
+  lua["parser"] = lars::glue::parser();
+  
+  lua.run(R"(
+    wordParser = parser.Program.create()
+
+    wordParser:setRule("Whitespace", "[ \t]")
+    wordParser:setSeparatorRule("Whitespace")
+
+    wordParser:setRule("Word", "[a-zA-Z]+")
+    
+    wordParser:setRuleWithCallback("Words", "Word*", function(e) 
+      local N = e:size()
+      local res = {}
+      for i=0,N-1 do res[#res+1] = e:get(i):string() end
+      return res
+    end)
+
+    wordParser:setStartRule("Words")
+  )");
+
+  lua.run(R"(
+    while true do
+      print("please enter some words or 'quit' to exit");
+      local input = io.read();
+      if input == "quit" then os.exit() end
+      local result
+      ok, err = pcall(function() result = wordParser:run(input) end)
+      if ok then
+        print("you entered " .. #result .. " words!")
+      else 
+        print("error: " .. tostring(err))
+      end
+    end
+  )");
+
+  return 0;
+}

examples/parser/CMakeLists.txt

@@ -0,0 +1,15 @@
+cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
+
+# add dependencies
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME LarsParser
+  GIT_REPOSITORY https://github.com/TheLartians/Parser.git
+  VERSION 1.7
+)
+
+# add executable
+add_executable(calculator main.cpp)
+set_target_properties(calculator PROPERTIES CXX_STANDARD 17)
+target_link_libraries(calculator LarsParser)

examples/parser/main.cpp

@@ -0,0 +1,57 @@
+#include <iostream>
+#include <unordered_map>
+#include <cmath>
+
+#include <lars/parser/generator.h>
+
+int main() {
+  using namespace std;
+  using VariableMap = unordered_map<string, float>;
+  
+  lars::ParserGenerator<float, VariableMap &> calculator;
+  
+  auto &g = calculator;
+  g.setSeparator(g["Whitespace"] << "[\t ]");
+
+  g["Expression"] << "Set | Sum";
+  g["Set"       ] << "Name '=' Sum" >> [](auto e, auto &v){ return v[e[0].string()] = e[1].evaluate(v); };
+  g["Sum"       ] << "Add | Subtract | Product";
+  g["Product"   ] << "Multiply | Divide | Exponent";
+  g["Exponent"  ] << "Power | Atomic";
+  g["Atomic"    ] << "Number | Brackets | Variable";
+  g["Brackets"  ] << "'(' Sum ')'";
+  g["Add"       ] << "Sum '+' Product"       >> [](auto e, auto &v){ return e[0].evaluate(v) + e[1].evaluate(v); };
+  g["Subtract"  ] << "Sum '-' Product"       >> [](auto e, auto &v){ return e[0].evaluate(v) - e[1].evaluate(v); };
+  g["Multiply"  ] << "Product '*' Exponent"  >> [](auto e, auto &v){ return e[0].evaluate(v) * e[1].evaluate(v); };
+  g["Divide"    ] << "Product '/' Exponent"  >> [](auto e, auto &v){ return e[0].evaluate(v) / e[1].evaluate(v); };
+  g["Power"     ] << "Atomic ('^' Exponent)" >> [](auto e, auto &v){ return pow(e[0].evaluate(v), e[1].evaluate(v)); };
+  g["Variable"  ] << "Name" >> [](auto e, auto &v){ return v[e[0].string()]; };
+  g["Name"      ] << "[a-zA-Z] [a-zA-Z0-9]*";
+  g["Number"    ] << "'-'? [0-9]+ ('.' [0-9]+)?" >> [](auto e, auto &){ return stod(e.string()); };
+
+  g.setStart(g["Expression"]);
+
+  cout << "Enter an expression to be evaluated or 'quit' to exit.\n";
+
+  VariableMap variables;
+
+  while (true) {
+    string str;
+    cout << "> ";
+    getline(cin,str);
+    if(str == "q" || str == "quit"){ break; }
+    try {
+      auto result = calculator.run(str, variables);
+      cout << str << " = " << result << endl;
+    } catch (lars::SyntaxError &error) {
+      auto syntax = error.syntax;
+      cout << "  ";
+      cout << string(syntax->begin, ' ');
+      cout << string(syntax->length(), '~');
+      cout << "^\n";
+      cout << "  " << "Syntax error while parsing " << syntax->rule->name << endl;
+    }
+  }
+
+  return 0;
+}

examples/range-v3/CMakeLists.txt

@@ -0,0 +1,24 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME range-v3
+  URL https://github.com/ericniebler/range-v3/archive/0.5.0.zip
+  VERSION 0.5.0
+  # the range-v3 CMakeLists screws with configuration options
+  DOWNLOAD_ONLY True
+)
+
+if(range-v3_ADDED) 
+  add_library(range-v3 INTERFACE IMPORTED)
+  target_include_directories(range-v3 INTERFACE "${range-v3_SOURCE_DIR}/include")
+endif()
+
+# ---- Executable ----
+
+add_executable(CPMRangev3Example "main.cpp")
+set_target_properties(CPMRangev3Example PROPERTIES CXX_STANDARD 17)        
+target_link_libraries(CPMRangev3Example range-v3)

examples/range-v3/main.cpp

@@ -0,0 +1,44 @@
+// Range v3 library
+//
+//  Copyright Jeff Garland 2017
+//
+//  Use, modification and distribution is subject to the
+//  Boost Software License, Version 1.0. (See accompanying
+//  file LICENSE_1_0.txt or copy at
+//  http://www.boost.org/LICENSE_1_0.txt)
+//
+// Project home: https://github.com/ericniebler/range-v3
+//
+
+//[any_all_none_of]]
+// Demonstrates any_of, all_of, none_of
+// output
+// vector: [6,2,3,4,5,6]
+// vector any_of is_six: true
+// vector all_of is_six: false
+// vector none_of is_six: false
+
+#include <range/v3/algorithm/all_of.hpp>
+#include <range/v3/algorithm/any_of.hpp>
+#include <range/v3/algorithm/for_each.hpp>
+#include <range/v3/algorithm/none_of.hpp>
+#include <range/v3/view/all.hpp>
+
+#include <iostream>
+#include <vector>
+using std::cout;
+
+auto is_six = [](int i) { return i == 6; };
+
+int
+main()
+{
+    std::vector<int> v{6, 2, 3, 4, 5, 6};
+    cout << std::boolalpha;
+    cout << "vector: " << ranges::view::all(v) << '\n';
+
+    cout << "vector any_of is_six: " << ranges::any_of(v, is_six) << '\n';
+    cout << "vector all_of is_six: " << ranges::all_of(v, is_six) << '\n';
+    cout << "vector none_of is_six: " << ranges::none_of(v, is_six) << '\n';
+}
+//[any_all_none_of]]

examples/run_all.py

@@ -0,0 +1,29 @@
+#!/usr/bin/python3
+
+from pathlib import Path
+from subprocess import PIPE, run
+
+examples = [
+  x for x in Path(__file__).parent.iterdir() if x.is_dir() and (x / 'CMakeLists.txt').exists()
+]
+
+assert(len(examples) > 0)
+
+def runCommand(command):
+  print('- %s' % command)
+  result = run(command, stdout=PIPE, stderr=PIPE, universal_newlines=True, shell=True)
+  if result.returncode != 0:
+    print("error while running '%s':\n" % command, '  ' + str(result.stderr).replace('\n','\n  '))
+    exit(result.returncode)
+  return result.stdout
+
+print('')
+for example in examples:
+  print("running example %s" % example.name)
+  print("================" + ('=' * len(example.name)))
+  project = Path(".") / 'build' / example.name
+  configure = runCommand('cmake -H%s -B%s -DCMAKE_BUILD_TYPE=RelWithDebInfo' % (example, project))
+  print('  ' + '\n  '.join([line for line in configure.split('\n') if 'CPM:' in line]))
+  build = runCommand('cmake --build %s -j4' % (project))
+  print('  ' + '\n  '.join([line for line in build.split('\n') if 'Built target' in line]))
+  print('')

examples/simple/CMakeLists.txt

@@ -1,21 +0,0 @@
-cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
-
-project(CPMTest)
-
-# add dependencies
-include(${CMAKE_CURRENT_SOURCE_DIR}/../../cmake/CPM.cmake)
-
-CPMAddPackage(
-  NAME LarsParser
-  GIT_REPOSITORY https://github.com/TheLartians/Parser.git
-  VERSION 1.7
-)
-
-# add executable
-add_executable(cpm-test-simple main.cpp)
-set_target_properties(cpm-test-simple PROPERTIES CXX_STANDARD 17)
-target_link_libraries(cpm-test-simple LarsParser)
-
-# tests
-enable_testing()
-add_test(cpm-test-simple cpm-test-simple)

examples/simple/main.cpp

@@ -1,27 +0,0 @@
-#include <lars/parser/generator.h>
-
-int main() {
-  lars::ParserGenerator<float> g;
-
-  // Define grammar and evaluation rules
-  g.setSeparator(g["Whitespace"] << "[\t ]");
-  g["Sum"     ] << "Add | Subtract | Product";
-  g["Product" ] << "Multiply | Divide | Atomic";
-  g["Atomic"  ] << "Number | '(' Sum ')'";
-  g["Add"     ] << "Sum '+' Product"    >> [](auto e){ return e[0].evaluate() + e[1].evaluate(); };
-  g["Subtract"] << "Sum '-' Product"    >> [](auto e){ return e[0].evaluate() - e[1].evaluate(); };
-  g["Multiply"] << "Product '*' Atomic" >> [](auto e){ return e[0].evaluate() * e[1].evaluate(); };
-  g["Divide"  ] << "Product '/' Atomic" >> [](auto e){ return e[0].evaluate() / e[1].evaluate(); };
-  g["Number"  ] << "'-'? [0-9]+ ('.' [0-9]+)?" >> [](auto e){ return stof(e.string()); };
-  g.setStart(g["Sum"]);
-
-  // Execute a string
-  float result = g.run("1 + 2 * (3+4)/2 - 3");
-
-  // validate result
-  if (result == 5) {
-    return 0;
-  } else {
-    return 1;
-  }
-}

examples/simple_match/CMakeLists.txt

@@ -0,0 +1,24 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME simple_match
+  GIT_REPOSITORY https://github.com/jbandela/simple_match.git
+  GIT_TAG a3ab17f3d98db302de68ad85ed399a42ae41889e
+  DOWNLOAD_ONLY True
+)
+
+if(simple_match_ADDED)
+  add_library(simple_match INTERFACE IMPORTED)
+  target_include_directories(simple_match INTERFACE "${simple_match_SOURCE_DIR}/include")
+endif()
+
+# ---- Executable ----
+
+add_executable(CPMSimpleMatchExample "main.cpp")
+set_target_properties(CPMSimpleMatchExample PROPERTIES CXX_STANDARD 17)        
+target_link_libraries(CPMSimpleMatchExample simple_match)
+

examples/simple_match/main.cpp

@@ -0,0 +1,34 @@
+#include <simple_match/simple_match.hpp>
+
+#include <iostream>
+
+int main(int argc, char ** argv){
+  using namespace simple_match;
+  using namespace simple_match::placeholders;
+
+  std::string input;
+  std::cout << "please enter a number or 'quit' to exit" << std::endl;
+
+  while (true) {
+    std::cout << "> ";
+    std::getline(std::cin, input);
+    if (input == "quit") { break; }
+    int x;
+    try {
+      x = std::stoi(input);
+    } catch(std::invalid_argument &) {
+      std::cout << "invalid input" << std::endl;
+      continue;
+    }
+    
+    match(x,
+      1, []() {std::cout << "The answer is one\n"; },
+      2, []() {std::cout << "The answer is two\n"; },
+      _x < 10, [](auto&& a) {std::cout << "The answer " << a << " is less than 10\n"; },
+      10 < _x < 20,	[](auto&& a) {std::cout << "The answer " << a  << " is between 10 and 20 exclusive\n"; },
+      _, []() {std::cout << "Did not match\n"; }
+    );
+  }
+
+  return 0;
+}

examples/sol2/CMakeLists.txt

@@ -0,0 +1,46 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME lua
+  GIT_REPOSITORY https://github.com/lua/lua.git
+  VERSION 5.3.4
+  GIT_TAG v5-3-4
+  DOWNLOAD_ONLY YES
+)
+
+if (lua_ADDED)
+  # lua has no CMakeLists, so we create our own target
+
+  FILE(GLOB lua_sources ${lua_SOURCE_DIR}/*.c)
+  add_library(lua STATIC ${lua_sources})
+
+  target_include_directories(lua
+    PUBLIC
+      $<BUILD_INTERFACE:${lua_SOURCE_DIR}>
+  )
+endif()
+
+
+CPMAddPackage(
+  NAME sol2
+  URL https://github.com/ThePhD/sol2/archive/v3.0.2.zip
+  VERSION 3.0.2
+  DOWNLOAD_ONLY YES
+)
+
+if (sol2_ADDED)
+  add_library(sol2 INTERFACE IMPORTED)
+  target_include_directories(sol2 INTERFACE ${sol2_SOURCE_DIR}/include)
+  target_link_libraries(sol2 INTERFACE lua)
+endif()
+
+# ---- Executable ----
+
+add_executable(CPMSol2Example "main.cpp")
+set_target_properties(CPMSol2Example PROPERTIES CXX_STANDARD 17)        
+target_link_libraries(CPMSol2Example sol2)
+

examples/sol2/main.cpp

@@ -0,0 +1,16 @@
+#include <sol/sol.hpp>
+#include <cassert>
+
+struct vars {
+    int boop = 0;
+};
+
+int main() {
+    sol::state lua;
+    lua.open_libraries( sol::lib::base );
+    lua.new_usertype<vars>("vars", "boop", &vars::boop);
+    lua.script("beep = vars.new()\n"
+               "beep.boop = 1\n"
+               "print('beep boop')");
+    assert(lua.get<vars>("beep").boop == 1);
+}

examples/yaml/CMakeLists.txt

@@ -0,0 +1,25 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME yaml-cpp
+  GIT_REPOSITORY https://github.com/jbeder/yaml-cpp.git
+  # 0.6.2 uses depricated CMake syntax
+  VERSION 0.6.3                                  
+  # 0.6.3 is not released yet, so use the most recent commit
+  GIT_TAG 012269756149ae99745b6dafefd415843d7420bb 
+  OPTIONS
+    "YAML_CPP_BUILD_TESTS Off"
+    "YAML_CPP_BUILD_CONTRIB Off"
+    "YAML_CPP_BUILD_TOOLS Off"
+)
+
+# ---- Executable ----
+
+add_executable(CPMYamlExample "main.cpp")
+set_target_properties(CPMYamlExample PROPERTIES CXX_STANDARD 17)        
+target_link_libraries(CPMYamlExample yaml-cpp)
+

examples/yaml/main.cpp

@@ -0,0 +1,14 @@
+#include <yaml-cpp/yaml.h>
+#include <iostream>
+
+int main(int argc, char ** argv){
+  if (argc != 2) {
+    std::cout << "usage: " << argv[0] << " <path to yaml file>" << std::endl;
+    return 1;
+  }
+
+  YAML::Node config = YAML::LoadFile(argv[1]);
+  std::cout << "Parsed YAML:\n" << config << std::endl;
+
+  return 0;
+}

examples/yaml/monsters.yaml

@@ -0,0 +1,21 @@
+- name: Ogre
+  position: [0, 5, 0]
+  powers:
+    - name: Club
+      damage: 10
+    - name: Fist
+      damage: 8
+- name: Dragon
+  position: [1, 0, 10]
+  powers:
+    - name: Fire Breath
+      damage: 25
+    - name: Claws
+      damage: 15
+- name: Wizard
+  position: [5, -3, 0]
+  powers:
+    - name: Acid Rain
+      damage: 50
+    - name: Staff
+      damage: 3

test/CMakeLists.txt

@@ -0,0 +1,14 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+file(GLOB tests "${CMAKE_CURRENT_SOURCE_DIR}/unit/*.cmake")
+
+enable_testing()
+
+foreach(test ${tests})
+  message(STATUS "adding test: ${test}")
+  add_test(
+    NAME ${test} 
+    COMMAND ${CMAKE_COMMAND} -DCPM_PATH=${CMAKE_CURRENT_SOURCE_DIR}/../cmake -P "${test}"
+  )
+
+endforeach()

test/unit/dependency_properties.cmake

@@ -0,0 +1,30 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+include(${CPM_PATH}/CPM.cmake)
+include(${CPM_PATH}/testing.cmake)
+
+set(CPM_DRY_RUN ON)
+
+CPMAddPackage(
+  NAME A
+  GIT_TAG 1.2.3
+)
+
+CPM_GET_PACKAGE_VERSION(A VERSION)
+ASSERT_EQUAL(${VERSION} "1.2.3")
+
+CPMAddPackage(
+  NAME B
+  GIT_TAG v2.3.1
+)
+
+CPM_GET_PACKAGE_VERSION(B VERSION)
+ASSERT_EQUAL(${VERSION} "2.3.1")
+
+CPMAddPackage(
+  NAME C
+  GIT_TAG v3.1.2-a
+)
+
+CPM_GET_PACKAGE_VERSION(C VERSION)
+ASSERT_EQUAL(${VERSION} "3.1.2")

test/unit/version_from_git_tag.cmake

@@ -0,0 +1,16 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+include(${CPM_PATH}/CPM.cmake)
+include(${CPM_PATH}/testing.cmake)
+
+CPM_GET_VERSION_FROM_GIT_TAG("1.2.3" VERSION)
+ASSERT_EQUAL("1.2.3" ${VERSION})
+
+CPM_GET_VERSION_FROM_GIT_TAG("v1.2.3" VERSION)
+ASSERT_EQUAL("1.2.3" ${VERSION})
+
+CPM_GET_VERSION_FROM_GIT_TAG("1.2.3-a" VERSION)
+ASSERT_EQUAL("1.2.3" ${VERSION})
+
+CPM_GET_VERSION_FROM_GIT_TAG("v1.2.3-a" VERSION)
+ASSERT_EQUAL("1.2.3" ${VERSION})