crashpad/build/crashpad_dependencies.gni

# Copyright 2017 The Crashpad Authors. All rights reserved.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

declare_args() {
  # Determines various flavors of build configuration, and which concrete
  # targets to use for dependencies. Valid values are "standalone", "chromium",
  # and "fuchsia".
  crashpad_dependencies = "standalone"
}

assert(
    crashpad_dependencies == "chromium" || crashpad_dependencies == "fuchsia" ||
    crashpad_dependencies == "standalone")

crashpad_is_in_chromium = crashpad_dependencies == "chromium"
crashpad_is_in_fuchsia = crashpad_dependencies == "fuchsia"
crashpad_is_standalone = crashpad_dependencies == "standalone"

if (crashpad_is_in_chromium) {
  crashpad_is_posix = is_posix
} else if (crashpad_is_in_fuchsia) {
  import("//third_party/mini_chromium/build/is_posix.gni")
  crashpad_is_posix = mini_chromium_is_posix
} else if (crashpad_is_standalone) {
  import("../third_party/mini_chromium/mini_chromium/build/is_posix.gni")
  crashpad_is_posix = mini_chromium_is_posix
}

if (crashpad_is_in_chromium) {
  import("//testing/test.gni")
} else {
  template("test") {
    executable(target_name) {
      testonly = true
      forward_variables_from(invoker, "*")
    }
  }

  set_defaults("test") {
    configs = default_executable_configs
  }
}