Fix support for source subdirectories (#238)

* add support for source subdirectories

* style fixes

* remove debug log

* grammar fix in comment

.cmake-format

@@ -33,6 +33,7 @@ parse:
         DOWNLOAD_NO_EXTRACT: 1
         HTTP_USERNAME: 1
         HTTP_PASSWORD: 1
+        EXCLUDE_FROM_ALL: 1
         OPTIONS: +
     cpmfindpackage:
       pargs:

README.md

@@ -27,9 +27,9 @@ For everything else, the targets can be created manually after the dependency ha
 
 ## Usage
 
-After `CPM.cmake` has been [added](#adding-cpm) to your project, the function `CPMAddPackage` or `CPMFindPackage` can be used to fetch and configure a dependency.
+After `CPM.cmake` has been [added](#adding-cpm) to your project, the function `CPMAddPackage` can be used to fetch and configure a dependency.
 Afterwards, any targets defined in the dependency can be used directly.
-`CPMFindPackage` and `CPMAddPackage` take the following named parameters.
+`CPMAddPackage` takes the following named parameters.
 
 ```cmake
 CPMAddPackage(
@@ -43,18 +43,44 @@ CPMAddPackage(
 
 The origin may be specified by a `GIT_REPOSITORY`, but other sources, such as direct URLs, are [also supported](https://cmake.org/cmake/help/v3.11/module/ExternalProject.html#external-project-definition).
 If `GIT_TAG` hasn't been explicitly specified it defaults to `v(VERSION)`, a common convention for git projects.
-On the other hand, if `VERSION` hasn't been explicitly specified, CPM can automatically identify the version from the git tag in some common cases. 
+On the other hand, if `VERSION` hasn't been explicitly specified, CPM can automatically identify the version from the git tag in some common cases.
 `GIT_TAG` can also be set to a specific commit or a branch name such as `master` to always download the most recent version.
-The optional argument `FIND_PACKAGE_ARGUMENTS` can be specified to a string of parameters that will be passed to `find_package` if enabled (see below).
 
-After calling `CPMAddPackage` or `CPMFindPackage`, the following variables are defined in the local scope, where `<dependency>` is the name of the dependency.
+If an additional optional parameter `EXCLUDE_FROM_ALL` is set to a truthy value, then any targets defined inside the dependency won't be built by default. See the [CMake docs](https://cmake.org/cmake/help/latest/prop_tgt/EXCLUDE_FROM_ALL.html) for details.
+
+A single-argument compact syntax is also supported:
+
+```cmake
+# A git package from a given uri with a version
+CPMAddPackage("uri@version")
+# A git package from a given uri with a git tag or commit hash, or branch name
+CPMAddPackage("uri#tag")
+# A git package with both version and tag provided
+CPMAddPackage("uri@version#tag")
+```
+
+In the shorthand syntax if the URI is of the form `gh:user/name`, it is interpreted as GitHub URI and converted to `https://github.com/user/name.git`. If the URI is of the form `gl:user/name`, it is interpreted as a [GitLab](https://gitlab.com/explore/) URI and coverted to `https://gitlab.com/user/name.git`. Otherwise the URI used verbatim as a git URL. All packages added using the shorthand syntax will be added using the [EXCLUDE_FROM_ALL](https://cmake.org/cmake/help/latest/prop_tgt/EXCLUDE_FROM_ALL.html) flag.
+
+The single-argument syntax also works for URLs:
+
+```cmake
+# An archive package from a given url. The version is inferred
+CPMAddPackage("https://example.com/my-package-1.2.3.zip")
+# An archive package from a given url with an MD5 hash provided
+CPMAddPackage("https://example.com/my-package-1.2.3.zip#MD5=68e20f674a48be38d60e129f600faf7d")
+# An archive package from a given url. The version is explicitly given
+CPMAddPackage("https://example.com/my-package.zip@1.2.3")
+```
+
+After calling `CPMAddPackage`, the following variables are defined in the local scope, where `<dependency>` is the name of the dependency.
 
 - `<dependency>_SOURCE_DIR` is the path to the source of the dependency.
 - `<dependency>_BINARY_DIR` is the path to the build directory of the dependency.
 - `<dependency>_ADDED` is set to `YES` if the dependency has not been added before, otherwise it is set to `NO`.
 
-The difference between `CPMFindPackage` and `CPMAddPackage` is that `CPMFindPackage` will try to find a local dependency via CMake's `find_package` and fallback to `CPMAddPackage` if the dependency is not found.
-This behaviour can be also modified globally via [CPM options](#options).
+For using CPM.cmake projects with external package managers, such as conan or vcpkg, setting the variable [`CPM_USE_LOCAL_PACKAGES`](#options) will make CPM.cmake try to add a package through `find_package` first, and add it from source if it doesn't succeed.
+
+In rare cases, this behaviour may be desirable by default. The function `CPMFindPackage` will try to find a local dependency via CMake's `find_package` and fallback to `CPMAddPackage`, if the dependency is not found.
 
 ## Full CMakeLists Example
 
@@ -69,12 +95,7 @@ add_executable(tests tests.cpp)
 
 # add dependencies
 include(cmake/CPM.cmake)
-
-CPMAddPackage(
-  NAME Catch2
-  GITHUB_REPOSITORY catchorg/Catch2
-  VERSION 2.5.0
-)
+CPMAddPackage("gh:catchorg/Catch2@2.5.0")
 
 # link dependencies
 target_link_libraries(tests Catch2)
@@ -112,7 +133,7 @@ Dependencies using CPM will automatically use the updated script of the outermos
 ## Limitations
 
 - **No pre-built binaries** For every new build directory, all dependencies are initially downloaded and built from scratch. To avoid extra downloads it is recommend to set the [`CPM_SOURCE_CACHE`](#CPM_SOURCE_CACHE) environmental variable. Using a caching compiler such as [ccache](https://github.com/TheLartians/Ccache.cmake) can drastically reduce build time.
-- **Dependent on good CMakeLists** Many libraries do not have CMakeLists that work well for subprojects. Luckily this is slowly changing, however, until then, some manual configuration may be required (see the snippets [below](#snippets) for examples). For best practices on preparing projects for CPM, see the [wiki](https://github.com/cpm-cmake/CPM.cmake/wiki/Preparing-projects-for-CPM.cmake). 
+- **Dependent on good CMakeLists** Many libraries do not have CMakeLists that work well for subprojects. Luckily this is slowly changing, however, until then, some manual configuration may be required (see the snippets [below](#snippets) for examples). For best practices on preparing projects for CPM, see the [wiki](https://github.com/cpm-cmake/CPM.cmake/wiki/Preparing-projects-for-CPM.cmake).
 - **First version used** In diamond-shaped dependency graphs (e.g. `A` depends on `C`@1.1 and `B`, which itself depends on `C`@1.2 the first added dependency will be used (in this case `C`@1.1). In this case, B requires a newer version of `C` than `A`, so CPM will emit a warning. This can be easily resolved by adding a new version of the dependency in the outermost project, or by introducing a [package lock file](#package-lock).
 
 For projects with more complex needs and where an extra setup step doesn't matter, it may be worth to check out an external C++ package manager such as [vcpkg](https://github.com/microsoft/vcpkg), [conan](https://conan.io) or [hunter](https://github.com/ruslo/hunter).
@@ -143,7 +164,7 @@ The most notable features are:
 - [Package lock files](#package-lock) for easier transitive dependency management.
 - Dependencies can be overridden [per-build](#local-package-override) using CMake CLI parameters.
 
-ExternalProject works similarly as FetchContent, however waits with adding dependencies until build time. 
+ExternalProject works similarly as FetchContent, however waits with adding dependencies until build time.
 This has a quite a few disadvantages, especially as it makes using custom toolchains / cross-compiling very difficult and can lead to problems with nested dependencies.
 
 ## Options
@@ -174,11 +195,13 @@ CPM can be configured to use `find_package` to search for locally installed depe
 If the option `CPM_LOCAL_PACKAGES_ONLY` is set, CPM will emit an error if the dependency is not found locally.
 These options can also be set as environmental variables.
 
+In the case that `find_package` requires additional arguments, the parameter `FIND_PACKAGE_ARGUMENTS` may be specified in the `CPMAddPackage` call. The value of this parameter will be forwarded to `find_package`.
+
 ## Local package override
 
 Library developers are often in the situation where they work on a locally checked out dependency at the same time as on a consumer project.
 It is possible to override the consumer's dependency with the version by supplying the CMake option `CPM_<dependency name>_SOURCE` set to the absolute path of the local library.
-For example, to use the local version of the dependency `Dep` at the path `/path/to/dep`, the consumer can be built with the following command. 
+For example, to use the local version of the dependency `Dep` at the path `/path/to/dep`, the consumer can be built with the following command.
 
 ```bash
 cmake -Bbuild -DCPM_Dep_SOURCE=/path/to/dep
@@ -205,7 +228,7 @@ See the [wiki](https://github.com/cpm-cmake/CPM.cmake/wiki/Package-lock) for mor
 
 ## Built with CPM.cmake
 
-Some amazing projects that are built using the CPM.cmake package manager. 
+Some amazing projects that are built using the CPM.cmake package manager.
 If you know others, feel free to add them here through a PR.
 
 <table>
@@ -245,51 +268,25 @@ See the [wiki](https://github.com/cpm-cmake/CPM.cmake/wiki/More-Snippets) for mo
 ### [Catch2](https://github.com/catchorg/Catch2)
 
 ```cmake
-CPMAddPackage(
-  NAME Catch2
-  GITHUB_REPOSITORY catchorg/Catch2
-  VERSION 2.5.0
-)
+CPMAddPackage("gh:catchorg/Catch2@2.5.0")
 ```
 
 ### [Boost (via boost-cmake)](https://github.com/Orphis/boost-cmake)
 
 ```CMake
-CPMAddPackage(
-  NAME boost-cmake
-  GITHUB_REPOSITORY Orphis/boost-cmake
-  VERSION 1.67.0
-)
+CPMAddPackage("gh:Orphis/boost-cmake@1.67.0")
 ```
 
 ### [cxxopts](https://github.com/jarro2783/cxxopts)
 
 ```cmake
-CPMAddPackage(
-  NAME cxxopts
-  GITHUB_REPOSITORY jarro2783/cxxopts
-  VERSION 2.2.0
-  OPTIONS
-    "CXXOPTS_BUILD_EXAMPLES Off"
-    "CXXOPTS_BUILD_TESTS Off"
-)
+CPMAddPackage("gh:jarro2783/cxxopts@2.2.0")
 ```
 
 ### [Yaml-cpp](https://github.com/jbeder/yaml-cpp)
 
 ```CMake
-CPMAddPackage(
-  NAME yaml-cpp
-  GITHUB_REPOSITORY jbeder/yaml-cpp
-  # 0.6.2 uses deprecated CMake syntax
-  VERSION 0.6.3
-  # 0.6.3 is not released yet, so use a recent commit
-  GIT_TAG 012269756149ae99745b6dafefd415843d7420bb 
-  OPTIONS
-    "YAML_CPP_BUILD_TESTS Off"
-    "YAML_CPP_BUILD_CONTRIB Off"
-    "YAML_CPP_BUILD_TOOLS Off"
-)
+CPMAddPackage("gh:jbeder/yaml-cpp#yaml-cpp-0.6.3@0.6.3")
 ```
 
 ### [google/benchmark](https://github.com/google/benchmark)
@@ -298,14 +295,13 @@ CPMAddPackage(
 CPMAddPackage(
   NAME benchmark
   GITHUB_REPOSITORY google/benchmark
-  VERSION 1.4.1
-  OPTIONS
-    "BENCHMARK_ENABLE_TESTING Off"
+  VERSION 1.5.2
+  OPTIONS "BENCHMARK_ENABLE_TESTING Off"
 )
 
-if (benchmark_ADDED)
-  # compile with C++17
-  set_target_properties(benchmark PROPERTIES CXX_STANDARD 17)
+if(benchmark_ADDED)
+  # enable c++11 to avoid compilation errors
+  set_target_properties(benchmark PROPERTIES CXX_STANDARD 11)
 endif()
 ```
 
@@ -314,7 +310,7 @@ endif()
 ```cmake
 CPMAddPackage(
   NAME nlohmann_json
-  VERSION 3.6.1  
+  VERSION 3.6.1
   # the git repo is incredibly large, so we download the archived include directory
   URL https://github.com/nlohmann/json/releases/download/v3.6.1/include.zip
   URL_HASH SHA256=69cc88207ce91347ea530b227ff0776db82dcb8de6704e1a3d74f4841bc651cf
@@ -337,7 +333,7 @@ CPMAddPackage(
   DOWNLOAD_ONLY True
 )
 
-if(range-v3_ADDED) 
+if(range-v3_ADDED)
   add_library(range-v3 INTERFACE IMPORTED)
   target_include_directories(range-v3 INTERFACE "${range-v3_SOURCE_DIR}/include")
 endif()

cmake/CPM.cmake

@@ -134,6 +134,64 @@ endif()
 include(FetchContent)
 include(CMakeParseArguments)
 
+# Try to infer package name from git repository uri (path or url)
+function(cpm_package_name_from_git_uri URI RESULT)
+  if("${URI}" MATCHES "([^/:]+)/?.git/?$")
+    set(${RESULT}
+        ${CMAKE_MATCH_1}
+        PARENT_SCOPE
+    )
+  else()
+    unset(${RESULT} PARENT_SCOPE)
+  endif()
+endfunction()
+
+# Try to infer package name and version from a url
+function(cpm_package_name_and_ver_from_url url outName outVer)
+  if(url MATCHES "[/\\?]([a-zA-Z0-9_\\.-]+)\\.(tar|tar\\.gz|tar\\.bz2|zip|ZIP)(\\?|/|$)")
+    # We matched an archive
+    set(filename "${CMAKE_MATCH_1}")
+
+    if(filename MATCHES "([a-zA-Z0-9_\\.-]+)[_-]v?(([0-9]+\\.)*[0-9]+[a-zA-Z0-9]*)")
+      # We matched <name>-<version> (ie foo-1.2.3)
+      set(${outName}
+          "${CMAKE_MATCH_1}"
+          PARENT_SCOPE
+      )
+      set(${outVer}
+          "${CMAKE_MATCH_2}"
+          PARENT_SCOPE
+      )
+    elseif(filename MATCHES "(([0-9]+\\.)+[0-9]+[a-zA-Z0-9]*)")
+      # We couldn't find a name, but we found a version
+      #
+      # In many cases (which we don't handle here) the url would look something like
+      # `irrelevant/ACTUAL_PACKAGE_NAME/irrelevant/1.2.3.zip`. In such a case we can't possibly
+      # distinguish the package name from the irrelevant bits. Moreover if we try to match the
+      # package name from the filename, we'd get bogus at best.
+      unset(${outName} PARENT_SCOPE)
+      set(${outVer}
+          "${CMAKE_MATCH_1}"
+          PARENT_SCOPE
+      )
+    else()
+      # Boldly assume that the file name is the package name.
+      #
+      # Yes, something like `irrelevant/ACTUAL_NAME/irrelevant/download.zip` will ruin our day, but
+      # such cases should be quite rare. No popular service does this... we think.
+      set(${outName}
+          "${filename}"
+          PARENT_SCOPE
+      )
+      unset(${outVer} PARENT_SCOPE)
+    endif()
+  else()
+    # No ideas yet what to do with non-archives
+    unset(${outName} PARENT_SCOPE)
+    unset(${outVer} PARENT_SCOPE)
+  endif()
+endfunction()
+
 # Initialize logging prefix
 if(NOT CPM_INDENT)
   set(CPM_INDENT
@@ -240,8 +298,80 @@ function(cpm_check_if_package_already_added CPM_ARGS_NAME CPM_ARGS_VERSION CPM_A
   endif()
 endfunction()
 
+# Parse the argument of CPMAddPackage in case a single one was provided and convert it to a list of
+# arguments which can then be parsed idiomatically. For example gh:foo/bar@1.2.3 will be converted
+# to: GITHUB_REPOSITORY;foo/bar;VERSION;1.2.3
+function(cpm_parse_add_package_single_arg arg outArgs)
+  # Look for a scheme
+  if("${arg}" MATCHES "^([a-zA-Z]+):(.+)$")
+    string(TOLOWER "${CMAKE_MATCH_1}" scheme)
+    set(uri "${CMAKE_MATCH_2}")
+
+    # Check for CPM-specific schemes
+    if(scheme STREQUAL "gh")
+      set(out "GITHUB_REPOSITORY;${uri}")
+      set(packageType "git")
+    elseif(scheme STREQUAL "gl")
+      set(out "GITLAB_REPOSITORY;${uri}")
+      set(packageType "git")
+      # A CPM-specific scheme was not found. Looks like this is a generic URL so try to determine
+      # type
+    elseif(arg MATCHES ".git/?(@|#|$)")
+      set(out "GIT_REPOSITORY;${arg}")
+      set(packageType "git")
+    else()
+      # Fall back to a URL
+      set(out "URL;${arg}")
+      set(packageType "archive")
+
+      # We could also check for SVN since FetchContent supports it, but SVN is so rare these days.
+      # We just won't bother with the additional complexity it will induce in this function. SVN is
+      # done by multi-arg
+    endif()
+  else()
+    if(arg MATCHES ".git/?(@|#|$)")
+      set(out "GIT_REPOSITORY;${arg}")
+      set(packageType "git")
+    else()
+      # Give up
+      message(FATAL_ERROR "CPM: Can't determine package type of '${arg}'")
+    endif()
+  endif()
+
+  # For all packages we interpret @... as version. Only replace the last occurence. Thus URIs
+  # containing '@' can be used
+  string(REGEX REPLACE "@([^@]+)$" ";VERSION;\\1" out "${out}")
+
+  # Parse the rest according to package type
+  if(packageType STREQUAL "git")
+    # For git repos we interpret #... as a tag or branch or commit hash
+    string(REGEX REPLACE "#([^#]+)$" ";GIT_TAG;\\1" out "${out}")
+  elseif(packageType STREQUAL "archive")
+    # For archives we interpret #... as a URL hash.
+    string(REGEX REPLACE "#([^#]+)$" ";URL_HASH;\\1" out "${out}")
+    # We don't try to parse the version if it's not provided explicitly. cpm_get_version_from_url
+    # should do this at a later point
+  else()
+    # We should never get here. This is an assertion and hitting it means there's a bug in the code
+    # above. A packageType was set, but not handled by this if-else.
+    message(FATAL_ERROR "CPM: Unsupported package type '${packageType}' of '${arg}'")
+  endif()
+
+  set(${outArgs}
+      ${out}
+      PARENT_SCOPE
+  )
+endfunction()
+
 # Download and add a package from source
 function(CPMAddPackage)
+  list(LENGTH ARGN argnLength)
+  if(argnLength EQUAL 1)
+    cpm_parse_add_package_single_arg("${ARGN}" ARGN)
+
+    # The shorthand syntax implies EXCLUDE_FROM_ALL
+    set(ARGN "${ARGN};EXCLUDE_FROM_ALL;YES")
+  endif()
 
   set(oneValueArgs
       NAME
@@ -257,9 +387,11 @@ function(CPMAddPackage)
       FIND_PACKAGE_ARGUMENTS
       NO_CACHE
       GIT_SHALLOW
+      EXCLUDE_FROM_ALL
+      SOURCE_SUBDIR
   )
 
-  set(multiValueArgs OPTIONS)
+  set(multiValueArgs URL OPTIONS)
 
   cmake_parse_arguments(CPM_ARGS "" "${oneValueArgs}" "${multiValueArgs}" "${ARGN}")
 
@@ -290,6 +422,11 @@ function(CPMAddPackage)
     if(NOT DEFINED CPM_ARGS_GIT_TAG)
       set(CPM_ARGS_GIT_TAG v${CPM_ARGS_VERSION})
     endif()
+
+    # If a name wasn't provided, try to infer it from the git repo
+    if(NOT DEFINED CPM_ARGS_NAME)
+      cpm_package_name_from_git_uri(${CPM_ARGS_GIT_REPOSITORY} CPM_ARGS_NAME)
+    endif()
   endif()
 
   set(CPM_SKIP_FETCH FALSE)
@@ -302,6 +439,33 @@ function(CPMAddPackage)
     endif()
   endif()
 
+  if(DEFINED CPM_ARGS_URL)
+    # If a name or version aren't provided, try to infer them from the URL
+    list(GET CPM_ARGS_URL 0 firstUrl)
+    cpm_package_name_and_ver_from_url(${firstUrl} nameFromUrl verFromUrl)
+    # If we fail to obtain name and version from the first URL, we could try other URLs if any.
+    # However multiple URLs are expected to be quite rare, so for now we won't bother.
+
+    # If the caller provided their own name and version, they trump the inferred ones.
+    if(NOT DEFINED CPM_ARGS_NAME)
+      set(CPM_ARGS_NAME ${nameFromUrl})
+    endif()
+    if(NOT DEFINED CPM_ARGS_VERSION)
+      set(CPM_ARGS_VERSION ${verFromUrl})
+    endif()
+
+    list(APPEND CPM_ARGS_UNPARSED_ARGUMENTS URL "${CPM_ARGS_URL}")
+  endif()
+
+  # Check for required arguments
+
+  if(NOT DEFINED CPM_ARGS_NAME)
+    message(
+      FATAL_ERROR
+        "CPM: 'NAME' was not provided and couldn't be automatically inferred for package added with arguments: '${ARGN}'"
+    )
+  endif()
+
   # Check if package has been added before
   cpm_check_if_package_already_added(${CPM_ARGS_NAME} "${CPM_ARGS_VERSION}" "${CPM_ARGS_OPTIONS}")
   if(CPM_PACKAGE_ALREADY_ADDED)
@@ -386,9 +550,11 @@ function(CPMAddPackage)
       set(${CPM_ARGS_NAME}_BINARY_DIR ${CMAKE_BINARY_DIR}/_deps/${lower_case_name}-build)
       set(${CPM_ARGS_NAME}_ADDED YES)
       set(${CPM_ARGS_NAME}_SOURCE_DIR ${download_directory})
-      if(NOT CPM_ARGS_DOWNLOAD_ONLY AND EXISTS ${download_directory}/CMakeLists.txt)
-        add_subdirectory(${download_directory} ${${CPM_ARGS_NAME}_BINARY_DIR})
-      endif()
+      cpm_add_subdirectory(
+        "${CPM_ARGS_NAME}" "${DOWNLOAD_ONLY}"
+        "${${CPM_ARGS_NAME}_SOURCE_DIR}/${CPM_ARGS_SOURCE_SUBDIR}" "${${CPM_ARGS_NAME}_BINARY_DIR}"
+        "${CPM_ARGS_EXCLUDE_FROM_ALL}"
+      )
       set(CPM_SKIP_FETCH TRUE)
       set(PACKAGE_INFO "${PACKAGE_INFO} at ${download_directory}")
     else()
@@ -427,7 +593,12 @@ function(CPMAddPackage)
     cpm_declare_fetch(
       "${CPM_ARGS_NAME}" "${CPM_ARGS_VERSION}" "${PACKAGE_INFO}" "${CPM_ARGS_UNPARSED_ARGUMENTS}"
     )
-    cpm_fetch_package("${CPM_ARGS_NAME}" "${DOWNLOAD_ONLY}")
+    cpm_fetch_package("${CPM_ARGS_NAME}")
+    cpm_add_subdirectory(
+      "${CPM_ARGS_NAME}" "${DOWNLOAD_ONLY}"
+      "${${CPM_ARGS_NAME}_SOURCE_DIR}/${CPM_ARGS_SOURCE_SUBDIR}" "${${CPM_ARGS_NAME}_BINARY_DIR}"
+      "${CPM_ARGS_EXCLUDE_FROM_ALL}"
+    )
     cpm_get_fetch_properties("${CPM_ARGS_NAME}")
   endif()
 
@@ -550,24 +721,44 @@ function(cpm_get_fetch_properties PACKAGE)
   )
 endfunction()
 
-# downloads a previously declared package via FetchContent
-function(cpm_fetch_package PACKAGE DOWNLOAD_ONLY)
+# adds a package as a subdirectory if viable, according to provided options
+function(cpm_add_subdirectory PACKAGE DOWNLOAD_ONLY SOURCE_DIR BINARY_DIR EXCLUDE)
+  if(NOT DOWNLOAD_ONLY AND EXISTS ${SOURCE_DIR}/CMakeLists.txt)
+    if(EXCLUDE)
+      set(addSubdirectoryExtraArgs EXCLUDE_FROM_ALL)
+    else()
+      set(addSubdirectoryExtraArgs "")
+    endif()
+    set(CPM_OLD_INDENT "${CPM_INDENT}")
+    set(CPM_INDENT "${CPM_INDENT} ${PACKAGE}:")
+    add_subdirectory(${SOURCE_DIR} ${BINARY_DIR} ${addSubdirectoryExtraArgs})
+    set(CPM_INDENT "${CPM_OLD_INDENT}")
+  endif()
+endfunction()
+
+# downloads a previously declared package via FetchContent and exports the variables
+# `${PACKAGE}_SOURCE_DIR` and `${PACKAGE}_BINARY_DIR` to the parent scope
+function(cpm_fetch_package PACKAGE)
   if(${CPM_DRY_RUN})
     message(STATUS "${CPM_INDENT} package ${PACKAGE} not fetched (dry run)")
     return()
   endif()
 
-  if(DOWNLOAD_ONLY)
-    FetchContent_GetProperties(${PACKAGE})
-    if(NOT ${PACKAGE}_POPULATED)
-      FetchContent_Populate(${PACKAGE})
-    endif()
-  else()
-    set(CPM_OLD_INDENT "${CPM_INDENT}")
-    set(CPM_INDENT "${CPM_INDENT} ${PACKAGE}:")
-    FetchContent_MakeAvailable(${PACKAGE})
-    set(CPM_INDENT "${CPM_OLD_INDENT}")
+  FetchContent_GetProperties(${PACKAGE})
+
+  if(NOT ${lower_case_name}_POPULATED)
+    FetchContent_Populate(${PACKAGE})
   endif()
+
+  string(TOLOWER "${PACKAGE}" lower_case_name)
+  set(${PACKAGE}_SOURCE_DIR
+      ${${lower_case_name}_SOURCE_DIR}
+      PARENT_SCOPE
+  )
+  set(${PACKAGE}_BINARY_DIR
+      ${${lower_case_name}_BINARY_DIR}
+      PARENT_SCOPE
+  )
 endfunction()
 
 # splits a package option

cmake/testing.cmake

@@ -3,13 +3,25 @@ function(ASSERT_EQUAL)
     message(FATAL_ERROR "assertion failed: invalid argument count: ${ARGC}")
   endif()
 
-  if(NOT ${ARGV0} STREQUAL ${ARGV1})
+  if(NOT "${ARGV0}" STREQUAL "${ARGV1}")
     message(FATAL_ERROR "assertion failed: '${ARGV0}' != '${ARGV1}'")
   else()
     message(STATUS "test passed: '${ARGV0}' == '${ARGV1}'")
   endif()
 endfunction()
 
+function(ASSERT_NOT_EQUAL)
+  if(NOT ARGC EQUAL 2)
+    message(FATAL_ERROR "assertion failed: invalid argument count: ${ARGC}")
+  endif()
+
+  if("${ARGV0}" STREQUAL "${ARGV1}")
+    message(FATAL_ERROR "assertion failed: '${ARGV0}' == '${ARGV1}'")
+  else()
+    message(STATUS "test passed: '${ARGV0}' != '${ARGV1}'")
+  endif()
+endfunction()
+
 function(ASSERT_EMPTY)
   if(NOT ARGC EQUAL 0)
     message(FATAL_ERROR "assertion failed: input ${ARGC} not empty: '${ARGV}'")
@@ -24,6 +36,14 @@ function(ASSERT_DEFINED KEY)
   endif()
 endfunction()
 
+function(ASSERT_NOT_DEFINED KEY)
+  if(DEFINED ${KEY})
+    message(FATAL_ERROR "assertion failed: '${KEY}' is defiend")
+  else()
+    message(STATUS "test passed: '${KEY}' is not defined")
+  endif()
+endfunction()
+
 function(ASSERT_TRUTHY KEY)
   if(${${KEY}})
     message(STATUS "test passed: '${KEY}' is set truthy")

examples/asio-standalone/CMakeLists.txt

@@ -8,12 +8,7 @@ include(../../cmake/CPM.cmake)
 
 find_package(Threads REQUIRED)
 
-CPMAddPackage(
-  NAME asio
-  VERSION 1.18.1
-  GITHUB_REPOSITORY chriskohlhoff/asio
-  GIT_TAG asio-1-18-1 # asio uses non-standard version tag, we must specify GIT_TAG
-)
+CPMAddPackage("gh:chriskohlhoff/asio#asio-1-18-1@1.18.1")
 
 # ASIO doesn't use CMake, we have to configure it manually. Extra notes for using on Windows:
 #

examples/benchmark/CMakeLists.txt

@@ -6,11 +6,7 @@ project(CPMExampleBenchmark)
 
 include(../../cmake/CPM.cmake)
 
-CPMAddPackage(
-  NAME fibonacci
-  GITLAB_REPOSITORY TheLartians/Fibonacci
-  VERSION 2.0
-)
+CPMAddPackage("gh:cpm-cmake/testpack-fibonacci@2.0")
 
 CPMAddPackage(
   NAME benchmark
@@ -20,7 +16,7 @@ CPMAddPackage(
 )
 
 if(benchmark_ADDED)
-  # Don't use C++14 because it doesn't work in some configurations.
+  # enable c++11 to avoid compilation errors
   set_target_properties(benchmark PROPERTIES CXX_STANDARD 11)
 endif()
 

examples/boost/CMakeLists.txt

@@ -15,6 +15,7 @@ CPMFindPackage(
   NAME Boost
   GITHUB_REPOSITORY Orphis/boost-cmake
   VERSION 1.67.0
+  # setting FIND_PACKAGE_ARGUMENTS allow usage with `CPM_USE_LOCAL_PACKAGES`
   FIND_PACKAGE_ARGUMENTS "COMPONENTS system"
 )
 

examples/catch2/CMakeLists.txt

@@ -6,17 +6,8 @@ project(CPMExampleCatch2)
 
 include(../../cmake/CPM.cmake)
 
-CPMAddPackage(
-  NAME fibonacci
-  GITHUB_REPOSITORY TheLartians/Fibonacci
-  VERSION 2.0
-)
-
-CPMAddPackage(
-  NAME Catch2
-  GITHUB_REPOSITORY catchorg/Catch2
-  VERSION 2.13.4
-)
+CPMAddPackage("gh:cpm-cmake/testpack-fibonacci@2.0")
+CPMAddPackage("gh:catchorg/Catch2@2.13.4")
 
 # ---- Create binary ----
 

examples/cxxopts/CMakeLists.txt

@@ -6,12 +6,7 @@ project(CPMExampleCXXOpts)
 
 include(../../cmake/CPM.cmake)
 
-CPMAddPackage(
-  NAME cxxopts
-  GITHUB_REPOSITORY jarro2783/cxxopts
-  VERSION 2.2.0
-  OPTIONS "CXXOPTS_BUILD_EXAMPLES Off" "CXXOPTS_BUILD_TESTS Off"
-)
+CPMAddPackage("gh:jarro2783/cxxopts@2.2.0")
 
 # ---- Create binary ----
 

examples/doctest/CMakeLists.txt

@@ -6,17 +6,8 @@ project(CPMExampleDoctest)
 
 include(../../cmake/CPM.cmake)
 
-CPMAddPackage(
-  NAME fibonacci
-  GITLAB_REPOSITORY TheLartians/Fibonacci
-  VERSION 2.0
-)
-
-CPMAddPackage(
-  NAME doctest
-  GITHUB_REPOSITORY onqtam/doctest
-  GIT_TAG 2.4.5
-)
+CPMAddPackage("gh:cpm-cmake/testpack-fibonacci@2.0")
+CPMAddPackage("gh:onqtam/doctest#2.4.5")
 
 # ---- Create binary ----
 

examples/fmt/CMakeLists.txt

@@ -6,11 +6,7 @@ project(CPMJSONExample)
 
 include(../../cmake/CPM.cmake)
 
-CPMAddPackage(
-  NAME fmt
-  GIT_TAG 7.1.3
-  GITHUB_REPOSITORY fmtlib/fmt
-)
+CPMAddPackage("gh:fmtlib/fmt#7.1.3")
 
 # ---- Executable ----
 

examples/gtest/CMakeLists.txt

@@ -6,11 +6,7 @@ project(CPMExampleGtest)
 
 include(../../cmake/CPM.cmake)
 
-CPMAddPackage(
-  NAME fibonacci
-  GITLAB_REPOSITORY TheLartians/Fibonacci
-  VERSION 2.0
-)
+CPMAddPackage("gh:cpm-cmake/testpack-fibonacci@2.0")
 
 CPMAddPackage(
   NAME googletest

examples/linenoise/CMakeLists.txt

@@ -6,11 +6,7 @@ project(CPMlinenoiseExample)
 
 include(../../cmake/CPM.cmake)
 
-CPMAddPackage(
-  NAME linenoise
-  GIT_TAG 1.0
-  GITHUB_REPOSITORY antirez/linenoise
-)
+CPMAddPackage("gh:antirez/linenoise#1.0")
 
 if(linenoise_ADDED)
   add_library(linenoise ${linenoise_SOURCE_DIR}/linenoise.c)

examples/spdlog/CMakeLists.txt

@@ -6,11 +6,7 @@ project(CPMSpdlogExample)
 
 include(../../cmake/CPM.cmake)
 
-CPMAddPackage(
-  NAME spdlog
-  GITHUB_REPOSITORY gabime/spdlog
-  VERSION 1.8.2
-)
+CPMAddPackage("gh:gabime/spdlog@1.8.2")
 
 # ---- Executable ----
 

examples/yaml/CMakeLists.txt

@@ -6,13 +6,7 @@ project(CPMYamlExample)
 
 include(../../cmake/CPM.cmake)
 
-CPMAddPackage(
-  NAME yaml-cpp
-  GIT_REPOSITORY https://github.com/jbeder/yaml-cpp.git
-  VERSION 0.6.3
-  GIT_TAG yaml-cpp-0.6.3
-  OPTIONS "YAML_CPP_BUILD_TESTS Off" "YAML_CPP_BUILD_CONTRIB Off" "YAML_CPP_BUILD_TOOLS Off"
-)
+CPMAddPackage("gh:jbeder/yaml-cpp#yaml-cpp-0.6.3@0.6.3")
 
 # ---- Executable ----
 

test/unit/broken_dependency/.gitignore

@@ -0,0 +1,2 @@
+/CMakeLists.txt
+/package-lock.cmake

test/unit/broken_dependency/CMakeLists.txt.in

@@ -0,0 +1,13 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMTest)
+
+# ---- Dependencies ----
+
+include(@CPM_PATH@/CPM.cmake)
+
+CPMAddPackage(
+  NAME BrokenDependency
+  SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/dependency
+  EXCLUDE_FROM_ALL @EXCLUDE_FROM_ALL@
+)

test/unit/broken_dependency/dependency/CMakeLists.txt

@@ -0,0 +1,3 @@
+project(BrokenDependency)
+
+add_custom_target(error ALL ${CMAKE_COMMAND} -E false)

test/unit/exclude_from_all.cmake

@@ -0,0 +1,35 @@
+include(CMakePackageConfigHelpers)
+include(${CPM_PATH}/testing.cmake)
+
+set(TEST_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/exclude_from_all)
+
+function(init_project EXCLUDE_FROM_ALL)
+  configure_package_config_file(
+    "${CMAKE_CURRENT_LIST_DIR}/broken_dependency/CMakeLists.txt.in"
+    "${CMAKE_CURRENT_LIST_DIR}/broken_dependency/CMakeLists.txt"
+    INSTALL_DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/junk
+  )
+
+  execute_process(
+    COMMAND ${CMAKE_COMMAND} "-H${CMAKE_CURRENT_LIST_DIR}/broken_dependency" "-B${TEST_BUILD_DIR}"
+    RESULT_VARIABLE ret
+  )
+
+  assert_equal(${ret} "0")
+endfunction()
+
+function(build_project expected_success)
+  execute_process(COMMAND ${CMAKE_COMMAND} "--build" "${TEST_BUILD_DIR}" RESULT_VARIABLE ret)
+
+  if(expected_success)
+    assert_equal(${ret} 0)
+  else()
+    assert_not_equal(${ret} 0)
+  endif()
+endfunction()
+
+init_project(FALSE)
+build_project(FALSE)
+
+init_project(TRUE)
+build_project(TRUE)

test/unit/local_dependency/SubdirCMakeLists.txt.in

@@ -0,0 +1,17 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMTest)
+
+# ---- Dependencies ----
+
+include(@CPM_PATH@/CPM.cmake)
+
+CPMAddPackage(
+  NAME Dependency
+  SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/dependency
+  SOURCE_SUBDIR inner
+)
+
+# ---- Call inner dependency method to validate correct addition of subdirectory ----
+
+inner_dependency_function()

test/unit/local_dependency/dependency/inner/CMakeLists.txt

@@ -0,0 +1,3 @@
+function(inner_dependency_function)
+  message("called inner method")
+endfunction()

test/unit/package_name_and_ver_from_url.cmake

@@ -0,0 +1,60 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+include(${CPM_PATH}/CPM.cmake)
+include(${CPM_PATH}/testing.cmake)
+
+cpm_package_name_and_ver_from_url("https://example.com/coolpack-1.2.3.zip" name ver)
+assert_equal("coolpack" ${name})
+assert_equal("1.2.3" ${ver})
+
+cpm_package_name_and_ver_from_url("https://example.com/cool-pack-v1.3.tar.gz" name ver)
+assert_equal("cool-pack" ${name})
+assert_equal("1.3" ${ver})
+
+cpm_package_name_and_ver_from_url(
+  "https://subd.zip.com/download.php?Cool.Pack-v1.2.3rc0.tar" name ver
+)
+assert_equal("Cool.Pack" ${name})
+assert_equal("1.2.3rc0" ${ver})
+
+cpm_package_name_and_ver_from_url(
+  "http://evil-1.2.tar.gz.com/Plan9_1.2.3a.tar.bz2?download" name ver
+)
+assert_equal("Plan9" ${name})
+assert_equal("1.2.3a" ${ver})
+
+cpm_package_name_and_ver_from_url(
+  "http://evil-1.2.tar.gz.com/Plan_9-1.2.3a.tar.bz2?download" name ver
+)
+assert_equal("Plan_9" ${name})
+assert_equal("1.2.3a" ${ver})
+
+cpm_package_name_and_ver_from_url(
+  "http://evil-1.2.tar.gz.com/Plan-9_1.2.3a.tar.bz2?download" name ver
+)
+assert_equal("Plan-9" ${name})
+assert_equal("1.2.3a" ${ver})
+
+cpm_package_name_and_ver_from_url("https://sf.com/distrib/SFLib-0.999.4.tar.gz/download" name ver)
+assert_equal("SFLib" ${name})
+assert_equal("0.999.4" ${ver})
+
+cpm_package_name_and_ver_from_url("https://example.com/coolpack/v5.6.5rc44.zip" name ver)
+assert_not_defined(name)
+assert_equal("5.6.5rc44" ${ver})
+
+cpm_package_name_and_ver_from_url("evil-1.3.zip.com/coolpack/release999.000beta.ZIP" name ver)
+assert_not_defined(name)
+assert_equal("999.000beta" ${ver})
+
+cpm_package_name_and_ver_from_url("https://example.com/Foo55.tar.gz" name ver)
+assert_equal("Foo55" ${name})
+assert_not_defined(ver)
+
+cpm_package_name_and_ver_from_url("https://example.com/foo" name ver)
+assert_not_defined(name)
+assert_not_defined(ver)
+
+cpm_package_name_and_ver_from_url("example.zip.com/foo" name ver)
+assert_not_defined(name)
+assert_not_defined(ver)

test/unit/package_name_from_git_uri.cmake

@@ -0,0 +1,28 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+include(${CPM_PATH}/CPM.cmake)
+include(${CPM_PATH}/testing.cmake)
+
+cpm_package_name_from_git_uri("https://github.com/cpm-cmake/CPM.cmake.git" name)
+assert_equal("CPM.cmake" ${name})
+
+cpm_package_name_from_git_uri("ssh://user@host.xz:123/path/to/pkg.git/" name)
+assert_equal("pkg" ${name})
+
+cpm_package_name_from_git_uri("git://host.xz/path/to/pkg.git" name)
+assert_equal("pkg" ${name})
+
+cpm_package_name_from_git_uri("git@host.xz:cool-pkg.git" name)
+assert_equal("cool-pkg" ${name})
+
+cpm_package_name_from_git_uri("file:///path/to/pkg33.git" name)
+assert_equal("pkg33" ${name})
+
+cpm_package_name_from_git_uri("../local-repo/.git" name)
+assert_equal("local-repo" ${name})
+
+cpm_package_name_from_git_uri("asdf" name)
+assert_not_defined(name)
+
+cpm_package_name_from_git_uri("/something.git/stuff" name)
+assert_not_defined(name)

test/unit/parse_add_package_single_arg.cmake

@@ -0,0 +1,65 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+include(${CPM_PATH}/CPM.cmake)
+include(${CPM_PATH}/testing.cmake)
+
+cpm_parse_add_package_single_arg("gh:cpm-cmake/CPM.cmake" args)
+assert_equal("GITHUB_REPOSITORY;cpm-cmake/CPM.cmake" "${args}")
+
+cpm_parse_add_package_single_arg("gh:cpm-cmake/CPM.cmake@1.2.3" args)
+assert_equal("GITHUB_REPOSITORY;cpm-cmake/CPM.cmake;VERSION;1.2.3" "${args}")
+
+cpm_parse_add_package_single_arg("gh:cpm-cmake/CPM.cmake#master" args)
+assert_equal("GITHUB_REPOSITORY;cpm-cmake/CPM.cmake;GIT_TAG;master" "${args}")
+
+cpm_parse_add_package_single_arg("gh:cpm-cmake/CPM.cmake@0.20.3#asdf" args)
+assert_equal("GITHUB_REPOSITORY;cpm-cmake/CPM.cmake;VERSION;0.20.3;GIT_TAG;asdf" "${args}")
+
+cpm_parse_add_package_single_arg("gh:a/b#c@d" args)
+assert_equal("GITHUB_REPOSITORY;a/b;GIT_TAG;c;VERSION;d" "${args}")
+
+cpm_parse_add_package_single_arg("gh:foo#c@d" args)
+assert_equal("GITHUB_REPOSITORY;foo;GIT_TAG;c;VERSION;d" "${args}")
+
+cpm_parse_add_package_single_arg("gh:Foo@5" args)
+assert_equal("GITHUB_REPOSITORY;Foo;VERSION;5" "${args}")
+
+cpm_parse_add_package_single_arg("gl:foo/bar" args)
+assert_equal("GITLAB_REPOSITORY;foo/bar" "${args}")
+
+cpm_parse_add_package_single_arg("gl:foo/Bar" args)
+assert_equal("GITLAB_REPOSITORY;foo/Bar" "${args}")
+
+cpm_parse_add_package_single_arg("https://github.com/cpm-cmake/CPM.cmake.git@0.30.5" args)
+assert_equal("GIT_REPOSITORY;https://github.com/cpm-cmake/CPM.cmake.git;VERSION;0.30.5" "${args}")
+
+cpm_parse_add_package_single_arg("git@host.xz:user/pkg.git@0.1.2" args)
+assert_equal("GIT_REPOSITORY;git@host.xz:user/pkg.git;VERSION;0.1.2" "${args}")
+
+cpm_parse_add_package_single_arg("git@host.xz:user/pkg.git@0.1.2#rc" args)
+assert_equal("GIT_REPOSITORY;git@host.xz:user/pkg.git;VERSION;0.1.2;GIT_TAG;rc" "${args}")
+
+cpm_parse_add_package_single_arg(
+  "ssh://user@host.xz:123/path/to/pkg.git#fragment@1.2.3#branch" args
+)
+assert_equal(
+  "GIT_REPOSITORY;ssh://user@host.xz:123/path/to/pkg.git#fragment;VERSION;1.2.3;GIT_TAG;branch"
+  "${args}"
+)
+
+cpm_parse_add_package_single_arg("https://example.org/foo.tar.gz" args)
+assert_equal("URL;https://example.org/foo.tar.gz" "${args}")
+
+cpm_parse_add_package_single_arg("https://example.org/foo.tar.gz#baadf00d@1.2.0" args)
+assert_equal("URL;https://example.org/foo.tar.gz;URL_HASH;baadf00d;VERSION;1.2.0" "${args}")
+
+cpm_parse_add_package_single_arg("https://example.org/foo.tar.gz#MD5=baadf00d" args)
+assert_equal("URL;https://example.org/foo.tar.gz;URL_HASH;MD5=baadf00d" "${args}")
+
+cpm_parse_add_package_single_arg("https://example.org/Foo.zip#SHA3_512=1337" args)
+assert_equal("URL;https://example.org/Foo.zip;URL_HASH;SHA3_512=1337" "${args}")
+
+cpm_parse_add_package_single_arg("ftp://user:pass@server/pathname.zip#fragment#0ddb411@0" args)
+assert_equal(
+  "URL;ftp://user:pass@server/pathname.zip#fragment;URL_HASH;0ddb411;VERSION;0" "${args}"
+)

test/unit/remote_dependency/CMakeLists.txt.in

@@ -12,7 +12,7 @@ include(@CPM_PATH@/CPM.cmake)
 
 CPMAddPackage(
   NAME fibonacci
-  GIT_REPOSITORY https://github.com/TheLartians/Fibonacci.git
+  GIT_REPOSITORY https://github.com/cpm-cmake/testpack-fibonacci.git
   VERSION @FIBONACCI_VERSION@
   @FIBONACCI_PACKAGE_ARGS@
 )

test/unit/subdir.cmake

@@ -0,0 +1,17 @@
+include(CMakePackageConfigHelpers)
+include(${CPM_PATH}/testing.cmake)
+
+set(TEST_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/source_dir)
+
+configure_package_config_file(
+  "${CMAKE_CURRENT_LIST_DIR}/local_dependency/SubdirCMakeLists.txt.in"
+  "${CMAKE_CURRENT_LIST_DIR}/local_dependency/CMakeLists.txt"
+  INSTALL_DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/junk
+)
+
+execute_process(
+  COMMAND ${CMAKE_COMMAND} "-H${CMAKE_CURRENT_LIST_DIR}/local_dependency" "-B${TEST_BUILD_DIR}"
+  RESULT_VARIABLE ret
+)
+
+assert_equal(${ret} "0")