Add CPM_SOURCE_CACHE environmental variable support and keep existing sources (#83)

* read CPM_SOURCE_CACHE from environment

* update readme

* cleanup

* add cache tests

.gitignore

@@ -1,10 +1,3 @@
-CMakeCache.txt
-CMakeFiles
-CMakeScripts
-Testing
-Makefile
-cmake_install.cmake
-install_manifest.txt
-compile_commands.json
-CTestTestfile.cmake
-build
+/build*
+/.vscode
+*.DS_Store

.travis.yml

@@ -1,4 +1,3 @@
-
 language: cpp
 sudo: require
 dist: xenial
@@ -17,7 +16,7 @@ matrix:
       addons: &gcc8
         apt:
           sources: *all_sources
-          packages: 
+          packages:
             - g++-8
       env:
         - MATRIX_EVAL="export CC=gcc-8; export CXX=g++-8;"
@@ -25,11 +24,11 @@ matrix:
     - os: linux
       compiler: clang
       addons:
-          apt:
-              sources: *all_sources
-              packages:
-                - g++-8
-                - clang-6.0
+        apt:
+          sources: *all_sources
+          packages:
+            - g++-8
+            - clang-6.0
       env:
         - MATRIX_EVAL="export CC=clang-6.0; export CXX=clang++-6.0;"
 
@@ -38,11 +37,14 @@ before_install:
   - eval "${MATRIX_EVAL}"
   - echo "CC=$CC CXX=$CXX"
   # Install a supported cmake version (>= 3.14)
-  - wget -O cmake.sh https://cmake.org/files/v3.14/cmake-3.14.0-Linux-x86_64.sh 
+  - wget -O cmake.sh https://cmake.org/files/v3.14/cmake-3.14.0-Linux-x86_64.sh
   - sudo sh cmake.sh --skip-license --exclude-subdir --prefix=/usr/local
   - export PATH=/usr/local/bin:$PATH
   - cmake --version
 
 script:
-  - python3 examples/run_all.py
- 
+  # unit tests
+  - cmake -Htest -Bbuild/test
+  - CTEST_OUTPUT_ON_FAILURE=1 cmake --build build/test --target test
+  # examples
+  - python3 examples/build_all.py

README.md

@@ -1,23 +1,29 @@
 [![Build Status](https://travis-ci.com/TheLartians/CPM.svg?branch=master)](https://travis-ci.com/TheLartians/CPM)
 
-# CPM
+<p align="center">
+  <img src="./logo/CPM.png" height="100" />
+</p>
 
-CPM is a CMake script that adds dependency management capabilities to CMake. 
-It's built as an extension of CMake's [FetchContent](https://cmake.org/cmake/help/latest/module/FetchContent.html) module that adds version control and simpler usage.
+# Setup-free CMake dependency management
 
-## Supported projects
+CPM is a CMake script that adds dependency management capabilities to CMake.
+It's built as a wrapper around CMake's [FetchContent](https://cmake.org/cmake/help/latest/module/FetchContent.html) module that adds version control and a simple API.
 
-Any project that you can add via `add_subdirectory` should already work with CPM.
+## Manage everything
+
+Anything can be added as a version-controlled dependency though CPM, no packaging required.
+Projects using CMake are automatically configured and their targets can be used immediately.
+For everything else, a target can be created manually (see below).
 
 ## Usage
 
-After `CPM.cmake` has been added to your project, the function `CPMAddPackage` can be used to fetch and configure all dependencies.
-Afterwards all targets defined in the dependencies can be used.
-`CPMAddPackage` takes the following named arguments.
+After `CPM.cmake` has been [added](#adding-cpm) to your project, the function `CPMAddPackage` can be used to fetch and configure a dependency.
+Afterwards, any targets defined in the dependency can be used directly.
+`CPMAddPackage` takes the following named parameters.
 
 ```cmake
 CPMAddPackage(
-  NAME          # The name of the dependency (should be chosen to match the main target's name)
+  NAME          # The unique name of the dependency (should be the main target's name)
   VERSION       # The minimum version of the dependency (optional, defaults to 0)
   OPTIONS       # Configuration options passed to the dependency (optional)
   DOWNLOAD_ONLY # If set, the project is downloaded, but not configured (optional)
@@ -25,9 +31,9 @@ CPMAddPackage(
 )
 ```
 
-The origin is usually specified by a `GIT_REPOSITORY`, but [svn revisions and direct URLs are also supported](https://cmake.org/cmake/help/latest/module/FetchContent.html#declaring-content-details).
-If `GIT_TAG` hasn't been explicitly specified it defaults to `v(VERSION)`, a common convention for github projects.
-`GIT_TAG` can also be set to a branch name such as `master` to download the most recent version.
+The origin may be specified by a `GIT_REPOSITORY`, but other sources, such as direct URLs, are [also supported](https://cmake.org/cmake/help/v3.11/module/ExternalProject.html#external-project-definition).
+If `GIT_TAG` hasn't been explicitly specified it defaults to `v(VERSION)`, a common convention for git projects.
+`GIT_TAG` can also be set to a specific commit or a branch name such as `master` to download the most recent version.
 
 Besides downloading and to configuring the dependency, the following variables are defined in the local scope, where `(DEPENDENCY)` is the name of the dependency.
 
@@ -35,7 +41,7 @@ Besides downloading and to configuring the dependency, the following variables a
 - `(DEPENDENCY)_BINARY_DIR` is the path to the build directory of the dependency.
 - `(DEPENDENCY)_ADDED` is set to `YES` if the dependency has not been added before, otherwise it is set to `NO`.
 
-## Full Example
+## Full CMakeLists Example
 
 ```cmake
 cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
@@ -43,44 +49,77 @@ cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
 # create project
 project(MyProject)
 
+# add executable
+add_executable(tests tests.cpp)
+
 # add dependencies
 include(cmake/CPM.cmake)
 
 CPMAddPackage(
-  NAME LarsParser
-  VERSION 1.8
-  GIT_REPOSITORY https://github.com/TheLartians/Parser.git
-  OPTIONS
-    "LARS_PARSER_BUILD_GLUE_EXTENSION ON"
+  NAME Catch2
+  GITHUB_REPOSITORY catchorg/Catch2
+  VERSION 2.5.0
 )
 
-# add executable
-add_executable(myProject myProject.cpp)
-set_target_properties(myProject PROPERTIES CXX_STANDARD 17)
-target_link_libraries(myProject LarsParser)
+# link dependencies
+target_link_libraries(tests Catch2)
 ```
 
-See the [examples directory](https://github.com/TheLartians/CPM/tree/master/examples) for more examples with source code.
+See the [examples directory](https://github.com/TheLartians/CPM/tree/master/examples) for more many examples with source code or the [wiki](https://github.com/TheLartians/CPM/wiki/More-Snippets) for many example snippets.
 
 ## Adding CPM
 
 To add CPM to your current project, simply add `cmake/CPM.cmake` to your project's `cmake` directory. The command below will perform this automatically.
 
 ```bash
+mkdir -p cmake
 wget -O cmake/CPM.cmake https://raw.githubusercontent.com/TheLartians/CPM/master/cmake/CPM.cmake
 ```
 
+You can even use CMake to download CPM for you. See the [wiki](https://github.com/TheLartians/CPM/wiki/Adding-CPM) for more details.
+
 ## Updating CPM
 
-To update CPM to the newest version, simply update the script in the project's cmake directory, for example by running the command above. Dependencies using CPM will automatically use the updated script of the outermost project.
+To update CPM to the newest version, update the script in the project's root directory, for example by running the command above. Dependencies using CPM will automatically use the updated script of the outermost project.
 
-## Snipplets
+## Advantages
+
+- **Small and reusable projects** CPM takes care of all project dependencies, allowing developers to focus on creating small, well-tested frameworks.
+- **Cross-Platform** CPM adds projects via `add_subdirectory`, which is compatible with all CMake toolchains and generators.
+- **Reproducable builds** By using versioning via git tags it is ensured that a project will always be in the same state everywhere.
+- **Recursive dependencies** Ensures that no dependency is added twice and is added in the minimum required version.
+- **Plug-and-play** No need to install anything. Just add the script to your project and you're good to go.
+- **No packaging required** There is a good chance your existing projects already work as CPM dependencies.
+- **Simple source distribution** CPM makes including projects with source files and dependencies easy, reducing the need for monolithic header files or git submodules.
+
+## Limitations
+
+- **No pre-built binaries** For every new build directory, all dependencies are initially downloaded and built from scratch. To avoid extra downloads it is recommend to set the [`CPM_SOURCE_CACHE`](#CPM_SOURCE_CACHE) environmental variable. Using a caching compiler such as [sccahe](https://github.com/mozilla/sccache) can drastically reduce build time.
+- **Dependent on good CMakeLists** Many libraries do not have CMakeLists that work well for subprojects. Luckily this is slowly changing, however, until then, some manual configuration may be required (see the snippets [below](#snippets)). For best practices on preparing your projects for CPM, see the [wiki](https://github.com/TheLartians/CPM/wiki/Preparing-projects-for-CPM). 
+- **First version used** In diamond-shaped dependency graphs (e.g. `A` depends on `C`@1.1 and `B`, which itself depends on `C`@1.2 the first added dependency will be used (in this case `C`@1.1). In this case, B requires a newer version of `C` than `A`, so CPM will emit an error. This can be resolved by updating the outermost dependency version.
+
+For projects with more complex needs and where an extra setup step doesn't matter, it is worth to check out fully featured C++ package managers such as [conan](https://conan.io), [vcpkg](https://github.com/microsoft/vcpkg) or [hunter](https://github.com/ruslo/hunter).
+Support for these package managers is also [planned](https://github.com/TheLartians/CPM/issues/51) for a future version of CPM.
+
+## Options
+
+### CPM_SOURCE_CACHE
+
+To avoid re-downloading dependencies, CPM has an option `CPM_SOURCE_CACHE` that can be passed to CMake as `-DCPM_SOURCE_CACHE=<path to an external download directory>`.
+It can also be defined system-wide as an environmental variable, by adding `export CPM_SOURCE_CACHE=$HOME/.cache/CPM` to your `.bashrc` or `.bash_profile`.
+Note that passing the variable as a configure option to CMake will always override the value set by the environmental variable.
+
+### CPM_USE_LOCAL_PACKAGES
+
+CPM can be configured to use `find_package` to search for locally installed dependencies first by setting the CMake option `CPM_USE_LOCAL_PACKAGES`.
+If the option `CPM_LOCAL_PACKAGES_ONLY` is set, CPM will emit an error if the dependency is not found locally.
+
+## Snippets
 
 These examples demonstrate how to include some well-known projects with CPM.
+See the [wiki](https://github.com/TheLartians/CPM/wiki/More-Snippets) for more snippets.
 
-### [Catch2](https://github.com/catchorg/Catch2.git)
-
-Has a CMakeLists.txt that supports `add_subdirectory`.
+### [Catch2](https://github.com/catchorg/Catch2)
 
 ```cmake
 CPMAddPackage(
@@ -90,12 +129,47 @@ CPMAddPackage(
 )
 ```
 
-See [here](https://github.com/TheLartians/CPM/blob/master/examples/doctest/CMakeLists.txt) for doctest example.
-Note that we can shorten Github and Gitlab URLs by using `GITHUB_REPOSITORY` or `GITLAB_REPOSITORY`, respectively.
+### [Boost (via boost-cmake)](https://github.com/Orphis/boost-cmake)
 
-### [google/benchmark](https://github.com/google/benchmark.git)
+```CMake
+CPMAddPackage(
+  NAME boost-cmake
+  GITHUB_REPOSITORY Orphis/boost-cmake
+  VERSION 1.67.0
+)
+```
 
-Has a CMakeLists.txt that supports `add_subdirectory`, but needs some configuring to work without external dependencies.
+### [cxxopts](https://github.com/jarro2783/cxxopts)
+
+```cmake
+CPMAddPackage(
+  NAME cxxopts
+  GITHUB_REPOSITORY jarro2783/cxxopts
+  VERSION 2.2.0
+  OPTIONS
+    "CXXOPTS_BUILD_EXAMPLES Off"
+    "CXXOPTS_BUILD_TESTS Off"
+)
+```
+
+### [Yaml-cpp](https://github.com/jbeder/yaml-cpp)
+
+```CMake
+CPMAddPackage(
+  NAME yaml-cpp
+  GITHUB_REPOSITORY jbeder/yaml-cpp
+  # 0.6.2 uses deprecated CMake syntax
+  VERSION 0.6.3
+  # 0.6.3 is not released yet, so use a recent commit
+  GIT_TAG 012269756149ae99745b6dafefd415843d7420bb 
+  OPTIONS
+    "YAML_CPP_BUILD_TESTS Off"
+    "YAML_CPP_BUILD_CONTRIB Off"
+    "YAML_CPP_BUILD_TOOLS Off"
+)
+```
+
+### [google/benchmark](https://github.com/google/benchmark)
 
 ```cmake
 CPMAddPackage(
@@ -106,44 +180,59 @@ CPMAddPackage(
     "BENCHMARK_ENABLE_TESTING Off"
 )
 
-# needed to compile with C++17
-set_target_properties(benchmark PROPERTIES CXX_STANDARD 17)
+if (benchmark_ADDED)
+  # compile with C++17
+  set_target_properties(benchmark PROPERTIES CXX_STANDARD 17)
+endif()
 ```
 
 ### [nlohmann/json](https://github.com/nlohmann/json)
 
-Header-only library with a huge git repositoy.
-Instead of downloading the whole repositoy, we fetch the zip included with the release and create our own target.
-
 ```cmake
 CPMAddPackage(
   NAME nlohmann_json
   VERSION 3.6.1  
+  # the git repo is incredibly large, so we download the archived include directory
   URL https://github.com/nlohmann/json/releases/download/v3.6.1/include.zip
   URL_HASH SHA256=69cc88207ce91347ea530b227ff0776db82dcb8de6704e1a3d74f4841bc651cf
 )
 
 if (nlohmann_json_ADDED)
-  add_library(nlohmann_json INTERFACE)
+  add_library(nlohmann_json INTERFACE IMPORTED)
   target_include_directories(nlohmann_json INTERFACE ${nlohmann_json_SOURCE_DIR})
 endif()
 ```
 
-Adding large repos works as well, but takes a while for the initial clone.
+### [Range-v3](https://github.com/ericniebler/range-v3)
+
+```Cmake
+CPMAddPackage(
+  NAME range-v3
+  URL https://github.com/ericniebler/range-v3/archive/0.5.0.zip
+  VERSION 0.5.0
+  # the range-v3 CMakeLists screws with configuration options
+  DOWNLOAD_ONLY True
+)
+
+if(range-v3_ADDED) 
+  add_library(range-v3 INTERFACE IMPORTED)
+  target_include_directories(range-v3 INTERFACE "${range-v3_SOURCE_DIR}/include")
+endif()
+```
 
 ### [Lua](https://www.lua.org)
 
-Lua does not oficially support CMake, so we query the sources and create our own target.
-
 ```cmake
 CPMAddPackage(
   NAME lua
   GIT_REPOSITORY https://github.com/lua/lua.git
-  VERSION 5-3-4
+  VERSION 5.3.5
   DOWNLOAD_ONLY YES
 )
 
 if (lua_ADDED)
+  # lua has no CMake support, so we create our own target
+
   FILE(GLOB lua_sources ${lua_SOURCE_DIR}/*.c)
   add_library(lua STATIC ${lua_sources})
 
@@ -154,25 +243,8 @@ if (lua_ADDED)
 endif()
 ```
 
-## Local packages
+For a full example on using CPM to download and configure lua with sol2 see [here](examples/sol2).
 
-CPM can be configured to use `find_package` to search for locally installed dependencies first.
-If `CPM_LOCAL_PACKAGES_ONLY` is set, CPM will error when dependency is not found locally.
+### Full Examples
 
-## Advantages
-
-- **Small and reusable projects** CPM takes care of project dependencies, allowing developers to focus on creating small, well-tested frameworks.
-- **Cross-Plattform** CPM adds projects via `add_subdirectory`, which is compatible with all cmake toolchains and generators.
-- **Reproducable builds** By using versioning via git tags it is ensured that a project will always be in the same state everywhere.
-- **Recursive dependencies** Ensures that no dependency is added twice and is added in the minimum required version.
-- **No installation required** No need to install anything. Just add the script to your project and you're good to go.
-- **No Setup required** There is a good chance your existing projects already work as CPM dependencies.
-- **Simple source distribution** CPM makes including projects with source files and dependencies easy, reducing the need for monolithic header files.
-
-## Limitations
-
-- **First version used** In diamond-shaped dependency graphs (e.g. `A` depends on `C`@1.1 and `B`, which itself depends on `C`@1.2 the first added dependency will be used (in this case `C`@1.1). In this case, B requires a newer version of `C` than `A`, so CPM will emit an error. This can be resolved by updating the outermost dependency version.
-- **No auto-update** To update a dependency, version must be adapted manually and there is no way for CPM to figure out the most recent version.
-- **No pre-built binaries** Unless they are installed or included in the linked repository. 
-
-For projects with more complex needs and where an extra setup step doesn't matter, it is worth to check out fully featured C++ package managers such as [conan](https://conan.io) or [hunter](https://github.com/ruslo/hunter).
+See the [examples directory](https://github.com/TheLartians/CPM/tree/master/examples) for full examples with source code and check out the [wiki](https://github.com/TheLartians/CPM/wiki/More-Snippets) for many more example snippets.

cmake/CPM.cmake

@@ -28,7 +28,7 @@
 
 cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
 
-set(CURRENT_CPM_VERSION 0.11) 
+set(CURRENT_CPM_VERSION 0.14) 
 
 if(CPM_DIRECTORY)
   if(NOT ${CPM_DIRECTORY} MATCHES ${CMAKE_CURRENT_LIST_DIR})
@@ -42,10 +42,19 @@ endif()
 set(CPM_VERSION ${CURRENT_CPM_VERSION} CACHE INTERNAL "")
 set(CPM_DIRECTORY ${CMAKE_CURRENT_LIST_DIR} CACHE INTERNAL "")
 set(CPM_PACKAGES "" CACHE INTERNAL "")
+set(CPM_DRY_RUN OFF CACHE INTERNAL "Don't download or configure dependencies (for testing)")
 
 option(CPM_USE_LOCAL_PACKAGES "Use locally installed packages (find_package)" OFF)
 option(CPM_LOCAL_PACKAGES_ONLY "Use only locally installed packages" OFF)
 
+if(DEFINED ENV{CPM_SOURCE_CACHE})
+  set(CPM_SOURCE_CACHE_DEFAULT $ENV{CPM_SOURCE_CACHE})
+else()
+  set(CPM_SOURCE_CACHE_DEFAULT OFF)
+endif()
+
+set(CPM_SOURCE_CACHE ${CPM_SOURCE_CACHE_DEFAULT} CACHE PATH "Directory to downlaod CPM dependencies")
+
 include(FetchContent)
 include(CMakeParseArguments)
 
@@ -64,6 +73,8 @@ function(CPMAddPackage)
     DOWNLOAD_ONLY
     GITHUB_REPOSITORY
     GITLAB_REPOSITORY
+    SOURCE_DIR
+    DOWNLOAD_COMMAND
   )
 
   set(multiValueArgs
@@ -89,11 +100,16 @@ function(CPMAddPackage)
     endif()
   endif()
 
-  if (NOT CPM_ARGS_VERSION)
-    set(CPM_ARGS_VERSION 0)
+  if (NOT DEFINED CPM_ARGS_VERSION)
+    if (DEFINED CPM_ARGS_GIT_TAG) 
+      CPM_GET_VERSION_FROM_GIT_TAG("${CPM_ARGS_GIT_TAG}" CPM_ARGS_VERSION)
+    endif()
+    if (NOT DEFINED CPM_ARGS_VERSION) 
+      set(CPM_ARGS_VERSION 0)
+    endif()
   endif()
 
-  if (NOT CPM_ARGS_GIT_TAG)
+  if (NOT DEFINED CPM_ARGS_GIT_TAG)
     set(CPM_ARGS_GIT_TAG v${CPM_ARGS_VERSION})
   endif()
 
@@ -110,11 +126,11 @@ function(CPMAddPackage)
   endif()
 
   if (CPM_ARGS_GITLAB_REPOSITORY)
-    list(APPEND CPM_ARGS_UNPARSED_ARGUMENTS GIT_REPOSITORY "https://gitlab.com/${CPM_ARGS_GITHUB_REPOSITORY}.git")
+    list(APPEND CPM_ARGS_UNPARSED_ARGUMENTS GIT_REPOSITORY "https://gitlab.com/${CPM_ARGS_GITLAB_REPOSITORY}.git")
   endif()
 
   if (${CPM_ARGS_NAME} IN_LIST CPM_PACKAGES)
-    CPM_GET_PACKAGE_VERSION(${CPM_ARGS_NAME})
+    CPM_GET_PACKAGE_VERSION(${CPM_ARGS_NAME} CPM_PACKAGE_VERSION)
     if(${CPM_PACKAGE_VERSION} VERSION_LESS ${CPM_ARGS_VERSION})
       message(WARNING "${CPM_INDENT} requires a newer version of ${CPM_ARGS_NAME} (${CPM_ARGS_VERSION}) than currently included (${CPM_PACKAGE_VERSION}).")
     endif()
@@ -143,7 +159,36 @@ function(CPMAddPackage)
     endforeach()
   endif()
 
-  CPM_DECLARE_PACKAGE(${CPM_ARGS_NAME} ${CPM_ARGS_VERSION} ${CPM_ARGS_GIT_TAG} "${CPM_ARGS_UNPARSED_ARGUMENTS}")
+  set(FETCH_CONTENT_DECLARE_EXTRA_OPTS "")
+
+  if (DEFINED CPM_ARGS_GIT_TAG)
+    set(PACKAGE_INFO "${CPM_ARGS_GIT_TAG}")
+  else()
+    set(PACKAGE_INFO "${CPM_ARGS_VERSION}")
+  endif()
+
+  if (DEFINED CPM_ARGS_DOWNLOAD_COMMAND)
+    set(FETCH_CONTENT_DECLARE_EXTRA_OPTS DOWNLOAD_COMMAND ${CPM_ARGS_DOWNLOAD_COMMAND})
+  else()
+    if (CPM_SOURCE_CACHE AND NOT DEFINED CPM_ARGS_SOURCE_DIR)
+      string(TOLOWER ${CPM_ARGS_NAME} lower_case_name)
+      set(origin_parameters ${CPM_ARGS_UNPARSED_ARGUMENTS})
+      list(SORT origin_parameters)
+      string(SHA1 origin_hash "${origin_parameters}")
+      set(download_directory ${CPM_SOURCE_CACHE}/${lower_case_name}/${origin_hash})
+      list(APPEND FETCH_CONTENT_DECLARE_EXTRA_OPTS SOURCE_DIR ${download_directory})
+      if (EXISTS ${download_directory})
+        list(APPEND FETCH_CONTENT_DECLARE_EXTRA_OPTS DOWNLOAD_COMMAND ":")
+        set(PACKAGE_INFO "${download_directory}")
+      else()
+        # remove timestamps so CMake will re-download the dependency
+        file(REMOVE_RECURSE ${CMAKE_BINARY_DIR}/_deps/${lower_case_name}-subbuild)
+        set(PACKAGE_INFO "${PACKAGE_INFO} -> ${download_directory}")
+      endif()
+    endif()
+  endif()
+
+  CPM_DECLARE_PACKAGE(${CPM_ARGS_NAME} ${CPM_ARGS_VERSION} ${PACKAGE_INFO} "${CPM_ARGS_UNPARSED_ARGUMENTS}" ${FETCH_CONTENT_DECLARE_EXTRA_OPTS})
   CPM_FETCH_PACKAGE(${CPM_ARGS_NAME} ${DOWNLOAD_ONLY})
   CPMGetProperties(${CPM_ARGS_NAME})
   SET(${CPM_ARGS_NAME}_SOURCE_DIR "${${CPM_ARGS_NAME}_SOURCE_DIR}" PARENT_SCOPE)
@@ -151,8 +196,13 @@ function(CPMAddPackage)
   SET(${CPM_ARGS_NAME}_ADDED YES PARENT_SCOPE)  
 endfunction()
 
-function (CPM_DECLARE_PACKAGE PACKAGE VERSION GIT_TAG)
-  message(STATUS "${CPM_INDENT} adding package ${PACKAGE}@${VERSION} (${GIT_TAG})")
+function (CPM_DECLARE_PACKAGE PACKAGE VERSION INFO)
+  message(STATUS "${CPM_INDENT} adding package ${PACKAGE}@${VERSION} (${INFO})")
+
+  if (${CPM_DRY_RUN}) 
+    message(STATUS "${CPM_INDENT} package not declared (dry run)")
+    return()
+  endif()
 
   FetchContent_Declare(
     ${PACKAGE}
@@ -161,6 +211,12 @@ function (CPM_DECLARE_PACKAGE PACKAGE VERSION GIT_TAG)
 endfunction()
 
 function (CPM_FETCH_PACKAGE PACKAGE DOWNLOAD_ONLY)  
+
+  if (${CPM_DRY_RUN}) 
+    message(STATUS "${CPM_INDENT} package ${PACKAGE} not fetched (dry run)")
+    return()
+  endif()
+
   set(CPM_OLD_INDENT "${CPM_INDENT}")
   set(CPM_INDENT "${CPM_INDENT} ${PACKAGE}:")
   if(${DOWNLOAD_ONLY})
@@ -174,6 +230,9 @@ function (CPM_FETCH_PACKAGE PACKAGE DOWNLOAD_ONLY)
 endfunction()
 
 function (CPMGetProperties PACKAGE)
+  if (${CPM_DRY_RUN}) 
+    return()
+  endif()
   FetchContent_GetProperties(${PACKAGE})
   string(TOLOWER ${PACKAGE} lpackage)
   SET(${PACKAGE}_SOURCE_DIR "${${lpackage}_SOURCE_DIR}" PARENT_SCOPE)
@@ -186,8 +245,8 @@ function(CPMRegisterPackage PACKAGE VERSION)
   set("CPM_PACKAGE_${PACKAGE}_VERSION" ${VERSION} CACHE INTERNAL "")
 endfunction()
 
-function(CPM_GET_PACKAGE_VERSION PACKAGE)
-  set(CPM_PACKAGE_VERSION "${CPM_PACKAGE_${PACKAGE}_VERSION}" PARENT_SCOPE)
+function(CPM_GET_PACKAGE_VERSION PACKAGE OUTPUT)
+  set(${OUTPUT} "${CPM_PACKAGE_${PACKAGE}_VERSION}" PARENT_SCOPE)
 endfunction()
 
 function(CPM_PARSE_OPTION OPTION)
@@ -199,6 +258,11 @@ function(CPM_PARSE_OPTION OPTION)
   set(OPTION_VALUE "${OPTION_VALUE}" PARENT_SCOPE)
 endfunction()
 
+function(CPM_GET_VERSION_FROM_GIT_TAG GIT_TAG RESULT)
+  string(REGEX MATCH "v?([0123456789.]*).*" _ ${GIT_TAG})
+  SET(${RESULT} ${CMAKE_MATCH_1} PARENT_SCOPE)
+endfunction()
+
 function (CPM_HANDLE_OLD_VERSION NEW_CPM_VERSION)
   
   message(AUTHOR_WARNING "${CPM_INDENT} \
@@ -207,4 +271,4 @@ It is recommended to upgrade CPM to the most recent version. \
 See https://github.com/TheLartians/CPM for more information."
   )
 
-endfunction()
+endfunction()

cmake/testing.cmake

@@ -0,0 +1,22 @@
+
+function(ASSERT_EQUAL)
+  if (NOT ARGC EQUAL 2) 
+    message(FATAL_ERROR "assertion failed: invalid argument count: ${ARGC}")
+  endif()
+
+  if (NOT ${ARGV0} STREQUAL ${ARGV1})
+    message(FATAL_ERROR "assertion failed: '${ARGV0}' != '${ARGV1}'")
+  else()
+    message(STATUS "test passed: '${ARGV0}' == '${ARGV1}'")
+  endif()
+endfunction()
+
+function(ASSERT_EMPTY)
+  if (NOT ARGC EQUAL 0) 
+    message(FATAL_ERROR "assertion failed: input ${ARGC} not empty: '${ARGV}'")
+  endif()
+endfunction()
+
+function(ASSERTION_FAILED)
+  message(FATAL_ERROR "assertion failed: ${ARGN}")
+endfunction()

examples/benchmark/CMakeLists.txt

@@ -1,5 +1,7 @@
 cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
 
+project(CPMExampleBenchmark)
+
 # ---- Dependencies ----
 
 include(../../cmake/CPM.cmake)

examples/boost/CMakeLists.txt

@@ -0,0 +1,20 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMExampleBoost)
+
+# ---- Create binary ----
+
+add_executable(CPMExampleBoost main.cpp)
+set_target_properties(CPMExampleBoost PROPERTIES CXX_STANDARD 17)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME boost
+  GITHUB_REPOSITORY Orphis/boost-cmake
+  VERSION 1.67.0
+)
+
+target_link_libraries(CPMExampleBoost PRIVATE Boost::system pthread)

examples/boost/main.cpp

@@ -0,0 +1,30 @@
+//
+// timer.cpp
+// ~~~~~~~~~
+//
+// Copyright (c) 2003-2016 Christopher M. Kohlhoff (chris at kohlhoff dot com)
+//
+// Distributed under the Boost Software License, Version 1.0. (See accompanying
+// file LICENSE_1_0.txt or copy at http://www.boost.org/LICENSE_1_0.txt)
+//
+
+#include <iostream>
+#include <boost/asio.hpp>
+#include <boost/date_time/posix_time/posix_time.hpp>
+
+void print(const boost::system::error_code& /*e*/)
+{
+  std::cout << "Hello, world!" << std::endl;
+}
+
+int main()
+{
+  boost::asio::io_service io;
+
+  boost::asio::deadline_timer t(io, boost::posix_time::seconds(1));
+  t.async_wait(&print);
+
+  io.run();
+
+  return 0;
+}

examples/build_all.py

@@ -22,7 +22,7 @@ for example in examples:
   print("running example %s" % example.name)
   print("================" + ('=' * len(example.name)))
   project = Path(".") / 'build' / example.name
-  configure = runCommand('cmake -H%s -B%s -DCMAKE_BUILD_TYPE=RelWithDebInfo' % (example, project))
+  configure = runCommand('cmake -H%s -B%s' % (example, project))
   print('  ' + '\n  '.join([line for line in configure.split('\n') if 'CPM:' in line]))
   build = runCommand('cmake --build %s -j4' % (project))
   print('  ' + '\n  '.join([line for line in build.split('\n') if 'Built target' in line]))

examples/catch2/CMakeLists.txt

@@ -1,5 +1,7 @@
 cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
 
+project(CPMExampleCatch2)
+
 # ---- Options ----
 
 option(ENABLE_TEST_COVERAGE "Enable test coverage" OFF)

examples/cereal/CMakeLists.txt

@@ -0,0 +1,22 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMExampleCereal)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME cereal
+  VERSION 1.2.2
+  GITHUB_REPOSITORY USCiLab/cereal
+  OPTIONS
+    "SKIP_PORTABILITY_TEST ON"
+    "JUST_INSTALL_CEREAL ON"
+)
+
+# ---- Create binary ----
+
+add_executable(CPMExampleCereal main.cpp)
+target_link_libraries(CPMExampleCereal cereal )
+set_target_properties(CPMExampleCereal PROPERTIES CXX_STANDARD 17)

examples/cereal/main.cpp

@@ -0,0 +1,34 @@
+#define CATCH_CONFIG_MAIN
+
+#include <cereal/cereal.hpp>
+#include <cereal/archives/json.hpp>
+
+#include <string>
+#include <sstream>
+
+struct player_data 
+{
+  int id{-1};
+  std::string name{};
+};
+
+template<typename Archive>
+void serialize(Archive& archive, player_data const &data)
+{
+  archive(
+    cereal::make_nvp("id", data.id), 
+    cereal::make_nvp("name", data.name)
+  );
+}
+
+int main(int argc, char const *argv[])
+{
+  player_data player{3, "Gamer One"};
+  std::ostringstream oss;
+  cereal::JSONOutputArchive output(oss);
+  output(cereal::make_nvp("player_data", player));
+
+  std::cout << oss.str() << std::endl;
+
+  return 0;
+}

examples/cxxopts/CMakeLists.txt

@@ -0,0 +1,26 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMExampleCXXOpts)
+
+# ---- Options ----
+
+option(ENABLE_TEST_COVERAGE "Enable test coverage" OFF)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME cxxopts
+  GITHUB_REPOSITORY jarro2783/cxxopts
+  VERSION 2.2.0
+  OPTIONS
+    "CXXOPTS_BUILD_EXAMPLES Off"
+    "CXXOPTS_BUILD_TESTS Off"
+)
+
+# ---- Create binary ----
+
+add_executable(CPMExampleCXXOpts main.cpp)
+target_link_libraries(CPMExampleCXXOpts cxxopts)
+set_target_properties(CPMExampleCXXOpts PROPERTIES CXX_STANDARD 17 COMPILE_FLAGS "-Wall -pedantic -Wextra -Werror")

examples/cxxopts/main.cpp

@@ -0,0 +1,23 @@
+#include <cxxopts.hpp>
+#include <iostream>
+
+int main(int argc, char ** argv) {
+  cxxopts::Options options("MyProgram", "One line description of MyProgram");
+  options.add_options()
+    ("h,help", "Show help")
+    ("d,debug", "Enable debugging")
+    ("f,file", "File name", cxxopts::value<std::string>());
+
+  auto result = options.parse(argc, argv);
+  
+  if (result["help"].as<bool>()) {
+    std::cout << options.help() << std::endl;
+    return 0;
+  }
+
+  for (auto arg: result.arguments()) {
+    std::cout << "option: " << arg.key() << ": " << arg.value() << std::endl;
+  }
+
+  return 0;
+}

examples/doctest/CMakeLists.txt

@@ -1,5 +1,7 @@
 cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
 
+project(CPMExampleDoctest)
+
 # ---- Options ----
 
 option(ENABLE_TEST_COVERAGE "Enable test coverage" OFF)
@@ -17,7 +19,6 @@ CPMAddPackage(
 CPMAddPackage(
   NAME doctest
   GITHUB_REPOSITORY onqtam/doctest
-  VERSION 2.3.2
   GIT_TAG 2.3.2
 )
 

examples/entt/CMakeLists.txt

@@ -0,0 +1,26 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMEnTTExample)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME EnTT
+  VERSION 3.1.1
+  GITHUB_REPOSITORY skypjack/entt
+  # EnTT's CMakeLists screws with configuration options
+  DOWNLOAD_ONLY True
+)
+
+if (EnTT_ADDED)
+  add_library(EnTT INTERFACE)
+  target_include_directories(EnTT INTERFACE ${EnTT_SOURCE_DIR}/src)
+endif()
+
+# ---- Executable ----
+
+add_executable(CPMEnTTExample "main.cpp")
+set_target_properties(CPMEnTTExample PROPERTIES CXX_STANDARD 17)        
+target_link_libraries(CPMEnTTExample EnTT)

examples/entt/main.cpp

@@ -0,0 +1,54 @@
+#include <entt/entt.hpp>
+#include <cstdint>
+
+struct position {
+    float x;
+    float y;
+};
+
+struct velocity {
+    float dx;
+    float dy;
+};
+
+void update(entt::registry &registry) {
+    auto view = registry.view<position, velocity>();
+
+    for(auto entity: view) {
+        // gets only the components that are going to be used ...
+
+        auto &vel = view.get<velocity>(entity);
+
+        vel.dx = 0.;
+        vel.dy = 0.;
+
+        // ...
+    }
+}
+
+void update(std::uint64_t dt, entt::registry &registry) {
+    registry.view<position, velocity>().each([dt](auto &pos, auto &vel) {
+        // gets all the components of the view at once ...
+
+        pos.x += vel.dx * dt;
+        pos.y += vel.dy * dt;
+
+        // ...
+    });
+}
+
+int main() {
+    entt::registry registry;
+    std::uint64_t dt = 16;
+
+    for(auto i = 0; i < 10; ++i) {
+        auto entity = registry.create();
+        registry.assign<position>(entity, i * 1.f, i * 1.f);
+        if(i % 2 == 0) { registry.assign<velocity>(entity, i * .1f, i * .1f); }
+    }
+
+    update(dt, registry);
+    update(registry);
+
+    // ...
+}

examples/gtest/CMakeLists.txt

@@ -0,0 +1,45 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMExampleGtest)
+
+# ---- Options ----
+
+option(ENABLE_TEST_COVERAGE "Enable test coverage" OFF)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME fibonacci
+  GIT_REPOSITORY https://github.com/TheLartians/Fibonacci.git
+  VERSION 1.0
+)
+
+CPMAddPackage(
+  NAME googletest
+  GITHUB_REPOSITORY google/googletest
+  GIT_TAG release-1.8.1
+  VERSION 1.8.1
+  OPTIONS
+      "INSTALL_GTEST OFF"
+      "gtest_force_shared_crt ON"
+)
+
+# ---- Create binary ----
+
+add_executable(CPMExampleGtest main.cpp)
+target_link_libraries(CPMExampleGtest fibonacci gtest gtest_main gmock)
+set_target_properties(CPMExampleGtest PROPERTIES CXX_STANDARD 17)
+
+# ---- Enable testing ----
+
+enable_testing() 
+add_test(CPMExampleGtest CPMExampleGtest)
+
+# ---- Add code coverage ----
+
+if (${ENABLE_TEST_COVERAGE})
+  set_target_properties(CPMExampleGtest PROPERTIES CXX_STANDARD 17 COMPILE_FLAGS "-O0 -g -fprofile-arcs -ftest-coverage --coverage")
+  target_link_options(CPMExampleGtest PUBLIC "--coverage")
+endif()

examples/gtest/main.cpp

@@ -0,0 +1,13 @@
+#include <gtest/gtest.h>
+#include <fibonacci.h>
+
+TEST(FibonacciTests, BasicChecks)
+{
+  ASSERT_TRUE(fibonnacci(0) == 0);
+  ASSERT_TRUE(fibonnacci(1) == 1);
+  ASSERT_TRUE(fibonnacci(2) == 1);
+  ASSERT_TRUE(fibonnacci(3) == 2);
+  ASSERT_TRUE(fibonnacci(4) == 3);
+  ASSERT_TRUE(fibonnacci(5) == 5);
+  ASSERT_TRUE(fibonnacci(13) == 233);
+}

examples/json/CMakeLists.txt

@@ -1,5 +1,7 @@
 cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
 
+project(CPMJSONExample)
+
 # ---- Dependencies ----
 
 include(../../cmake/CPM.cmake)

examples/linenoise/CMakeLists.txt

@@ -0,0 +1,24 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMlinenoiseExample)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME linenoise
+  GIT_TAG 1.0
+  GITHUB_REPOSITORY antirez/linenoise
+)
+
+if(linenoise_ADDED)
+  add_library(linenoise ${linenoise_SOURCE_DIR}/linenoise.c)
+  target_include_directories(linenoise PUBLIC ${linenoise_SOURCE_DIR})
+endif()
+
+# ---- Executable ----
+
+add_executable(CPMlinenoiseExample "main.cpp")
+set_target_properties(CPMlinenoiseExample PROPERTIES CXX_STANDARD 17)        
+target_link_libraries(CPMlinenoiseExample linenoise)

examples/linenoise/main.cpp

@@ -0,0 +1,64 @@
+#include <stdio.h>
+#include <stdlib.h>
+#include <string.h>
+#include "linenoise.h"
+
+
+void completion(const char *buf, linenoiseCompletions *lc) {
+    if (buf[0] == 'h') {
+        linenoiseAddCompletion(lc,"hello");
+        linenoiseAddCompletion(lc,"hello there");
+    }
+}
+
+int main(int argc, char **argv) {
+    char *line;
+    char *prgname = argv[0];
+
+    /* Parse options, with --multiline we enable multi line editing. */
+    while(argc > 1) {
+        argc--;
+        argv++;
+        if (!strcmp(*argv,"--multiline")) {
+            linenoiseSetMultiLine(1);
+            printf("Multi-line mode enabled.\n");
+        } else if (!strcmp(*argv,"--keycodes")) {
+            linenoisePrintKeyCodes();
+            exit(0);
+        } else {
+            fprintf(stderr, "Usage: %s [--multiline] [--keycodes]\n", prgname);
+            exit(1);
+        }
+    }
+
+    /* Set the completion callback. This will be called every time the
+     * user uses the <tab> key. */
+    linenoiseSetCompletionCallback(completion);
+
+    /* Load history from file. The history file is just a plain text file
+     * where entries are separated by newlines. */
+    linenoiseHistoryLoad("history.txt"); /* Load the history at startup */
+
+    /* Now this is the main loop of the typical linenoise-based application.
+     * The call to linenoise() will block as long as the user types something
+     * and presses enter.
+     *
+     * The typed string is returned as a malloc() allocated string by
+     * linenoise, so the user needs to free() it. */
+    while((line = linenoise("hello> ")) != NULL) {
+        /* Do something with the string. */
+        if (line[0] != '\0' && line[0] != '/') {
+            printf("echo: '%s'\n", line);
+            linenoiseHistoryAdd(line); /* Add to the history. */
+            linenoiseHistorySave("history.txt"); /* Save the history on disk. */
+        } else if (!strncmp(line,"/historylen",11)) {
+            /* The "/historylen" command will change the history len. */
+            int len = atoi(line+11);
+            linenoiseHistorySetMaxLen(len);
+        } else if (line[0] == '/') {
+            printf("Unreconized command: %s\n", line);
+        }
+        free(line);
+    }
+    return 0;
+}

examples/parser-lua/CMakeLists.txt

@@ -1,5 +1,7 @@
 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
 
+project(CPMParserLuaExample)
+
 include(../../cmake/CPM.cmake)
 
 # ---- Dependencies ----
@@ -7,7 +9,7 @@ include(../../cmake/CPM.cmake)
 CPMAddPackage(
   NAME Glue
   GIT_REPOSITORY https://github.com/TheLartians/Glue.git
-  VERSION 0.8.1
+  VERSION 0.8.2
   OPTIONS 
     "GLUE_ENABLE_LUA ON"
     "GLUE_BUILD_LUA ON"

examples/parser/CMakeLists.txt

@@ -1,5 +1,7 @@
 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
 
+project(CPMParserExample)
+
 # add dependencies
 include(../../cmake/CPM.cmake)
 

examples/range-v3/CMakeLists.txt

@@ -0,0 +1,26 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMRangev3Example)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME range-v3
+  URL https://github.com/ericniebler/range-v3/archive/0.5.0.zip
+  VERSION 0.5.0
+  # the range-v3 CMakeLists screws with configuration options
+  DOWNLOAD_ONLY True
+)
+
+if(range-v3_ADDED) 
+  add_library(range-v3 INTERFACE IMPORTED)
+  target_include_directories(range-v3 INTERFACE "${range-v3_SOURCE_DIR}/include")
+endif()
+
+# ---- Executable ----
+
+add_executable(CPMRangev3Example "main.cpp")
+set_target_properties(CPMRangev3Example PROPERTIES CXX_STANDARD 17)        
+target_link_libraries(CPMRangev3Example range-v3)

examples/range-v3/main.cpp

@@ -0,0 +1,44 @@
+// Range v3 library
+//
+//  Copyright Jeff Garland 2017
+//
+//  Use, modification and distribution is subject to the
+//  Boost Software License, Version 1.0. (See accompanying
+//  file LICENSE_1_0.txt or copy at
+//  http://www.boost.org/LICENSE_1_0.txt)
+//
+// Project home: https://github.com/ericniebler/range-v3
+//
+
+//[any_all_none_of]]
+// Demonstrates any_of, all_of, none_of
+// output
+// vector: [6,2,3,4,5,6]
+// vector any_of is_six: true
+// vector all_of is_six: false
+// vector none_of is_six: false
+
+#include <range/v3/algorithm/all_of.hpp>
+#include <range/v3/algorithm/any_of.hpp>
+#include <range/v3/algorithm/for_each.hpp>
+#include <range/v3/algorithm/none_of.hpp>
+#include <range/v3/view/all.hpp>
+
+#include <iostream>
+#include <vector>
+using std::cout;
+
+auto is_six = [](int i) { return i == 6; };
+
+int
+main()
+{
+    std::vector<int> v{6, 2, 3, 4, 5, 6};
+    cout << std::boolalpha;
+    cout << "vector: " << ranges::view::all(v) << '\n';
+
+    cout << "vector any_of is_six: " << ranges::any_of(v, is_six) << '\n';
+    cout << "vector all_of is_six: " << ranges::all_of(v, is_six) << '\n';
+    cout << "vector none_of is_six: " << ranges::none_of(v, is_six) << '\n';
+}
+//[any_all_none_of]]

examples/simple_match/CMakeLists.txt

@@ -1,5 +1,7 @@
 cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
 
+project(CPMSimpleMatchExample)
+
 # ---- Dependencies ----
 
 include(../../cmake/CPM.cmake)

examples/sol2/CMakeLists.txt

@@ -0,0 +1,47 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMSol2Example)
+
+# ---- Dependencies ----
+
+include(../../cmake/CPM.cmake)
+
+CPMAddPackage(
+  NAME lua
+  GIT_REPOSITORY https://github.com/lua/lua.git
+  VERSION 5.3.5
+  DOWNLOAD_ONLY YES
+)
+
+if (lua_ADDED)
+  # lua has no CMakeLists, so we create our own target
+
+  FILE(GLOB lua_sources ${lua_SOURCE_DIR}/*.c)
+  add_library(lua STATIC ${lua_sources})
+
+  target_include_directories(lua
+    PUBLIC
+      $<BUILD_INTERFACE:${lua_SOURCE_DIR}>
+  )
+endif()
+
+
+CPMAddPackage(
+  NAME sol2
+  URL https://github.com/ThePhD/sol2/archive/v3.0.2.zip
+  VERSION 3.0.2
+  DOWNLOAD_ONLY YES
+)
+
+if (sol2_ADDED)
+  add_library(sol2 INTERFACE IMPORTED)
+  target_include_directories(sol2 INTERFACE ${sol2_SOURCE_DIR}/include)
+  target_link_libraries(sol2 INTERFACE lua)
+endif()
+
+# ---- Executable ----
+
+add_executable(CPMSol2Example "main.cpp")
+set_target_properties(CPMSol2Example PROPERTIES CXX_STANDARD 17)        
+target_link_libraries(CPMSol2Example sol2)
+

examples/sol2/main.cpp

@@ -0,0 +1,16 @@
+#include <sol/sol.hpp>
+#include <cassert>
+
+struct vars {
+    int boop = 0;
+};
+
+int main() {
+    sol::state lua;
+    lua.open_libraries( sol::lib::base );
+    lua.new_usertype<vars>("vars", "boop", &vars::boop);
+    lua.script("beep = vars.new()\n"
+               "beep.boop = 1\n"
+               "print('beep boop')");
+    assert(lua.get<vars>("beep").boop == 1);
+}

examples/yaml/CMakeLists.txt

@@ -1,5 +1,7 @@
 cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
 
+project(CPMYamlExample)
+
 # ---- Dependencies ----
 
 include(../../cmake/CPM.cmake)
@@ -7,7 +9,7 @@ include(../../cmake/CPM.cmake)
 CPMAddPackage(
   NAME yaml-cpp
   GIT_REPOSITORY https://github.com/jbeder/yaml-cpp.git
-  # 0.6.2 uses depricated CMake syntax
+  # 0.6.2 uses deprecated CMake syntax
   VERSION 0.6.3                                  
   # 0.6.3 is not released yet, so use the most recent commit
   GIT_TAG 012269756149ae99745b6dafefd415843d7420bb 

test/CMakeLists.txt

@@ -0,0 +1,17 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMTests)
+
+file(GLOB tests "${CMAKE_CURRENT_SOURCE_DIR}/unit/*.cmake")
+
+enable_testing()
+
+foreach(test ${tests})
+  message(STATUS "adding test: ${test}")
+  add_test(
+    NAME ${test} 
+    COMMAND ${CMAKE_COMMAND} -DCPM_PATH=${CMAKE_CURRENT_SOURCE_DIR}/../cmake -P "${test}"
+  )
+endforeach()
+
+add_custom_target(test-verbose COMMAND ${CMAKE_CTEST_COMMAND} --verbose)

test/unit/cache.cmake

@@ -0,0 +1,125 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+include(${CPM_PATH}/testing.cmake)
+include(CMakePackageConfigHelpers)
+
+
+set(CPM_SOURCE_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/CPM")
+set(TEST_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/cache)
+
+function(clear_cache)
+  FILE(REMOVE_RECURSE ${CPM_SOURCE_CACHE_DIR})
+  
+  if (EXISTS "${CPM_SOURCE_CACHE_DIR}")
+    ASSERTION_FAILED("cache not cleared")
+  endif()
+endfunction()
+
+function(update_cmake_lists)
+  configure_package_config_file(
+    "${CMAKE_CURRENT_LIST_DIR}/cache/CMakeLists.txt.in"
+    "${CMAKE_CURRENT_LIST_DIR}/cache/CMakeLists.txt"
+    INSTALL_DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/junk
+  )
+endfunction()
+
+function(reset_test)
+  clear_cache()
+  FILE(REMOVE_RECURSE ${TEST_BUILD_DIR})
+  update_cmake_lists()
+endfunction()
+
+set(CATCH2_VERSION 2.8.0)
+
+## Read CPM_SOURCE_CACHE from arguments
+
+reset_test()
+
+execute_process(
+  COMMAND 
+  ${CMAKE_COMMAND} "-H${CMAKE_CURRENT_LIST_DIR}/cache" "-B${TEST_BUILD_DIR}" "-DCPM_SOURCE_CACHE=${CPM_SOURCE_CACHE_DIR}"
+  RESULT_VARIABLE ret
+)
+
+ASSERT_EQUAL(${ret} "0")
+
+if (NOT EXISTS "${CPM_SOURCE_CACHE_DIR}/catch2")
+  ASSERTION_FAILED("catch2 not in cache")
+endif()
+
+FILE(GLOB catch2_versions "${CPM_SOURCE_CACHE_DIR}/catch2/*")
+list(LENGTH catch2_versions catch2_version_count)
+ASSERT_EQUAL(${catch2_version_count} "1")
+
+FILE(GLOB fibonacci_versions "${CPM_SOURCE_CACHE_DIR}/fibonacci/*")
+list(LENGTH fibonacci_versions fibonacci_version_count)
+ASSERT_EQUAL(${fibonacci_version_count} "1")
+
+## Update dependency and keep CPM_SOURCE_CACHE
+
+set(CATCH2_VERSION 2.9.0)
+update_cmake_lists()
+
+execute_process(
+  COMMAND 
+  ${CMAKE_COMMAND} ${TEST_BUILD_DIR}
+  RESULT_VARIABLE ret
+)
+
+ASSERT_EQUAL(${ret} "0")
+
+FILE(GLOB catch2_versions "${CPM_SOURCE_CACHE_DIR}/catch2/*")
+list(LENGTH catch2_versions catch2_version_count)
+ASSERT_EQUAL(${catch2_version_count} "2")
+
+FILE(GLOB fibonacci_versions "${CPM_SOURCE_CACHE_DIR}/fibonacci/*")
+list(LENGTH fibonacci_versions fibonacci_version_count)
+ASSERT_EQUAL(${fibonacci_version_count} "1")
+
+## Clear cache and update
+
+clear_cache()
+
+execute_process(
+  COMMAND 
+  ${CMAKE_COMMAND} ${TEST_BUILD_DIR}
+  RESULT_VARIABLE ret
+)
+
+ASSERT_EQUAL(${ret} "0")
+
+if (NOT EXISTS "${CPM_SOURCE_CACHE_DIR}/catch2")
+  ASSERTION_FAILED("catch2 not in cache")
+endif()
+
+## Read CPM_SOURCE_CACHE from environment
+
+reset_test()
+
+execute_process(
+  COMMAND 
+  ${CMAKE_COMMAND} -E env "CPM_SOURCE_CACHE=${CPM_SOURCE_CACHE_DIR}" ${CMAKE_COMMAND} "-H${CMAKE_CURRENT_LIST_DIR}/cache" "-B${TEST_BUILD_DIR}"
+  RESULT_VARIABLE ret
+)
+
+ASSERT_EQUAL(${ret} "0")
+
+if (NOT EXISTS "${CPM_SOURCE_CACHE_DIR}/catch2")
+  ASSERTION_FAILED("catch2 not in cache")
+endif()
+
+## Overwrite CPM_SOURCE_CACHE with argument
+
+reset_test()
+
+execute_process(
+  COMMAND 
+  ${CMAKE_COMMAND} -E env "CPM_SOURCE_CACHE=${CMAKE_CURRENT_BINARY_DIR}/junk" ${CMAKE_COMMAND} "-H${CMAKE_CURRENT_LIST_DIR}/cache" "-B${TEST_BUILD_DIR}" "-DCPM_SOURCE_CACHE=${CPM_SOURCE_CACHE_DIR}"
+  RESULT_VARIABLE ret
+)
+
+ASSERT_EQUAL(${ret} "0")
+
+if (NOT EXISTS "${CPM_SOURCE_CACHE_DIR}/catch2")
+  ASSERTION_FAILED("catch2 not in cache")
+endif()

test/unit/cache/.gitignore

@@ -0,0 +1 @@
+/CMakeLists.txt

test/unit/cache/CMakeLists.txt.in

@@ -0,0 +1,30 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMExampleCatch2)
+
+# ---- Options ----
+
+option(ENABLE_TEST_COVERAGE "Enable test coverage" OFF)
+
+# ---- Dependencies ----
+
+include(@CPM_PATH@/CPM.cmake)
+
+CPMAddPackage(
+  NAME fibonacci
+  GIT_REPOSITORY https://github.com/TheLartians/Fibonacci.git
+  VERSION 1.0
+)
+
+CPMAddPackage(
+  NAME Catch2
+  GITHUB_REPOSITORY catchorg/Catch2
+  VERSION @CATCH2_VERSION@
+  GIT_SHALLOW YES
+)
+
+# ---- Create binary ----
+
+add_executable(CPMExampleCatch2 main.cpp)
+target_link_libraries(CPMExampleCatch2 fibonacci Catch2)
+set_target_properties(CPMExampleCatch2 PROPERTIES CXX_STANDARD 17 COMPILE_FLAGS "-Wall -pedantic -Wextra -Werror")

test/unit/cache/main.cpp

@@ -0,0 +1,13 @@
+#define CATCH_CONFIG_MAIN
+
+#include <catch2/catch.hpp>
+#include <fibonacci.h>
+
+TEST_CASE("fibonnacci"){
+  REQUIRE(fibonnacci(0) == 0);
+  REQUIRE(fibonnacci(1) == 1);
+  REQUIRE(fibonnacci(2) == 1);
+  REQUIRE(fibonnacci(3) == 2);
+  REQUIRE(fibonnacci(4) == 3);
+  REQUIRE(fibonnacci(5) == 5);
+}

test/unit/dependency_properties.cmake

@@ -0,0 +1,41 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+include(${CPM_PATH}/CPM.cmake)
+include(${CPM_PATH}/testing.cmake)
+
+set(CPM_DRY_RUN ON)
+
+CPMAddPackage(
+  NAME A
+  GIT_TAG 1.2.3
+)
+
+CPMAddPackage(
+  NAME A
+  VERSION 1.2.3
+)
+
+CPM_GET_PACKAGE_VERSION(A VERSION)
+ASSERT_EQUAL(${VERSION} "1.2.3")
+
+CPMAddPackage(
+  NAME B
+  VERSION 2.4.1
+)
+
+CPMAddPackage(
+  NAME B
+  GIT_TAG v2.3.1
+)
+
+CPM_GET_PACKAGE_VERSION(B VERSION)
+ASSERT_EQUAL(${VERSION} "2.4.1")
+
+CPMAddPackage(
+  NAME C
+  GIT_TAG v3.1.2-a
+  VERSION 3.1.2
+)
+
+CPM_GET_PACKAGE_VERSION(C VERSION)
+ASSERT_EQUAL(${VERSION} "3.1.2")

test/unit/version_from_git_tag.cmake

@@ -0,0 +1,16 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+include(${CPM_PATH}/CPM.cmake)
+include(${CPM_PATH}/testing.cmake)
+
+CPM_GET_VERSION_FROM_GIT_TAG("1.2.3" VERSION)
+ASSERT_EQUAL("1.2.3" ${VERSION})
+
+CPM_GET_VERSION_FROM_GIT_TAG("v1.2.3" VERSION)
+ASSERT_EQUAL("1.2.3" ${VERSION})
+
+CPM_GET_VERSION_FROM_GIT_TAG("1.2.3-a" VERSION)
+ASSERT_EQUAL("1.2.3" ${VERSION})
+
+CPM_GET_VERSION_FROM_GIT_TAG("v1.2.3-a" VERSION)
+ASSERT_EQUAL("1.2.3" ${VERSION})