mirror of
https://github.com/chromium/crashpad.git
synced 2024-12-26 23:01:05 +08:00
3332ae3546
I’m working on something that I’m not ready to share, but maintaining these compat headers in my local branch is becoming annoying because “git cl format” keeps reformatting them since they were added since my local branch point. Because these headers are non-trivial, they’re brought nearly unmodified from upstream into third_party, with forwarding from the appropriate locations in compat. <elf.h> comes from glibc 2.29 (2019-01-31) and was modified to remove the #include of <features.h> and to replace the use of __BEGIN_DECLS and __END_DECLS with the proper conditional extern "C" construct. <mach-o/loader.h> comes from xnu 4903.221.2 (macOS 10.14.1, 2018-10-30) and was modified to remove the unused #includes of <mach/machine/thread_status.h> and <architecture/byte_order.h>. Rather than taking <mach/machine.h> and <mach/vm_prot.h> with a spider web of other dependencies from xnu, compat has cut-back versions of these headers that provide only the required typedefs. This also includes an update of apple_cf to 1153.18 (OS X 10.10.3, 2015-04-08), the last public release of CF-Lite. The change doesn’t do much for our purposes, but it restores the file to an Apple-shipped state, trailing whitespace and all. This also canonically formats BUILD.gn. 48ee086ca4c4c didn’t format it. Change-Id: Ib4f28ad53d9757bd0eed838e148c51172bfe30b1 Reviewed-on: https://chromium-review.googlesource.com/c/1489795 Reviewed-by: Robert Sesek <rsesek@chromium.org> Commit-Queue: Mark Mentovai <mark@chromium.org>
153 lines
3.4 KiB
Plaintext
153 lines
3.4 KiB
Plaintext
# Copyright 2015 The Crashpad Authors. All rights reserved.
|
||
#
|
||
# Licensed under the Apache License, Version 2.0 (the "License");
|
||
# you may not use this file except in compliance with the License.
|
||
# You may obtain a copy of the License at
|
||
#
|
||
# http://www.apache.org/licenses/LICENSE-2.0
|
||
#
|
||
# Unless required by applicable law or agreed to in writing, software
|
||
# distributed under the License is distributed on an "AS IS" BASIS,
|
||
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
||
# See the License for the specific language governing permissions and
|
||
# limitations under the License.
|
||
|
||
import("../build/crashpad_buildconfig.gni")
|
||
|
||
config("compat_config") {
|
||
include_dirs = []
|
||
|
||
if (crashpad_is_mac) {
|
||
include_dirs += [ "mac" ]
|
||
} else {
|
||
include_dirs += [ "non_mac" ]
|
||
}
|
||
|
||
if (crashpad_is_linux || crashpad_is_android) {
|
||
include_dirs += [ "linux" ]
|
||
}
|
||
|
||
if (crashpad_is_android) {
|
||
include_dirs += [ "android" ]
|
||
}
|
||
|
||
if (crashpad_is_win) {
|
||
include_dirs += [ "win" ]
|
||
} else {
|
||
include_dirs += [ "non_win" ]
|
||
}
|
||
|
||
if (!crashpad_is_linux && !crashpad_is_android && !crashpad_is_fuchsia) {
|
||
include_dirs += [ "non_elf" ]
|
||
}
|
||
}
|
||
|
||
template("compat_target") {
|
||
if (crashpad_is_mac) {
|
||
# There are no sources to compile, which doesn’t mix will with a
|
||
# static_library.
|
||
group(target_name) {
|
||
forward_variables_from(invoker, "*")
|
||
}
|
||
} else {
|
||
static_library(target_name) {
|
||
forward_variables_from(invoker, "*")
|
||
}
|
||
}
|
||
}
|
||
|
||
compat_target("compat") {
|
||
sources = []
|
||
|
||
if (crashpad_is_mac) {
|
||
sources += [
|
||
"mac/AvailabilityMacros.h",
|
||
"mac/kern/exc_resource.h",
|
||
"mac/mach-o/loader.h",
|
||
"mac/mach/mach.h",
|
||
"mac/sys/resource.h",
|
||
]
|
||
} else {
|
||
sources += [
|
||
"non_mac/mach-o/loader.h",
|
||
"non_mac/mach/mach.h",
|
||
"non_mac/mach/machine.h",
|
||
"non_mac/mach/vm_prot.h",
|
||
]
|
||
}
|
||
|
||
if (crashpad_is_linux || crashpad_is_android) {
|
||
sources += [
|
||
"linux/signal.h",
|
||
"linux/sys/ptrace.h",
|
||
"linux/sys/user.h",
|
||
]
|
||
}
|
||
|
||
if (crashpad_is_android) {
|
||
sources += [
|
||
"android/android/api-level.cc",
|
||
"android/android/api-level.h",
|
||
"android/dlfcn_internal.cc",
|
||
"android/dlfcn_internal.h",
|
||
"android/elf.h",
|
||
"android/linux/elf.h",
|
||
"android/linux/prctl.h",
|
||
"android/linux/ptrace.h",
|
||
"android/sched.h",
|
||
"android/sys/epoll.cc",
|
||
"android/sys/epoll.h",
|
||
"android/sys/mman.cc",
|
||
"android/sys/mman.h",
|
||
"android/sys/syscall.h",
|
||
"android/sys/user.h",
|
||
]
|
||
}
|
||
|
||
if (crashpad_is_win) {
|
||
sources += [
|
||
"win/getopt.h",
|
||
"win/strings.cc",
|
||
"win/strings.h",
|
||
"win/sys/types.h",
|
||
"win/time.cc",
|
||
"win/time.h",
|
||
"win/winbase.h",
|
||
"win/winnt.h",
|
||
"win/winternl.h",
|
||
]
|
||
} else {
|
||
sources += [
|
||
"non_win/dbghelp.h",
|
||
"non_win/minwinbase.h",
|
||
"non_win/timezoneapi.h",
|
||
"non_win/verrsrc.h",
|
||
"non_win/windows.h",
|
||
"non_win/winnt.h",
|
||
]
|
||
}
|
||
|
||
if (!crashpad_is_linux && !crashpad_is_android && !crashpad_is_fuchsia) {
|
||
sources += [ "non_elf/elf.h" ]
|
||
}
|
||
|
||
public_configs = [
|
||
":compat_config",
|
||
"..:crashpad_config",
|
||
]
|
||
|
||
deps = []
|
||
|
||
if (!crashpad_is_mac) {
|
||
deps += [ "../third_party/xnu" ]
|
||
}
|
||
|
||
if (crashpad_is_win) {
|
||
deps += [ "../third_party/getopt" ]
|
||
}
|
||
|
||
if (!crashpad_is_linux && !crashpad_is_android && !crashpad_is_fuchsia) {
|
||
deps += [ "../third_party/glibc" ]
|
||
}
|
||
}
|