Added FindHinnatDate.cmake to prevent usage of preset paths

Howard Hinnant's date and time library is found using a cmake Find-module.

Commit 377fbc8958 was reverted to ensure that the
exported target has the correct properties.

CMakeLists.txt

@@ -1,4 +1,5 @@
 # Copyright (c) 2013-2016, Roland Bock
+# Copyright (c) 2016 Christian Dávid
 # All rights reserved.
 #
 # Redistribution and use in source and binary forms, with or without modification,
@@ -27,27 +28,18 @@ project(sqlpp11 VERSION 0.1 LANGUAGES CXX)
 
 enable_testing()
 
+list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules/")
+find_package(HinnantDate REQUIRED)
+
 add_library(sqlpp11 INTERFACE)
 
-set(DATE_INCLUDE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../date" CACHE FILEPATH "Path to Howard Hinnant's date library")
+target_link_libraries(sqlpp11 INTERFACE HinnantDate::Date)
-
-if(NOT EXISTS ${DATE_INCLUDE_DIR}/date.h)
-	message(SEND_ERROR "Can't find file date.h and cannot compile date_test/date_test.cpp")
-	message("Can't find date.h in ${DATE_INCLUDE_DIR} ")
-	message("Please either")
-	message("  - git clone https://github.com/howardhinnant/date ${DATE_INCLUDE_DIR}")
-	message("  - download and unzip a current version from https://github.com/howardhinnant/date to ${DATE_INCLUDE_DIR}")
-	message("  - set DATE_INCLUDE_DIR to point to the dir containing date.h from the date library")
-	message("")
-endif()
 
 target_include_directories(sqlpp11 INTERFACE
-  $<BUILD_INTERFACE:${DATE_INCLUDE_DIR}>
   $<BUILD_INTERFACE:${sqlpp11_SOURCE_DIR}/include>
   $<INSTALL_INTERFACE:include>
   )
 
-if (NOT DEFINED MSVC)
 target_compile_features(sqlpp11 INTERFACE
 	cxx_alias_templates
 	cxx_auto_type
@@ -69,7 +61,6 @@ target_compile_features(sqlpp11 INTERFACE
 	cxx_template_template_parameters
   cxx_variadic_templates
   )
-endif ()
 
 install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/sqlpp11"
         DESTINATION include
@@ -106,13 +97,13 @@ install(EXPORT Sqlpp11Targets
 
 install(
   FILES
-    cmake/Sqlpp11Config.cmake
+    "cmake/Sqlpp11Config.cmake"
     "${CMAKE_CURRENT_BINARY_DIR}/cmake/Sqlpp11ConfigVersion.cmake"
+    "cmake/Modules/FindHinnantDate.cmake"
   DESTINATION
     ${ConfigPackageLocation}
 )
 
-
 add_subdirectory(tests)
 add_subdirectory(test_types)
 add_subdirectory(test_serializer)

cmake/Modules/FindHinnantDate.cmake

@@ -0,0 +1,83 @@
+#.rst:
+# FindHinnantDate
+# ---------------
+#
+# This module finds Howard Hinnant's date and time library for C++11 and beyond
+# See https://github.com/HowardHinnant/date for details.
+#
+# This will define the following variables::
+#
+#   HinnantDate_FOUND       - True if the system has the library
+#   HinnantDate_INCLUDE_DIR - The directory which includes the header
+#
+# and the following imported targets::
+#
+#   HinnantDate::Date   - The target to use date.h
+#
+# The target will enable the required C++11 standard in your compiler. You can
+# use any later standard but you have to enable them explicitly.
+
+# Copyright (c) 2016 Christian Dávid
+# All rights reserved.
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions are met:
+#
+#   Redistributions of source code must retain the above copyright notice, this
+#   list of conditions and the following disclaimer.
+#
+#   Redistributions in binary form must reproduce the above copyright notice,
+#   this list of conditions and the following disclaimer in the documentation
+#   and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
+# AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+# IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+# ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
+# LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
+# CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
+# SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
+# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
+# CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+# ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+# POSSIBILITY OF SUCH DAMAGE.
+
+cmake_minimum_required(VERSION 3.1)
+
+find_file(HinnantDate_INCLUDE_FILE
+    date.h
+    HINTS ${HinnantDate_INCLUDE_DIR}
+)
+
+if (HinnantDate_INCLUDE_FILE)
+    # Validate that correct file is found
+    file(STRINGS ${HinnantDate_INCLUDE_FILE} check_result
+        LIMIT_COUNT 1
+        REGEX "^ *// Copyright [(]c[)] 2015.* Howard Hinnant *$"
+    )
+
+    if("${check_result}" STREQUAL "")
+        message(STATUS "FindHinnantDate: Rejecting found '${HinnantDate_INCLUDE_FILE}', it seems to be a name twin.")
+        unset(HinnantDate_INCLUDE_FILE)
+    else()
+        # Check succeeded, create target
+        get_filename_component(HinnantDate_INCLUDE_DIR "${HinnantDate_INCLUDE_FILE}" DIRECTORY CACHE)
+        if(NOT TARGET HinnantDate::Date)
+            add_library(HinnantDate::Date INTERFACE IMPORTED)
+            set_target_properties(HinnantDate::Date PROPERTIES
+              INTERFACE_INCLUDE_DIRECTORIES "${HinnantDate_INCLUDE_DIR}"
+              INTERFACE_COMPILE_FEATURES "cxx_auto_type;cxx_static_assert;cxx_decltype;cxx_alias_templates;cxx_strong_enums"
+# Due to cmake restrictions the standard cannot be set directly to interface imported targets. Instead required compile
+# features are set (list maybe incomplete). Please note that this list shall be a minimal set of required features.
+#              CXX_STANDARD 11
+#              CXX_STANDARD_REQUIRED true
+            )
+        endif()
+    endif()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(HinnantDate
+    REQUIRED_VARS
+    HinnantDate_INCLUDE_DIR
+)

cmake/Sqlpp11Config.cmake

@@ -23,4 +23,9 @@
 # ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
 # POSSIBILITY OF SUCH DAMAGE.
 
+list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}")
+
+include(CMakeFindDependencyMacro)
+find_dependency(HinnantDate REQUIRED)
+
 include("${CMAKE_CURRENT_LIST_DIR}/Sqlpp11Targets.cmake")