mirror of
https://github.com/chromium/crashpad.git
synced 2025-03-09 14:06:33 +00:00
2bb56fafe3
- Adds a .gn and a build/BUILDCONFIG.gn that uses mini_chromium's build/BUILD.gn. - Adds some stub BUILD.gn files in locations where Chromium expects them (in //build, //testing, //third_party) containing empty targets/configs. These are no-ops in standalone builds, but add functionality when building in Chromium. This is in preference to having a global bool that conditionally does Chromium-y things in the Crashpad build files. These stub files are all contained in a secondary source root in build/chromium_compatibility, referred to by //.gn. - Adds //base/BUILD.gn which forwards to mini_chromium/base. This is only used when building standalone so that both Chromium and Crashpad can refer to it as "//base". - Changes references to other Crashpad targets to be relatively specified so that they work when the root of the project is //, and also when it's //third_party/crashpad/crashpad as it is in Chromium. - Moves any error-causing Mac/Win-specific files into explicit if (is_mac) or if (is_win) blocks as part of removing the dependency on set_sources_assignment_filter(). As yet unresolved: - CRASHPAD_IN_CHROMIUM needs to be removed when standalone; to be tackled in a follow up. - Not sure what to do with zlib yet, the build file currently assumes "in Chromium" too, and similarly having Crashpad //third_party/zlib:zlib pointing at itself doesn't work. Bug: crashpad:79 Change-Id: I6a7dda214e4b3b14a60c1ed285267ab97432a1a8 Reviewed-on: https://chromium-review.googlesource.com/777410 Reviewed-by: Mark Mentovai <mark@chromium.org> Reviewed-by: Robert Sesek <rsesek@chromium.org> Commit-Queue: Scott Graham <scottmg@chromium.org>
162 lines
3.0 KiB
Plaintext
162 lines
3.0 KiB
Plaintext
# Copyright 2015 The Crashpad Authors. All rights reserved.
|
||
#
|
||
# Licensed under the Apache License, Version 2.0 (the "License");
|
||
# you may not use this file except in compliance with the License.
|
||
# You may obtain a copy of the License at
|
||
#
|
||
# http://www.apache.org/licenses/LICENSE-2.0
|
||
#
|
||
# Unless required by applicable law or agreed to in writing, software
|
||
# distributed under the License is distributed on an "AS IS" BASIS,
|
||
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
||
# See the License for the specific language governing permissions and
|
||
# limitations under the License.
|
||
|
||
source_set("tool_support") {
|
||
sources = [
|
||
"tool_support.cc",
|
||
"tool_support.h",
|
||
]
|
||
|
||
public_configs = [ "..:crashpad_config" ]
|
||
|
||
deps = [
|
||
"//base",
|
||
]
|
||
}
|
||
|
||
executable("crashpad_database_util") {
|
||
sources = [
|
||
"crashpad_database_util.cc",
|
||
]
|
||
|
||
deps = [
|
||
":tool_support",
|
||
"../client",
|
||
"../compat",
|
||
"../util",
|
||
"//base",
|
||
"//build/win:default_exe_manifest",
|
||
]
|
||
}
|
||
|
||
executable("crashpad_http_upload") {
|
||
sources = [
|
||
"crashpad_http_upload.cc",
|
||
]
|
||
|
||
deps = [
|
||
":tool_support",
|
||
"../compat",
|
||
"../util",
|
||
"//base",
|
||
"//build/win:default_exe_manifest",
|
||
]
|
||
}
|
||
|
||
executable("generate_dump") {
|
||
sources = [
|
||
"generate_dump.cc",
|
||
]
|
||
|
||
deps = [
|
||
":tool_support",
|
||
"../compat",
|
||
"../minidump",
|
||
"../snapshot",
|
||
"../util",
|
||
"//base",
|
||
"//build/win:default_exe_manifest",
|
||
]
|
||
|
||
if (is_mac) {
|
||
# This would be better as a config so that it could be shared with
|
||
# exception_port_tool, but configs can’t alter “inputs”.
|
||
inputs = [
|
||
rebase_path("mac/sectaskaccess_info.plist"),
|
||
]
|
||
ldflags = [
|
||
"-sectcreate",
|
||
"__TEXT",
|
||
"__info_plist",
|
||
inputs[0],
|
||
]
|
||
}
|
||
|
||
if (is_win) {
|
||
cflags = [ "/wd4201" ] # nonstandard extension used : nameless struct/union
|
||
}
|
||
}
|
||
|
||
if (is_mac) {
|
||
executable("catch_exception_tool") {
|
||
sources = [
|
||
"mac/catch_exception_tool.cc",
|
||
]
|
||
|
||
deps = [
|
||
":tool_support",
|
||
"../compat",
|
||
"../util",
|
||
"//base",
|
||
]
|
||
}
|
||
|
||
executable("exception_port_tool") {
|
||
sources = [
|
||
"mac/exception_port_tool.cc",
|
||
]
|
||
|
||
# This would be better as a config so that it could be shared with
|
||
# generate_dump, but configs can’t alter “inputs”.
|
||
inputs = [
|
||
rebase_path("mac/sectaskaccess_info.plist"),
|
||
]
|
||
ldflags = [
|
||
"-sectcreate",
|
||
"__TEXT",
|
||
"__info_plist",
|
||
inputs[0],
|
||
]
|
||
|
||
deps = [
|
||
":tool_support",
|
||
"../compat",
|
||
"../util",
|
||
"//base",
|
||
]
|
||
}
|
||
|
||
executable("on_demand_service_tool") {
|
||
sources = [
|
||
"mac/on_demand_service_tool.mm",
|
||
]
|
||
|
||
libs = [
|
||
"CoreFoundation.framework",
|
||
"Foundation.framework",
|
||
]
|
||
|
||
deps = [
|
||
":tool_support",
|
||
"../compat",
|
||
"../util",
|
||
"//base",
|
||
]
|
||
}
|
||
|
||
executable("run_with_crashpad") {
|
||
sources = [
|
||
"mac/run_with_crashpad.cc",
|
||
]
|
||
|
||
deps = [
|
||
":tool_support",
|
||
"../client",
|
||
"../compat",
|
||
"../util",
|
||
"//base",
|
||
]
|
||
}
|
||
}
|