Single-argument shorthand syntax for CPMAddPackage (#207)

* Added quotes in equality checks so lists can be compared

* Function to parse argument of CPMAddPackage in case a single one was provided

* Error on URL type in CPMAddPackage single-arg

* Fixed format

* Support single argument syntax of CPMAddPackage

* Documenting and showcasing the new shorthand syntax of CPMAddPackage

* Auto EXCLUDE_FROM_ALL for the shorthand syntax

* Fixed accidental paste of TOLOWER

* Document why some test cases are commented out

Co-authored-by: Lars Melchior <TheLartians@users.noreply.github.com>

* Update README.md

Co-authored-by: Lars Melchior <TheLartians@users.noreply.github.com>

* Removed GitHub as the default package shorthand provider

Co-authored-by: Lars Melchior <TheLartians@users.noreply.github.com>

.cmake-format

@@ -33,6 +33,7 @@ parse:
         DOWNLOAD_NO_EXTRACT: 1
         HTTP_USERNAME: 1
         HTTP_PASSWORD: 1
+        EXCLUDE_FROM_ALL: 1
         OPTIONS: +
     cpmfindpackage:
       pargs:

.gitignore

@@ -1,3 +1,4 @@
+build/
 /build*
 /.vscode
 *.DS_Store

README.md

@@ -1,7 +1,7 @@
-[![Build Status](https://travis-ci.com/TheLartians/CPM.cmake.svg?branch=master)](https://travis-ci.com/TheLartians/CPM.cmake)
-[![Actions Status](https://github.com/TheLartians/CPM.cmake/workflows/MacOS/badge.svg)](https://github.com/TheLartians/CPM.cmake/actions)
-[![Actions Status](https://github.com/TheLartians/CPM.cmake/workflows/Windows/badge.svg)](https://github.com/TheLartians/CPM.cmake/actions)
-[![Actions Status](https://github.com/TheLartians/CPM.cmake/workflows/Ubuntu/badge.svg)](https://github.com/TheLartians/CPM.cmake/actions) [![Join the chat at https://gitter.im/TheLartians/CPM.cmake](https://badges.gitter.im/TheLartians/CPM.cmake.svg)](https://gitter.im/TheLartians/CPM.cmake?utm_source=badge&utm_medium=badge&utm_campaign=pr-badge&utm_content=badge)
+[![Build Status](https://travis-ci.com/cpm-cmake/CPM.cmake.svg?branch=master)](https://travis-ci.com/cpm-cmake/CPM.cmake)
+[![Actions Status](https://github.com/cpm-cmake/CPM.cmake/workflows/MacOS/badge.svg)](https://github.com/cpm-cmake/CPM.cmake/actions)
+[![Actions Status](https://github.com/cpm-cmake/CPM.cmake/workflows/Windows/badge.svg)](https://github.com/cpm-cmake/CPM.cmake/actions)
+[![Actions Status](https://github.com/cpm-cmake/CPM.cmake/workflows/Ubuntu/badge.svg)](https://github.com/cpm-cmake/CPM.cmake/actions)
 
 <br />
 <p align="center">
@@ -47,6 +47,19 @@ On the other hand, if `VERSION` hasn't been explicitly specified, CPM can automa
 `GIT_TAG` can also be set to a specific commit or a branch name such as `master` to always download the most recent version.
 The optional argument `FIND_PACKAGE_ARGUMENTS` can be specified to a string of parameters that will be passed to `find_package` if enabled (see below).
 
+A single-argument compact syntax is also supported:
+
+```cmake
+# A git package from a given uri with a version
+CPMAddPackage("uri@version")
+# A git package from a given uri with a git tag or commit hash, or branch name
+CPMAddPackage("uri#tag")
+# A git package with both version and tag provided
+CPMAddPackage("uri@version#tag")
+```
+
+In the shorthand syntax if the URI is of the form `gh:user/name`, it is interpreted as GitHub URI and converted to `https://github.com/user/name.git`. If the URI is of the form `gl:user/name`, it is interpreted as a [GitLab](https://gitlab.com/explore/) URI and coverted to `https://gitlab.com/user/name.git`. Otherwise the URI used verbatim as a git URL.
+
 After calling `CPMAddPackage` or `CPMFindPackage`, the following variables are defined in the local scope, where `<dependency>` is the name of the dependency.
 
 - `<dependency>_SOURCE_DIR` is the path to the source of the dependency.
@@ -70,29 +83,25 @@ add_executable(tests tests.cpp)
 # add dependencies
 include(cmake/CPM.cmake)
 
-CPMAddPackage(
-  NAME Catch2
-  GITHUB_REPOSITORY catchorg/Catch2
-  VERSION 2.5.0
-)
+CPMAddPackage(gh:catchorg/Catch2@2.5.0)
 
 # link dependencies
 target_link_libraries(tests Catch2)
 ```
 
-See the [examples directory](https://github.com/TheLartians/CPM.cmake/tree/master/examples) for complete examples with source code and check [below](#snippets) or in the [wiki](https://github.com/TheLartians/CPM.cmake/wiki/More-Snippets) for example snippets.
+See the [examples directory](https://github.com/cpm-cmake/CPM.cmake/tree/master/examples) for complete examples with source code and check [below](#snippets) or in the [wiki](https://github.com/cpm-cmake/CPM.cmake/wiki/More-Snippets) for example snippets.
 
 ## Adding CPM
 
-To add CPM to your current project, simply add the [latest release](https://github.com/TheLartians/CPM.cmake/releases/latest) of `CPM.cmake` or `get_cpm.cmake` to your project's `cmake` directory.
+To add CPM to your current project, simply add the [latest release](https://github.com/cpm-cmake/CPM.cmake/releases/latest) of `CPM.cmake` or `get_cpm.cmake` to your project's `cmake` directory.
 The command below will perform this automatically.
 
 ```bash
 mkdir -p cmake
-wget -O cmake/CPM.cmake https://github.com/TheLartians/CPM.cmake/releases/latest/download/get_cpm.cmake
+wget -O cmake/CPM.cmake https://github.com/cpm-cmake/CPM.cmake/releases/latest/download/get_cpm.cmake
 ```
 
-You can also download CPM.cmake directly from your project's `CMakeLists.txt`. See the [wiki](https://github.com/TheLartians/CPM.cmake/wiki/Downloading-CPM.cmake-in-CMake) for more details.
+You can also download CPM.cmake directly from your project's `CMakeLists.txt`. See the [wiki](https://github.com/cpm-cmake/CPM.cmake/wiki/Downloading-CPM.cmake-in-CMake) for more details.
 
 ## Updating CPM
 
@@ -112,7 +121,7 @@ Dependencies using CPM will automatically use the updated script of the outermos
 ## Limitations
 
 - **No pre-built binaries** For every new build directory, all dependencies are initially downloaded and built from scratch. To avoid extra downloads it is recommend to set the [`CPM_SOURCE_CACHE`](#CPM_SOURCE_CACHE) environmental variable. Using a caching compiler such as [ccache](https://github.com/TheLartians/Ccache.cmake) can drastically reduce build time.
-- **Dependent on good CMakeLists** Many libraries do not have CMakeLists that work well for subprojects. Luckily this is slowly changing, however, until then, some manual configuration may be required (see the snippets [below](#snippets) for examples). For best practices on preparing projects for CPM, see the [wiki](https://github.com/TheLartians/CPM.cmake/wiki/Preparing-projects-for-CPM.cmake). 
+- **Dependent on good CMakeLists** Many libraries do not have CMakeLists that work well for subprojects. Luckily this is slowly changing, however, until then, some manual configuration may be required (see the snippets [below](#snippets) for examples). For best practices on preparing projects for CPM, see the [wiki](https://github.com/cpm-cmake/CPM.cmake/wiki/Preparing-projects-for-CPM.cmake).
 - **First version used** In diamond-shaped dependency graphs (e.g. `A` depends on `C`@1.1 and `B`, which itself depends on `C`@1.2 the first added dependency will be used (in this case `C`@1.1). In this case, B requires a newer version of `C` than `A`, so CPM will emit a warning. This can be easily resolved by adding a new version of the dependency in the outermost project, or by introducing a [package lock file](#package-lock).
 
 For projects with more complex needs and where an extra setup step doesn't matter, it may be worth to check out an external C++ package manager such as [vcpkg](https://github.com/microsoft/vcpkg), [conan](https://conan.io) or [hunter](https://github.com/ruslo/hunter).
@@ -127,7 +136,7 @@ Additionally, it is difficult to cross-compile projects (e.g. for mobile), as th
 
 CPM.cmake allows dependencies to be unambiguously defined and builds them from source.
 Note that the behaviour differs from `find_package`, as variables exported to the parent scope (such as  `<PackageName>_LIBRARIES`) will not be visible after adding a package using CPM.cmake.
-The behaviour can be [achieved manually](https://github.com/TheLartians/CPM.cmake/issues/132#issuecomment-644955140), if required.
+The behaviour can be [achieved manually](https://github.com/cpm-cmake/CPM.cmake/issues/132#issuecomment-644955140), if required.
 
 ## Comparison to pure FetchContent / ExternalProject
 
@@ -160,7 +169,7 @@ export CPM_SOURCE_CACHE=$HOME/.cache/CPM
 
 Note that passing the variable as a configure option to CMake will always override the value set by the environmental variable.
 
-You can use `CPM_SOURCE_CACHE` on GitHub Actions workflows [cache](https://github.com/actions/cache) and combine it with ccache, to make your CI faster. See the [wiki](https://github.com/TheLartians/CPM.cmake/wiki/Caching-with-CPM.cmake-and-ccache-on-GitHub-Actions) for more info.
+You can use `CPM_SOURCE_CACHE` on GitHub Actions workflows [cache](https://github.com/actions/cache) and combine it with ccache, to make your CI faster. See the [wiki](https://github.com/cpm-cmake/CPM.cmake/wiki/Caching-with-CPM.cmake-and-ccache-on-GitHub-Actions) for more info.
 
 ### CPM_DOWNLOAD_ALL
 
@@ -201,7 +210,7 @@ cmake -Bbuild
 cmake --build build --target cpm-update-package-lock
 ```
 
-See the [wiki](https://github.com/TheLartians/CPM.cmake/wiki/Package-lock) for more info.
+See the [wiki](https://github.com/cpm-cmake/CPM.cmake/wiki/Package-lock) for more info.
 
 ## Built with CPM.cmake
 
@@ -240,26 +249,18 @@ If you know others, feel free to add them here through a PR.
 ## Snippets
 
 These examples demonstrate how to include some well-known projects with CPM.
-See the [wiki](https://github.com/TheLartians/CPM.cmake/wiki/More-Snippets) for more snippets.
+See the [wiki](https://github.com/cpm-cmake/CPM.cmake/wiki/More-Snippets) for more snippets.
 
 ### [Catch2](https://github.com/catchorg/Catch2)
 
 ```cmake
-CPMAddPackage(
-  NAME Catch2
-  GITHUB_REPOSITORY catchorg/Catch2
-  VERSION 2.5.0
-)
+CPMAddPackage(gh:catchorg/Catch2@2.5.0)
 ```
 
 ### [Boost (via boost-cmake)](https://github.com/Orphis/boost-cmake)
 
 ```CMake
-CPMAddPackage(
-  NAME boost-cmake
-  GITHUB_REPOSITORY Orphis/boost-cmake
-  VERSION 1.67.0
-)
+CPMAddPackage(gh:Orphis/boost-cmake@1.67.0)
 ```
 
 ### [cxxopts](https://github.com/jarro2783/cxxopts)
@@ -371,4 +372,4 @@ For a full example on using CPM to download and configure lua with sol2 see [her
 
 ### Full Examples
 
-See the [examples directory](https://github.com/TheLartians/CPM.cmake/tree/master/examples) for full examples with source code and check out the [wiki](https://github.com/TheLartians/CPM.cmake/wiki/More-Snippets) for many more example snippets.
+See the [examples directory](https://github.com/cpm-cmake/CPM.cmake/tree/master/examples) for full examples with source code and check out the [wiki](https://github.com/cpm-cmake/CPM.cmake/wiki/More-Snippets) for many more example snippets.

cmake/CPM.cmake

@@ -1,6 +1,6 @@
 # CPM.cmake - CMake's missing package manager
 # ===========================================
-# See https://github.com/TheLartians/CPM.cmake for usage and update instructions.
+# See https://github.com/cpm-cmake/CPM.cmake for usage and update instructions.
 #
 # MIT License
 # -----------
@@ -38,9 +38,12 @@ if(CPM_DIRECTORY)
           "${CPM_INDENT} \
 A dependency is using a more recent CPM version (${CURRENT_CPM_VERSION}) than the current project (${CPM_VERSION}). \
 It is recommended to upgrade CPM to the most recent version. \
-See https://github.com/TheLartians/CPM.cmake for more information."
+See https://github.com/cpm-cmake/CPM.cmake for more information."
       )
     endif()
+    if(${CMAKE_VERSION} VERSION_LESS "3.17.0")
+      include(FetchContent)
+    endif()
     return()
   endif()
 
@@ -131,9 +134,24 @@ endif()
 include(FetchContent)
 include(CMakeParseArguments)
 
+# Infer package name from git repository uri (path or url)
+function(cpm_package_name_from_git_uri URI RESULT)
+  if("${URI}" MATCHES "([^/:]+)/?.git/?$")
+    set(${RESULT}
+        ${CMAKE_MATCH_1}
+        PARENT_SCOPE
+    )
+  else()
+    unset(${RESULT} PARENT_SCOPE)
+  endif()
+endfunction()
+
 # Initialize logging prefix
 if(NOT CPM_INDENT)
-  set(CPM_INDENT "CPM:")
+  set(CPM_INDENT
+      "CPM:"
+      CACHE INTERNAL ""
+  )
 endif()
 
 function(cpm_find_package NAME VERSION)
@@ -234,8 +252,85 @@ function(cpm_check_if_package_already_added CPM_ARGS_NAME CPM_ARGS_VERSION CPM_A
   endif()
 endfunction()
 
+# Parse the argument of CPMAddPackage in case a single one was provided and convert it to a list of
+# arguments which can then be parsed idiomatically. For example gh:foo/bar@1.2.3 will be converted
+# to: GITHUB_REPOSITORY;foo/bar;VERSION;1.2.3
+function(cpm_parse_add_package_single_arg arg outArgs)
+  # Look for a scheme
+  if("${arg}" MATCHES "^([a-zA-Z]+):(.+)$")
+    string(TOLOWER "${CMAKE_MATCH_1}" scheme)
+    set(uri "${CMAKE_MATCH_2}")
+
+    # Check for CPM-specific schemes
+    if(scheme STREQUAL "gh")
+      set(out "GITHUB_REPOSITORY;${uri}")
+      set(packageType "git")
+    elseif(scheme STREQUAL "gl")
+      set(out "GITLAB_REPOSITORY;${uri}")
+      set(packageType "git")
+      # A CPM-specific scheme was not found. Looks like this is a generic URL so try to determine
+      # type
+    elseif(arg MATCHES ".git/?(@|#|$)")
+      set(out "GIT_REPOSITORY;${arg}")
+      set(packageType "git")
+    else()
+      # This error here is temporary. We can't provide URLs from here until we support inferring the
+      # package name from an url. When this is supported, remove this error as well as commented out
+      # tests in test/unit/parse_add_package_single_arg.cmake
+      message(FATAL_ERROR "CPM: Unsupported package type of '${arg}'")
+
+      # Fall back to a URL
+      set(out "URL;${arg}")
+      set(packageType "archive")
+
+      # We could also check for SVN since FetchContent supports it, but SVN is so rare these days.
+      # We just won't bother with the additional complexity it will induce in this function. SVN is
+      # done by multi-arg
+    endif()
+  else()
+    if(arg MATCHES ".git/?(@|#|$)")
+      set(out "GIT_REPOSITORY;${arg}")
+      set(packageType "git")
+    else()
+      # Give up
+      message(FATAL_ERROR "CPM: Can't determine package type of '${arg}'")
+    endif()
+  endif()
+
+  # For all packages we interpret @... as version. Only replace the last occurence. Thus URIs
+  # containing '@' can be used
+  string(REGEX REPLACE "@([^@]+)$" ";VERSION;\\1" out "${out}")
+
+  # Parse the rest according to package type
+  if(packageType STREQUAL "git")
+    # For git repos we interpret #... as a tag or branch or commit hash
+    string(REGEX REPLACE "#([^#]+)$" ";GIT_TAG;\\1" out "${out}")
+  elseif(packageType STREQUAL "archive")
+    # For archives we interpret #... as a URL hash.
+    string(REGEX REPLACE "#([^#]+)$" ";URL_HASH;\\1" out "${out}")
+    # We don't try to parse the version if it's not provided explicitly. cpm_get_version_from_url
+    # should do this at a later point
+  else()
+    # We should never get here. This is an assertion and hitting it means there's a bug in the code
+    # above. A packageType was set, but not handled by this if-else.
+    message(FATAL_ERROR "CPM: Unsupported package type '${packageType}' of '${arg}'")
+  endif()
+
+  set(${outArgs}
+      ${out}
+      PARENT_SCOPE
+  )
+endfunction()
+
 # Download and add a package from source
 function(CPMAddPackage)
+  list(LENGTH ARGN argnLength)
+  if(argnLength EQUAL 1)
+    cpm_parse_add_package_single_arg("${ARGN}" ARGN)
+
+    # The shorthand syntax implies EXCLUDE_FROM_ALL
+    set(ARGN "${ARGN};EXCLUDE_FROM_ALL;YES")
+  endif()
 
   set(oneValueArgs
       NAME
@@ -251,6 +346,7 @@ function(CPMAddPackage)
       FIND_PACKAGE_ARGUMENTS
       NO_CACHE
       GIT_SHALLOW
+      EXCLUDE_FROM_ALL
   )
 
   set(multiValueArgs OPTIONS)
@@ -284,6 +380,11 @@ function(CPMAddPackage)
     if(NOT DEFINED CPM_ARGS_GIT_TAG)
       set(CPM_ARGS_GIT_TAG v${CPM_ARGS_VERSION})
     endif()
+
+    # If a name wasn't provided, try to infer it from the git repo
+    if(NOT DEFINED CPM_ARGS_NAME)
+      cpm_package_name_from_git_uri(${CPM_ARGS_GIT_REPOSITORY} CPM_ARGS_NAME)
+    endif()
   endif()
 
   set(CPM_SKIP_FETCH FALSE)
@@ -296,6 +397,15 @@ function(CPMAddPackage)
     endif()
   endif()
 
+  # Check for required arguments
+
+  if(NOT DEFINED CPM_ARGS_NAME)
+    message(
+      FATAL_ERROR
+        "CPM: 'NAME' was not provided and couldn't be automatically inferred for package added with arguments: '${ARGN}'"
+    )
+  endif()
+
   # Check if package has been added before
   cpm_check_if_package_already_added(${CPM_ARGS_NAME} "${CPM_ARGS_VERSION}" "${CPM_ARGS_OPTIONS}")
   if(CPM_PACKAGE_ALREADY_ADDED)
@@ -381,7 +491,9 @@ function(CPMAddPackage)
       set(${CPM_ARGS_NAME}_ADDED YES)
       set(${CPM_ARGS_NAME}_SOURCE_DIR ${download_directory})
       if(NOT CPM_ARGS_DOWNLOAD_ONLY AND EXISTS ${download_directory}/CMakeLists.txt)
-        add_subdirectory(${download_directory} ${${CPM_ARGS_NAME}_BINARY_DIR})
+        cpm_add_subdirectory(
+          ${download_directory} ${${CPM_ARGS_NAME}_BINARY_DIR} "${CPM_ARGS_EXCLUDE_FROM_ALL}"
+        )
       endif()
       set(CPM_SKIP_FETCH TRUE)
       set(PACKAGE_INFO "${PACKAGE_INFO} at ${download_directory}")
@@ -421,7 +533,7 @@ function(CPMAddPackage)
     cpm_declare_fetch(
       "${CPM_ARGS_NAME}" "${CPM_ARGS_VERSION}" "${PACKAGE_INFO}" "${CPM_ARGS_UNPARSED_ARGUMENTS}"
     )
-    cpm_fetch_package("${CPM_ARGS_NAME}" "${DOWNLOAD_ONLY}")
+    cpm_fetch_package("${CPM_ARGS_NAME}" "${DOWNLOAD_ONLY}" "${CPM_ARGS_EXCLUDE_FROM_ALL}")
     cpm_get_fetch_properties("${CPM_ARGS_NAME}")
   endif()
 
@@ -464,14 +576,16 @@ endmacro()
 
 function(cpm_add_to_package_lock Name)
   if(NOT CPM_DONT_CREATE_PACKAGE_LOCK)
-    file(APPEND ${CPM_PACKAGE_LOCK_FILE} "# ${Name}\nCPMDeclarePackage(${Name} \"${ARGN}\")\n")
+    cpm_prettify_package_arguments(PRETTY_ARGN false ${ARGN})
+    file(APPEND ${CPM_PACKAGE_LOCK_FILE} "# ${Name}\nCPMDeclarePackage(${Name}\n${PRETTY_ARGN})\n")
   endif()
 endfunction()
 
 function(cpm_add_comment_to_package_lock Name)
   if(NOT CPM_DONT_CREATE_PACKAGE_LOCK)
+    cpm_prettify_package_arguments(PRETTY_ARGN true ${ARGN})
     file(APPEND ${CPM_PACKAGE_LOCK_FILE}
-         "# ${Name} (unversioned)\n# CPMDeclarePackage(${Name} \"${ARGN}\")\n"
+         "# ${Name} (unversioned)\n# CPMDeclarePackage(${Name}\n${PRETTY_ARGN}#)\n"
     )
   endif()
 endfunction()
@@ -542,24 +656,36 @@ function(cpm_get_fetch_properties PACKAGE)
   )
 endfunction()
 
+function(cpm_add_subdirectory SOURCE_DIR BINARY_DIR EXCLUDE)
+  if(EXCLUDE)
+    set(addSubdirectoryExtraArgs EXCLUDE_FROM_ALL)
+  else()
+    set(addSubdirectoryExtraArgs "")
+  endif()
+  add_subdirectory(${SOURCE_DIR} ${BINARY_DIR} ${addSubdirectoryExtraArgs})
+endfunction()
+
 # downloads a previously declared package via FetchContent
-function(cpm_fetch_package PACKAGE DOWNLOAD_ONLY)
+function(cpm_fetch_package PACKAGE DOWNLOAD_ONLY EXCLUDE)
   if(${CPM_DRY_RUN})
     message(STATUS "${CPM_INDENT} package ${PACKAGE} not fetched (dry run)")
     return()
   endif()
 
-  if(DOWNLOAD_ONLY)
   FetchContent_GetProperties(${PACKAGE})
-    if(NOT ${PACKAGE}_POPULATED)
+  string(TOLOWER "${PACKAGE}" lower_case_name)
+
+  if(NOT ${lower_case_name}_POPULATED)
     FetchContent_Populate(${PACKAGE})
-    endif()
-  else()
+    if(NOT DOWNLOAD_ONLY AND EXISTS ${${lower_case_name}_SOURCE_DIR}/CMakeLists.txt)
       set(CPM_OLD_INDENT "${CPM_INDENT}")
       set(CPM_INDENT "${CPM_INDENT} ${PACKAGE}:")
-    FetchContent_MakeAvailable(${PACKAGE})
+      cpm_add_subdirectory(
+        ${${lower_case_name}_SOURCE_DIR} ${${lower_case_name}_BINARY_DIR} "${EXCLUDE}"
+      )
       set(CPM_INDENT "${CPM_OLD_INDENT}")
     endif()
+  endif()
 endfunction()
 
 # splits a package option
@@ -625,3 +751,68 @@ function(cpm_is_git_tag_commit_hash GIT_TAG RESULT)
     endif()
   endif()
 endfunction()
+
+function(cpm_prettify_package_arguments OUT_VAR IS_IN_COMMENT)
+  set(oneValueArgs
+      NAME
+      FORCE
+      VERSION
+      GIT_TAG
+      DOWNLOAD_ONLY
+      GITHUB_REPOSITORY
+      GITLAB_REPOSITORY
+      GIT_REPOSITORY
+      SOURCE_DIR
+      DOWNLOAD_COMMAND
+      FIND_PACKAGE_ARGUMENTS
+      NO_CACHE
+      GIT_SHALLOW
+  )
+  set(multiValueArgs OPTIONS)
+  cmake_parse_arguments(CPM_ARGS "" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  foreach(oneArgName ${oneValueArgs})
+    if(DEFINED CPM_ARGS_${oneArgName})
+      if(${IS_IN_COMMENT})
+        string(APPEND PRETTY_OUT_VAR "#")
+      endif()
+      if(${oneArgName} STREQUAL "SOURCE_DIR")
+        string(REPLACE ${CMAKE_SOURCE_DIR} "\${CMAKE_SOURCE_DIR}" CPM_ARGS_${oneArgName}
+                       ${CPM_ARGS_${oneArgName}}
+        )
+      endif()
+      string(APPEND PRETTY_OUT_VAR "  ${oneArgName} ${CPM_ARGS_${oneArgName}}\n")
+    endif()
+  endforeach()
+  foreach(multiArgName ${multiValueArgs})
+    if(DEFINED CPM_ARGS_${multiArgName})
+      if(${IS_IN_COMMENT})
+        string(APPEND PRETTY_OUT_VAR "#")
+      endif()
+      string(APPEND PRETTY_OUT_VAR "  ${multiArgName}\n")
+      foreach(singleOption ${CPM_ARGS_${multiArgName}})
+        if(${IS_IN_COMMENT})
+          string(APPEND PRETTY_OUT_VAR "#")
+        endif()
+        string(APPEND PRETTY_OUT_VAR "    \"${singleOption}\"\n")
+      endforeach()
+    endif()
+  endforeach()
+
+  if(NOT "${CPM_ARGS_UNPARSED_ARGUMENTS}" STREQUAL "")
+    if(${IS_IN_COMMENT})
+      string(APPEND PRETTY_OUT_VAR "#")
+    endif()
+    string(APPEND PRETTY_OUT_VAR " ")
+    foreach(CPM_ARGS_UNPARSED_ARGUMENT ${CPM_ARGS_UNPARSED_ARGUMENTS})
+      string(APPEND PRETTY_OUT_VAR " ${CPM_ARGS_UNPARSED_ARGUMENT}")
+    endforeach()
+    string(APPEND PRETTY_OUT_VAR "\n")
+  endif()
+
+  set(${OUT_VAR}
+      ${PRETTY_OUT_VAR}
+      PARENT_SCOPE
+  )
+
+endfunction()

cmake/get_cpm.cmake

@@ -13,7 +13,7 @@ endif()
 if(NOT (EXISTS ${CPM_DOWNLOAD_LOCATION}))
   message(STATUS "Downloading CPM.cmake to ${CPM_DOWNLOAD_LOCATION}")
   file(DOWNLOAD
-       https://github.com/TheLartians/CPM.cmake/releases/download/v${CPM_DOWNLOAD_VERSION}/CPM.cmake
+       https://github.com/cpm-cmake/CPM.cmake/releases/download/v${CPM_DOWNLOAD_VERSION}/CPM.cmake
        ${CPM_DOWNLOAD_LOCATION}
   )
 endif()

cmake/testing.cmake

@@ -3,13 +3,25 @@ function(ASSERT_EQUAL)
     message(FATAL_ERROR "assertion failed: invalid argument count: ${ARGC}")
   endif()
 
-  if(NOT ${ARGV0} STREQUAL ${ARGV1})
+  if(NOT "${ARGV0}" STREQUAL "${ARGV1}")
     message(FATAL_ERROR "assertion failed: '${ARGV0}' != '${ARGV1}'")
   else()
     message(STATUS "test passed: '${ARGV0}' == '${ARGV1}'")
   endif()
 endfunction()
 
+function(ASSERT_NOT_EQUAL)
+  if(NOT ARGC EQUAL 2)
+    message(FATAL_ERROR "assertion failed: invalid argument count: ${ARGC}")
+  endif()
+
+  if("${ARGV0}" STREQUAL "${ARGV1}")
+    message(FATAL_ERROR "assertion failed: '${ARGV0}' == '${ARGV1}'")
+  else()
+    message(STATUS "test passed: '${ARGV0}' != '${ARGV1}'")
+  endif()
+endfunction()
+
 function(ASSERT_EMPTY)
   if(NOT ARGC EQUAL 0)
     message(FATAL_ERROR "assertion failed: input ${ARGC} not empty: '${ARGV}'")
@@ -24,6 +36,14 @@ function(ASSERT_DEFINED KEY)
   endif()
 endfunction()
 
+function(ASSERT_NOT_DEFINED KEY)
+  if(DEFINED ${KEY})
+    message(FATAL_ERROR "assertion failed: '${KEY}' is defiend")
+  else()
+    message(STATUS "test passed: '${KEY}' is not defined")
+  endif()
+endfunction()
+
 function(ASSERT_TRUTHY KEY)
   if(${${KEY}})
     message(STATUS "test passed: '${KEY}' is set truthy")

examples/asio-standalone/CMakeLists.txt

@@ -10,9 +10,9 @@ find_package(Threads REQUIRED)
 
 CPMAddPackage(
   NAME asio
-  VERSION 1.16.1
+  VERSION 1.18.1
   GITHUB_REPOSITORY chriskohlhoff/asio
-  GIT_TAG asio-1-16-1 # asio uses non-standard version tag, we must specify GIT_TAG
+  GIT_TAG asio-1-18-1 # asio uses non-standard version tag, we must specify GIT_TAG
 )
 
 # ASIO doesn't use CMake, we have to configure it manually. Extra notes for using on Windows:
@@ -24,7 +24,7 @@ CPMAddPackage(
 if(asio_ADDED)
   add_library(asio INTERFACE)
 
-  target_include_directories(asio INTERFACE ${asio_SOURCE_DIR}/asio/include)
+  target_include_directories(asio SYSTEM INTERFACE ${asio_SOURCE_DIR}/asio/include)
 
   target_compile_definitions(asio INTERFACE ASIO_STANDALONE ASIO_NO_DEPRECATED)
 
@@ -65,3 +65,4 @@ endif()
 
 add_executable(CPMExampleASIOStandalone main.cpp)
 target_link_libraries(CPMExampleASIOStandalone asio)
+target_compile_features(CPMExampleASIOStandalone PRIVATE cxx_std_11)

examples/benchmark/CMakeLists.txt

@@ -15,17 +15,17 @@ CPMAddPackage(
 CPMAddPackage(
   NAME benchmark
   GITHUB_REPOSITORY google/benchmark
-  VERSION 1.5.0
+  VERSION 1.5.2
   OPTIONS "BENCHMARK_ENABLE_TESTING Off"
 )
 
 if(benchmark_ADDED)
-  # patch google benchmark target
-  set_target_properties(benchmark PROPERTIES CXX_STANDARD 17)
+  # Don't use C++14 because it doesn't work in some configurations.
+  set_target_properties(benchmark PROPERTIES CXX_STANDARD 11)
 endif()
 
 # ---- Executable ----
 
 add_executable(CPMExampleBenchmark "main.cpp")
-set_target_properties(CPMExampleBenchmark PROPERTIES CXX_STANDARD 17)
 target_link_libraries(CPMExampleBenchmark fibonacci benchmark)
+target_compile_features(CPMExampleBenchmark PRIVATE cxx_std_17)

examples/boost/CMakeLists.txt

@@ -5,7 +5,7 @@ project(CPMExampleBoost)
 # ---- Create binary ----
 
 add_executable(CPMExampleBoost main.cpp)
-set_target_properties(CPMExampleBoost PROPERTIES CXX_STANDARD 17)
+target_compile_features(CPMExampleBoost PRIVATE cxx_std_17)
 
 # ---- Dependencies ----
 
@@ -18,4 +18,6 @@ CPMFindPackage(
   FIND_PACKAGE_ARGUMENTS "COMPONENTS system"
 )
 
-target_link_libraries(CPMExampleBoost PRIVATE Boost::system pthread)
+find_package(Threads REQUIRED)
+
+target_link_libraries(CPMExampleBoost PRIVATE Boost::system Threads::Threads)

examples/build_all.py

@@ -1,5 +1,7 @@
 #!/usr/bin/python3
 
+import os
+
 from pathlib import Path
 from subprocess import PIPE, run
 
@@ -9,6 +11,7 @@ examples = [
 
 assert(len(examples) > 0)
 
+
 def runCommand(command):
   print('- %s' % command)
   result = run(command, stdout=PIPE, stderr=PIPE, universal_newlines=True, shell=True)
@@ -17,6 +20,7 @@ def runCommand(command):
     exit(result.returncode)
   return result.stdout
 
+
 print('')
 for example in examples:
   print("running example %s" % example.name)
@@ -24,6 +28,6 @@ for example in examples:
   project = Path(".") / 'build' / example.name
   configure = runCommand('cmake -H%s -B%s' % (example, project))
   print('  ' + '\n  '.join([line for line in configure.split('\n') if 'CPM:' in line]))
-  build = runCommand('cmake --build %s -j4' % (project))
+  build = runCommand('cmake --build %s -- -j%i' % (project, os.cpu_count() / 2))
   print('  ' + '\n  '.join([line for line in build.split('\n') if 'Built target' in line]))
   print('')

examples/catch2/CMakeLists.txt

@@ -15,14 +15,14 @@ CPMAddPackage(
 CPMAddPackage(
   NAME Catch2
   GITHUB_REPOSITORY catchorg/Catch2
-  VERSION 2.5.0
+  VERSION 2.13.4
 )
 
 # ---- Create binary ----
 
 add_executable(CPMExampleCatch2 main.cpp)
 target_link_libraries(CPMExampleCatch2 fibonacci Catch2)
-set_target_properties(CPMExampleCatch2 PROPERTIES CXX_STANDARD 17)
+target_compile_features(CPMExampleCatch2 PRIVATE cxx_std_17)
 
 # ---- Enable testing ----
 

examples/cereal/CMakeLists.txt

@@ -8,7 +8,7 @@ include(../../cmake/CPM.cmake)
 
 CPMAddPackage(
   NAME cereal
-  VERSION 1.2.2
+  VERSION 1.3.0
   GITHUB_REPOSITORY USCiLab/cereal
   OPTIONS "SKIP_PORTABILITY_TEST ON" "JUST_INSTALL_CEREAL ON"
 )
@@ -17,4 +17,4 @@ CPMAddPackage(
 
 add_executable(CPMExampleCereal main.cpp)
 target_link_libraries(CPMExampleCereal cereal)
-set_target_properties(CPMExampleCereal PROPERTIES CXX_STANDARD 17)
+target_compile_features(CPMExampleCereal PRIVATE cxx_std_17)

examples/cxxopts/CMakeLists.txt

@@ -17,4 +17,4 @@ CPMAddPackage(
 
 add_executable(CPMExampleCXXOpts main.cpp)
 target_link_libraries(CPMExampleCXXOpts cxxopts)
-set_target_properties(CPMExampleCXXOpts PROPERTIES CXX_STANDARD 17)
+target_compile_features(CPMExampleCXXOpts PRIVATE cxx_std_17)

examples/doctest/CMakeLists.txt

@@ -15,14 +15,14 @@ CPMAddPackage(
 CPMAddPackage(
   NAME doctest
   GITHUB_REPOSITORY onqtam/doctest
-  GIT_TAG 2.3.2
+  GIT_TAG 2.4.5
 )
 
 # ---- Create binary ----
 
 add_executable(CPMExampleDoctest main.cpp)
 target_link_libraries(CPMExampleDoctest fibonacci doctest)
-set_target_properties(CPMExampleDoctest PROPERTIES CXX_STANDARD 17)
+target_compile_features(CPMExampleDoctest PRIVATE cxx_std_17)
 
 # ---- Enable testing ----
 

examples/entt/CMakeLists.txt

@@ -16,11 +16,11 @@ CPMAddPackage(
 
 if(EnTT_ADDED)
   add_library(EnTT INTERFACE)
-  target_include_directories(EnTT INTERFACE ${EnTT_SOURCE_DIR}/src)
+  target_include_directories(EnTT SYSTEM INTERFACE ${EnTT_SOURCE_DIR}/src)
 endif()
 
 # ---- Executable ----
 
-add_executable(CPMEnTTExample "main.cpp")
-set_target_properties(CPMEnTTExample PROPERTIES CXX_STANDARD 17)
+add_executable(CPMEnTTExample main.cpp)
+target_compile_features(CPMEnTTExample PRIVATE cxx_std_17)
 target_link_libraries(CPMEnTTExample EnTT)

examples/fmt/CMakeLists.txt

@@ -8,12 +8,12 @@ include(../../cmake/CPM.cmake)
 
 CPMAddPackage(
   NAME fmt
-  GIT_TAG 6.1.2
+  GIT_TAG 7.1.3
   GITHUB_REPOSITORY fmtlib/fmt
 )
 
 # ---- Executable ----
 
-add_executable(CPMFmtExample "main.cpp")
-set_target_properties(CPMFmtExample PROPERTIES CXX_STANDARD 17)
+add_executable(CPMFmtExample main.cpp)
+target_compile_features(CPMFmtExample PRIVATE cxx_std_17)
 target_link_libraries(CPMFmtExample fmt)

examples/gtest/CMakeLists.txt

@@ -15,8 +15,8 @@ CPMAddPackage(
 CPMAddPackage(
   NAME googletest
   GITHUB_REPOSITORY google/googletest
-  GIT_TAG release-1.8.1
-  VERSION 1.8.1
+  GIT_TAG release-1.10.0
+  VERSION 1.10.0
   OPTIONS "INSTALL_GTEST OFF" "gtest_force_shared_crt"
 )
 
@@ -24,7 +24,7 @@ CPMAddPackage(
 
 add_executable(CPMExampleGtest main.cpp)
 target_link_libraries(CPMExampleGtest fibonacci gtest gtest_main gmock)
-set_target_properties(CPMExampleGtest PROPERTIES CXX_STANDARD 17)
+target_compile_features(CPMExampleGtest PRIVATE cxx_std_17)
 
 # ---- Enable testing ----
 

examples/json/CMakeLists.txt

@@ -8,19 +8,19 @@ include(../../cmake/CPM.cmake)
 
 CPMAddPackage(
   NAME nlohmann_json
-  VERSION 3.6.1
+  VERSION 3.9.1
   # not using the repo as it takes forever to clone
-  URL https://github.com/nlohmann/json/releases/download/v3.6.1/include.zip
-  URL_HASH SHA256=69cc88207ce91347ea530b227ff0776db82dcb8de6704e1a3d74f4841bc651cf
+  URL https://github.com/nlohmann/json/releases/download/v3.9.1/include.zip
+  URL_HASH SHA256=6bea5877b1541d353bd77bdfbdb2696333ae5ed8f9e8cc22df657192218cad91
 )
 
 if(nlohmann_json_ADDED)
   add_library(nlohmann_json INTERFACE)
-  target_include_directories(nlohmann_json INTERFACE ${nlohmann_json_SOURCE_DIR})
+  target_include_directories(nlohmann_json SYSTEM INTERFACE ${nlohmann_json_SOURCE_DIR}/include)
 endif()
 
 # ---- Executable ----
 
-add_executable(CPMJSONExample "main.cpp")
-set_target_properties(CPMJSONExample PROPERTIES CXX_STANDARD 17)
+add_executable(CPMJSONExample main.cpp)
+target_compile_features(CPMJSONExample PRIVATE cxx_std_17)
 target_link_libraries(CPMJSONExample nlohmann_json)

examples/linenoise/CMakeLists.txt

@@ -14,11 +14,11 @@ CPMAddPackage(
 
 if(linenoise_ADDED)
   add_library(linenoise ${linenoise_SOURCE_DIR}/linenoise.c)
-  target_include_directories(linenoise PUBLIC ${linenoise_SOURCE_DIR})
+  target_include_directories(linenoise SYSTEM PUBLIC ${linenoise_SOURCE_DIR})
 endif()
 
 # ---- Executable ----
 
-add_executable(CPMlinenoiseExample "main.cpp")
-set_target_properties(CPMlinenoiseExample PROPERTIES CXX_STANDARD 17)
+add_executable(CPMlinenoiseExample main.cpp)
+target_compile_features(CPMlinenoiseExample PRIVATE cxx_std_17)
 target_link_libraries(CPMlinenoiseExample linenoise)

examples/range-v3/CMakeLists.txt

@@ -8,19 +8,19 @@ include(../../cmake/CPM.cmake)
 
 CPMAddPackage(
   NAME range-v3
-  URL https://github.com/ericniebler/range-v3/archive/0.5.0.zip
-  VERSION 0.5.0
+  URL https://github.com/ericniebler/range-v3/archive/0.11.0.zip
+  VERSION 0.11.0
   # the range-v3 CMakeLists screws with configuration options
   DOWNLOAD_ONLY True
 )
 
 if(range-v3_ADDED)
   add_library(range-v3 INTERFACE IMPORTED)
-  target_include_directories(range-v3 INTERFACE "${range-v3_SOURCE_DIR}/include")
+  target_include_directories(range-v3 SYSTEM INTERFACE "${range-v3_SOURCE_DIR}/include")
 endif()
 
 # ---- Executable ----
 
-add_executable(CPMRangev3Example "main.cpp")
-set_target_properties(CPMRangev3Example PROPERTIES CXX_STANDARD 17)
+add_executable(CPMRangev3Example main.cpp)
+target_compile_features(CPMRangev3Example PRIVATE cxx_std_17)
 target_link_libraries(CPMRangev3Example range-v3)

examples/simple_match/CMakeLists.txt

@@ -15,11 +15,11 @@ CPMAddPackage(
 
 if(simple_match_ADDED)
   add_library(simple_match INTERFACE IMPORTED)
-  target_include_directories(simple_match INTERFACE "${simple_match_SOURCE_DIR}/include")
+  target_include_directories(simple_match SYSTEM INTERFACE "${simple_match_SOURCE_DIR}/include")
 endif()
 
 # ---- Executable ----
 
-add_executable(CPMSimpleMatchExample "main.cpp")
-set_target_properties(CPMSimpleMatchExample PROPERTIES CXX_STANDARD 17)
+add_executable(CPMSimpleMatchExample main.cpp)
+target_compile_features(CPMSimpleMatchExample PRIVATE cxx_std_17)
 target_link_libraries(CPMSimpleMatchExample simple_match)

examples/sol2/CMakeLists.txt

@@ -20,7 +20,7 @@ if(lua_ADDED)
   list(REMOVE_ITEM lua_sources "${lua_SOURCE_DIR}/lua.c" "${lua_SOURCE_DIR}/luac.c")
   add_library(lua STATIC ${lua_sources})
 
-  target_include_directories(lua PUBLIC $<BUILD_INTERFACE:${lua_SOURCE_DIR}>)
+  target_include_directories(lua SYSTEM PUBLIC $<BUILD_INTERFACE:${lua_SOURCE_DIR}>)
 endif()
 
 CPMAddPackage(
@@ -32,12 +32,12 @@ CPMAddPackage(
 
 if(sol2_ADDED)
   add_library(sol2 INTERFACE IMPORTED)
-  target_include_directories(sol2 INTERFACE ${sol2_SOURCE_DIR}/include)
+  target_include_directories(sol2 SYSTEM INTERFACE ${sol2_SOURCE_DIR}/include)
   target_link_libraries(sol2 INTERFACE lua)
 endif()
 
 # ---- Executable ----
 
-add_executable(CPMSol2Example "main.cpp")
-set_target_properties(CPMSol2Example PROPERTIES CXX_STANDARD 17)
+add_executable(CPMSol2Example main.cpp)
+target_compile_features(CPMSol2Example PRIVATE cxx_std_17)
 target_link_libraries(CPMSol2Example sol2)

examples/spdlog/CMakeLists.txt

@@ -9,11 +9,11 @@ include(../../cmake/CPM.cmake)
 CPMAddPackage(
   NAME spdlog
   GITHUB_REPOSITORY gabime/spdlog
-  VERSION 1.7.0
+  VERSION 1.8.2
 )
 
 # ---- Executable ----
 
-add_executable(CPMSpdlogExample "main.cpp")
-set_target_properties(CPMSpdlogExample PROPERTIES CXX_STANDARD 17)
+add_executable(CPMSpdlogExample main.cpp)
+target_compile_features(CPMSpdlogExample PRIVATE cxx_std_17)
 target_link_libraries(CPMSpdlogExample spdlog)

examples/yaml/CMakeLists.txt

@@ -9,15 +9,13 @@ include(../../cmake/CPM.cmake)
 CPMAddPackage(
   NAME yaml-cpp
   GIT_REPOSITORY https://github.com/jbeder/yaml-cpp.git
-  # 0.6.2 uses deprecated CMake syntax
   VERSION 0.6.3
-  # 0.6.3 is not released yet, so use the most recent commit
-  GIT_TAG 012269756149ae99745b6dafefd415843d7420bb
+  GIT_TAG yaml-cpp-0.6.3
   OPTIONS "YAML_CPP_BUILD_TESTS Off" "YAML_CPP_BUILD_CONTRIB Off" "YAML_CPP_BUILD_TOOLS Off"
 )
 
 # ---- Executable ----
 
-add_executable(CPMYamlExample "main.cpp")
-set_target_properties(CPMYamlExample PROPERTIES CXX_STANDARD 17)
+add_executable(CPMYamlExample main.cpp)
+target_compile_features(CPMYamlExample PRIVATE cxx_std_17)
 target_link_libraries(CPMYamlExample yaml-cpp)

test/unit/broken_dependency/.gitignore

@@ -0,0 +1,2 @@
+/CMakeLists.txt
+/package-lock.cmake

test/unit/broken_dependency/CMakeLists.txt.in

@@ -0,0 +1,13 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+project(CPMTest)
+
+# ---- Dependencies ----
+
+include(@CPM_PATH@/CPM.cmake)
+
+CPMAddPackage(
+  NAME BrokenDependency
+  SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/dependency
+  EXCLUDE_FROM_ALL @EXCLUDE_FROM_ALL@
+)

test/unit/broken_dependency/dependency/CMakeLists.txt

@@ -0,0 +1,3 @@
+project(BrokenDependency)
+
+add_custom_target(error ALL ${CMAKE_COMMAND} -E false)

test/unit/exclude_from_all.cmake

@@ -0,0 +1,35 @@
+include(CMakePackageConfigHelpers)
+include(${CPM_PATH}/testing.cmake)
+
+set(TEST_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/exclude_from_all)
+
+function(init_project EXCLUDE_FROM_ALL)
+  configure_package_config_file(
+    "${CMAKE_CURRENT_LIST_DIR}/broken_dependency/CMakeLists.txt.in"
+    "${CMAKE_CURRENT_LIST_DIR}/broken_dependency/CMakeLists.txt"
+    INSTALL_DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/junk
+  )
+
+  execute_process(
+    COMMAND ${CMAKE_COMMAND} "-H${CMAKE_CURRENT_LIST_DIR}/broken_dependency" "-B${TEST_BUILD_DIR}"
+    RESULT_VARIABLE ret
+  )
+
+  assert_equal(${ret} "0")
+endfunction()
+
+function(build_project expected_success)
+  execute_process(COMMAND ${CMAKE_COMMAND} "--build" "${TEST_BUILD_DIR}" RESULT_VARIABLE ret)
+
+  if(expected_success)
+    assert_equal(${ret} 0)
+  else()
+    assert_not_equal(${ret} 0)
+  endif()
+endfunction()
+
+init_project(FALSE)
+build_project(FALSE)
+
+init_project(TRUE)
+build_project(TRUE)

test/unit/package-lock_prettify.cmake

@@ -0,0 +1,42 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+include(${CPM_PATH}/CPM.cmake)
+include(${CPM_PATH}/testing.cmake)
+
+# cmake-format: off
+cpm_prettify_package_arguments(PRETTY_ARGN false
+  NAME Dependency
+  SOURCE_DIR ${CMAKE_SOURCE_DIR}/local_dependency/dependency
+  UPDATE_DISCONNECTED ON
+  TESTCUSTOMDATA TRUE
+)
+# cmake-format: on
+set(EXPECTED_UNCOMMENTED
+    "  NAME Dependency
+  SOURCE_DIR \${CMAKE_SOURCE_DIR}/local_dependency/dependency
+  UPDATE_DISCONNECTED ON TESTCUSTOMDATA TRUE
+"
+)
+assert_equal(${PRETTY_ARGN} ${EXPECTED_UNCOMMENTED})
+
+# cmake-format: off
+cpm_prettify_package_arguments(PRETTY_ARGN true
+  NAME Dependency
+  SOURCE_DIR ${CMAKE_SOURCE_DIR}/local_dependency/dependency
+  UPDATE_DISCONNECTED ON
+  TESTCUSTOMDATA TRUE
+)
+# cmake-format: on
+set(EXPECTED_COMMENTED
+    "#  NAME Dependency
+#  SOURCE_DIR \${CMAKE_SOURCE_DIR}/local_dependency/dependency
+#  UPDATE_DISCONNECTED ON TESTCUSTOMDATA TRUE
+"
+)
+assert_equal(${PRETTY_ARGN} ${EXPECTED_COMMENTED})
+
+cpm_prettify_package_arguments(PRETTY_ARGN true "local directory")
+set(EXPECTED_COMMENTED_LOCALDIR "#  local directory
+"
+)
+assert_equal(${PRETTY_ARGN} ${EXPECTED_COMMENTED_LOCALDIR})

test/unit/package_name_from_git_uri.cmake

@@ -0,0 +1,28 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+include(${CPM_PATH}/CPM.cmake)
+include(${CPM_PATH}/testing.cmake)
+
+cpm_package_name_from_git_uri("https://github.com/cpm-cmake/CPM.cmake.git" name)
+assert_equal("CPM.cmake" ${name})
+
+cpm_package_name_from_git_uri("ssh://user@host.xz:123/path/to/pkg.git/" name)
+assert_equal("pkg" ${name})
+
+cpm_package_name_from_git_uri("git://host.xz/path/to/pkg.git" name)
+assert_equal("pkg" ${name})
+
+cpm_package_name_from_git_uri("git@host.xz:cool-pkg.git" name)
+assert_equal("cool-pkg" ${name})
+
+cpm_package_name_from_git_uri("file:///path/to/pkg33.git" name)
+assert_equal("pkg33" ${name})
+
+cpm_package_name_from_git_uri("../local-repo/.git" name)
+assert_equal("local-repo" ${name})
+
+cpm_package_name_from_git_uri("asdf" name)
+assert_not_defined(name)
+
+cpm_package_name_from_git_uri("/something.git/stuff" name)
+assert_not_defined(name)

test/unit/parse_add_package_single_arg.cmake

@@ -0,0 +1,64 @@
+cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
+
+include(${CPM_PATH}/CPM.cmake)
+include(${CPM_PATH}/testing.cmake)
+
+cpm_parse_add_package_single_arg("gh:cpm-cmake/CPM.cmake" args)
+assert_equal("GITHUB_REPOSITORY;cpm-cmake/CPM.cmake" "${args}")
+
+cpm_parse_add_package_single_arg("gh:cpm-cmake/CPM.cmake@1.2.3" args)
+assert_equal("GITHUB_REPOSITORY;cpm-cmake/CPM.cmake;VERSION;1.2.3" "${args}")
+
+cpm_parse_add_package_single_arg("gh:cpm-cmake/CPM.cmake#master" args)
+assert_equal("GITHUB_REPOSITORY;cpm-cmake/CPM.cmake;GIT_TAG;master" "${args}")
+
+cpm_parse_add_package_single_arg("gh:cpm-cmake/CPM.cmake@0.20.3#asdf" args)
+assert_equal("GITHUB_REPOSITORY;cpm-cmake/CPM.cmake;VERSION;0.20.3;GIT_TAG;asdf" "${args}")
+
+cpm_parse_add_package_single_arg("gh:a/b#c@d" args)
+assert_equal("GITHUB_REPOSITORY;a/b;GIT_TAG;c;VERSION;d" "${args}")
+
+cpm_parse_add_package_single_arg("gh:foo#c@d" args)
+assert_equal("GITHUB_REPOSITORY;foo;GIT_TAG;c;VERSION;d" "${args}")
+
+cpm_parse_add_package_single_arg("gh:Foo@5" args)
+assert_equal("GITHUB_REPOSITORY;Foo;VERSION;5" "${args}")
+
+cpm_parse_add_package_single_arg("gl:foo/bar" args)
+assert_equal("GITLAB_REPOSITORY;foo/bar" "${args}")
+
+cpm_parse_add_package_single_arg("gl:foo/Bar" args)
+assert_equal("GITLAB_REPOSITORY;foo/Bar" "${args}")
+
+cpm_parse_add_package_single_arg("https://github.com/cpm-cmake/CPM.cmake.git@0.30.5" args)
+assert_equal("GIT_REPOSITORY;https://github.com/cpm-cmake/CPM.cmake.git;VERSION;0.30.5" "${args}")
+
+cpm_parse_add_package_single_arg("git@host.xz:user/pkg.git@0.1.2" args)
+assert_equal("GIT_REPOSITORY;git@host.xz:user/pkg.git;VERSION;0.1.2" "${args}")
+
+cpm_parse_add_package_single_arg("git@host.xz:user/pkg.git@0.1.2#rc" args)
+assert_equal("GIT_REPOSITORY;git@host.xz:user/pkg.git;VERSION;0.1.2;GIT_TAG;rc" "${args}")
+
+cpm_parse_add_package_single_arg(
+  "ssh://user@host.xz:123/path/to/pkg.git#fragment@1.2.3#branch" args
+)
+assert_equal(
+  "GIT_REPOSITORY;ssh://user@host.xz:123/path/to/pkg.git#fragment;VERSION;1.2.3;GIT_TAG;branch"
+  "${args}"
+)
+
+# The following test cases are to be used in the future, once single-argument archives are supported
+
+# cpm_parse_add_package_single_arg("https://example.org/foo.tar.gz" args)
+
+# assert_equal("URL;https://example.org/foo.tar.gz" "${args}")
+
+# cpm_parse_add_package_single_arg("https://example.org/foo.tar.gz#baadf00d@1.2.0" args)
+
+# assert_equal("URL;https://example.org/foo.tar.gz;URL_HASH;baadf00d;VERSION;1.2.0" "${args}")
+
+# cpm_parse_add_package_single_arg("ftp://user:password@server/pathname.zip#fragment#0ddb411@0"
+# args)
+
+# assert_equal("URL;ftp://user:password@server/pathname.zip#fragment;URL_HASH;0ddb411;VERSION;0"
+# "${args}")