mirror of
https://github.com/microsoft/vcpkg.git
synced 2024-12-27 10:21:07 +08:00
c69f2b9098
* [vcpkg tool] Add vcpkg_install_copyright
* Make sure FILE_LIST is provided
* relative to ${SOURCE_PATH}
* Add documentation
* Add to table of contents
* Relative paths was a bad idea.
* Tell users to use the correct way
Co-authored-by: Billy O'Neal <bion@microsoft.com>
* Fix docs
* Add parameter COMMENT
* Rename to vcpkg_concat_copyright
* Fix escape
* Revert "Fix escape"
This reverts commit 53f1636705396fe5e606bf67ef72e39edc35140f.
* Revert "Rename to vcpkg_concat_copyright"
This reverts commit 6ce9152a618b37e5a914248f6ca6c8b7b54ef3e3.
* Fix escape
* Add support for single copyright file
* Update docs
* Make comment less confusing
* [ci skip] Billy CR
* [ci skip] Format
* Remove explicit checks for STREQUAL ""
* Add error msg if file doesn't exist
Co-authored-by: Billy O'Neal <bion@microsoft.com>
43 lines
1.5 KiB
CMake
43 lines
1.5 KiB
CMake
function(vcpkg_install_copyright)
|
|
cmake_parse_arguments(PARSE_ARGV 0 arg "" "COMMENT" "FILE_LIST")
|
|
|
|
if(DEFINED arg_UNPARSED_ARGUMENTS)
|
|
message(FATAL_ERROR "${CMAKE_CURRENT_FUNCTION} was passed extra arguments: ${arg_UNPARSED_ARGUMENTS}")
|
|
endif()
|
|
|
|
if(NOT DEFINED arg_FILE_LIST)
|
|
message(FATAL_ERROR "FILE_LIST must be specified")
|
|
endif()
|
|
|
|
list(LENGTH arg_FILE_LIST FILE_LIST_LENGTH)
|
|
set(out_string "")
|
|
|
|
if(FILE_LIST_LENGTH LESS_EQUAL 0)
|
|
message(FATAL_ERROR "FILE_LIST must contain at least one file")
|
|
elseif(FILE_LIST_LENGTH EQUAL 1)
|
|
if(arg_COMMENT)
|
|
file(READ "${arg_FILE_LIST}" out_string)
|
|
else()
|
|
file(INSTALL "${arg_FILE_LIST}" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)
|
|
return()
|
|
endif()
|
|
else()
|
|
foreach(file_item IN LISTS arg_FILE_LIST)
|
|
if(NOT EXISTS "${file_item}")
|
|
message(FATAL_ERROR "\n${CMAKE_CURRENT_FUNCTION} was passed a non-existing path: ${file_item}\n")
|
|
endif()
|
|
|
|
get_filename_component(file_name "${file_item}" NAME)
|
|
file(READ "${file_item}" file_contents)
|
|
|
|
string(APPEND out_string "${file_name}:\n\n${file_contents}\n\n")
|
|
endforeach()
|
|
endif()
|
|
|
|
if(arg_COMMENT)
|
|
string(PREPEND out_string "${arg_COMMENT}\n\n")
|
|
endif()
|
|
|
|
file(WRITE "${CURRENT_PACKAGES_DIR}/share/${PORT}/copyright" "${out_string}")
|
|
endfunction()
|