mirror of
https://github.com/chromium/crashpad.git
synced 2024-12-26 23:01:05 +08:00
54bbd7d0d5
iOS needs to run tests from within the context of a UIApplication, and it needs to periodically spin the runloop to ensure that the watchdog does not kill the app for being unresponsive. BUG=crashpad:31 Change-Id: Ia1d881e478d4f83c236b475a21529760c06100c7 Reviewed-on: https://chromium-review.googlesource.com/c/crashpad/crashpad/+/1904226 Commit-Queue: Rohit Rao <rohitrao@chromium.org> Reviewed-by: Mark Mentovai <mark@chromium.org>
53 lines
1.6 KiB
Plaintext
53 lines
1.6 KiB
Plaintext
# Copyright 2017 The Crashpad Authors. All rights reserved.
|
|
#
|
|
# Licensed under the Apache License, Version 2.0 (the "License");
|
|
# you may not use this file except in compliance with the License.
|
|
# You may obtain a copy of the License at
|
|
#
|
|
# http://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS,
|
|
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
# See the License for the specific language governing permissions and
|
|
# limitations under the License.
|
|
|
|
import("crashpad_buildconfig.gni")
|
|
|
|
if (crashpad_is_in_chromium) {
|
|
import("//testing/test.gni")
|
|
} else {
|
|
template("test") {
|
|
if (crashpad_is_ios) {
|
|
import("//third_party/mini_chromium/mini_chromium/build/ios/rules.gni")
|
|
|
|
_launch_image_bundle_target = target_name + "_launch_image"
|
|
bundle_data(_launch_image_bundle_target) {
|
|
forward_variables_from(invoker, [ "testonly" ])
|
|
sources = [
|
|
"//build/ios/Default.png",
|
|
]
|
|
outputs = [
|
|
"{{bundle_contents_dir}}/{{source_file_part}}",
|
|
]
|
|
}
|
|
|
|
ios_app_bundle(target_name) {
|
|
testonly = true
|
|
info_plist = "//build/ios/Unittest-Info.plist"
|
|
extra_substitutions = [ "GTEST_BUNDLE_ID_SUFFIX=$target_name" ]
|
|
forward_variables_from(invoker, "*")
|
|
if (!defined(deps)) {
|
|
deps = []
|
|
}
|
|
deps += [ ":$_launch_image_bundle_target" ]
|
|
}
|
|
} else {
|
|
executable(target_name) {
|
|
testonly = true
|
|
forward_variables_from(invoker, "*")
|
|
}
|
|
}
|
|
}
|
|
}
|