mirror of
https://github.com/chromium/crashpad.git
synced 2025-01-14 01:08:01 +08:00
8742051c60
These are present on 10.7 and later, and were only provided for the benefit of older systems that probably aren’t relevant to Crashpad any longer. Change-Id: If9d7222f7af05020d0ff57d5d9ed06355fa14a48 Reviewed-on: https://chromium-review.googlesource.com/827686 Commit-Queue: Mark Mentovai <mark@chromium.org> Reviewed-by: Scott Graham <scottmg@chromium.org>
92 lines
2.0 KiB
Plaintext
92 lines
2.0 KiB
Plaintext
# Copyright 2015 The Crashpad Authors. All rights reserved.
|
||
#
|
||
# Licensed under the Apache License, Version 2.0 (the "License");
|
||
# you may not use this file except in compliance with the License.
|
||
# You may obtain a copy of the License at
|
||
#
|
||
# http://www.apache.org/licenses/LICENSE-2.0
|
||
#
|
||
# Unless required by applicable law or agreed to in writing, software
|
||
# distributed under the License is distributed on an "AS IS" BASIS,
|
||
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
||
# See the License for the specific language governing permissions and
|
||
# limitations under the License.
|
||
|
||
config("compat_config") {
|
||
include_dirs = []
|
||
|
||
if (is_win) {
|
||
include_dirs += [ "win" ]
|
||
} else {
|
||
include_dirs += [ "non_win" ]
|
||
}
|
||
|
||
if (is_mac) {
|
||
include_dirs += [ "mac" ]
|
||
}
|
||
}
|
||
|
||
template("compat_target") {
|
||
if (is_mac) {
|
||
# There are no sources to compile, which doesn’t mix will with a
|
||
# static_library.
|
||
group(target_name) {
|
||
forward_variables_from(invoker, "*")
|
||
}
|
||
} else {
|
||
static_library(target_name) {
|
||
forward_variables_from(invoker, "*")
|
||
}
|
||
}
|
||
}
|
||
|
||
compat_target("compat") {
|
||
sources = []
|
||
|
||
if (is_mac) {
|
||
sources += [
|
||
"mac/AvailabilityMacros.h",
|
||
"mac/kern/exc_resource.h",
|
||
"mac/mach-o/loader.h",
|
||
"mac/mach/mach.h",
|
||
"mac/sys/resource.h",
|
||
]
|
||
} else {
|
||
sources += [ "non_mac/mach/mach.h" ]
|
||
}
|
||
|
||
if (is_win) {
|
||
sources += [
|
||
"win/getopt.h",
|
||
"win/strings.cc",
|
||
"win/strings.h",
|
||
"win/sys/types.h",
|
||
"win/time.cc",
|
||
"win/time.h",
|
||
"win/winbase.h",
|
||
"win/winnt.h",
|
||
"win/winternl.h",
|
||
]
|
||
} else {
|
||
sources += [
|
||
"non_win/dbghelp.h",
|
||
"non_win/minwinbase.h",
|
||
"non_win/timezoneapi.h",
|
||
"non_win/verrsrc.h",
|
||
"non_win/windows.h",
|
||
"non_win/winnt.h",
|
||
]
|
||
}
|
||
|
||
public_configs = [
|
||
":compat_config",
|
||
"..:crashpad_config",
|
||
]
|
||
|
||
deps = []
|
||
|
||
if (is_win) {
|
||
deps += [ "../third_party/getopt" ]
|
||
}
|
||
}
|